P_RU_DSVATReporting0

@VDM.private: true
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'PRUDSVATRPTG0'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view P_RU_DSVATReporting0
  as select from           I_JournalEntry

    left outer to one join P_RU_CFinPseudoReversedDoc1 as ReversedDoc on  ReversedDoc.CompanyCode                = I_JournalEntry.CompanyCode
                                                                      and ReversedDoc.OriginalAccountingDocument = I_JournalEntry.AccountingDocument
                                                                      and ReversedDoc.OriginalFiscalYear         = I_JournalEntry.FiscalYear

{
  I_JournalEntry.CompanyCode,
  I_JournalEntry.AccountingDocument,
  I_JournalEntry.FiscalYear,
  I_JournalEntry.AccountingDocumentType,
  I_JournalEntry.PostingDate,
  I_JournalEntry.TaxReportingDate,

  I_JournalEntry.IsReversal,
  I_JournalEntry.IsReversed,
  I_JournalEntry.ReverseDocument,
  I_JournalEntry.ReverseDocumentFiscalYear,
  cast( '00000000' as vatdate )         as ReverseDocumentTaxRepDate,

  I_JournalEntry.AccountingDocument     as SrcDocNmbrForOriginalDocument,
  I_JournalEntry.FiscalYear             as SrcDocYearForOriginalDocument,
  I_JournalEntry.AccountingDocumentType as SrcDocTypeForOriginalDocument
}
where
      I_JournalEntry.IsReversal                 = ''
  and I_JournalEntry.IsReversed                 = ''
  and I_JournalEntry.JrnlEntryCntrySpecificRef2 not like 'NEG^%'
  and ReversedDoc.CompanyCode                   is null

union all select from P_RU_ReverseDocument

{
  CompanyCode,
  AccountingDocument,
  FiscalYear,
  AccountingDocumentType,
  PostingDate,
  TaxReportingDate,

  IsReversal,
  IsReversed,
  ReverseDocument,
  ReverseDocumentFiscalYear,
  ReverseDocumentTaxRepDate,

  SrcDocNmbrForOriginalDocument,
  SrcDocYearForOriginalDocument,
  SrcDocTypeForOriginalDocument
}