P_RTPCOrderWIPReserve

@AbapCatalog.sqlViewName: 'PFIRTPCORWIPRSRV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'RTPC Order WIP Reserve'

@VDM.viewType: #COMPOSITE
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
define view P_RTPCOrderWIPReserve
  as select from I_GLAccountLineItemRawData  as _item
    inner join   I_Ledger                    as _ledger on  _ledger.Ledger     = _item.SourceLedger
                                                        and _ledger.LedgerType = '' //standard ledger only

    inner join   P_RTPCOrderWIPReserveOffset as _offset on  _item.AccountingDocument = _offset.AccountingDocument
                                                        and _item.SourceLedger       = _offset.Ledger
                                                        and _item.OffsettingAccount  = _offset.GLAccount
                                                        and _item.CompanyCode        = _offset.CompanyCode
                                                        and _item.FiscalYear         = _offset.FiscalYear
{
  key _item.OrderID                             as OrderID,
  key _item.OrderItem                           as OrderItem,
  key _item.CompanyCode                         as CompanyCode,
  key _item.SourceLedger                        as Ledger,
  key _item.SubLedgerAcctLineItemType           as SubLedgerAcctLineItemType,
  key _item.FiscalYearPeriod                    as FiscalYearPeriod,
  key _offset.GLAccountType                     as OffsetAccountType,
 
      sum( _item.AmountInCompanyCodeCurrency )  as hsl,
      sum( _item.AmountInGlobalCurrency )       as ksl,
      sum( _item.AmountInFreeDefinedCurrency1 ) as osl,
      sum( _item.AmountInFreeDefinedCurrency2 ) as vsl,
      sum( _item.AmountInFreeDefinedCurrency3 ) as bsl,
      sum( _item.AmountInFreeDefinedCurrency4 ) as csl,
      sum( _item.AmountInFreeDefinedCurrency5 ) as dsl,
      sum( _item.AmountInFreeDefinedCurrency6 ) as esl,
      sum( _item.AmountInFreeDefinedCurrency7 ) as fsl,
      sum( _item.AmountInFreeDefinedCurrency8 ) as gsl
 
}
where
       _item.GLBusinessTransactionType = 'EBWP'
  and(
       _item.SubLedgerAcctLineItemType = '09100'
    or _item.SubLedgerAcctLineItemType = '09110'
  )
 
group by
  _item.OrderID,
  _item.OrderItem,
  _item.CompanyCode,
  _item.SourceLedger,
  _item.SubLedgerAcctLineItemType,
  _item.FiscalYearPeriod,
  _offset.GLAccountType
 
union select from I_GLAccountLineItemRawData  as _item
  inner join      I_Ledger as _ledger on  _ledger.Ledger     = _item.SourceLedger
                                      and _ledger.LedgerType = '' //standard ledger only

{
  key _item.OrderID                             as OrderID,
  key _item.OrderItem                           as OrderItem,
  key _item.CompanyCode                         as CompanyCode,
  key _item.SourceLedger                        as Ledger,
  key _item.SubLedgerAcctLineItemType           as SubLedgerAcctLineItemType,
  key _item.FiscalYearPeriod                    as FiscalYearPeriod,
  key 'N'               as OffsetAccountType,
 
      sum( _item.AmountInCompanyCodeCurrency )  as hsl,
      sum( _item.AmountInGlobalCurrency )       as ksl,
      sum( _item.AmountInFreeDefinedCurrency1 ) as osl,
      sum( _item.AmountInFreeDefinedCurrency2 ) as vsl,
      sum( _item.AmountInFreeDefinedCurrency3 ) as bsl,
      sum( _item.AmountInFreeDefinedCurrency4 ) as csl,
      sum( _item.AmountInFreeDefinedCurrency5 ) as dsl,
      sum( _item.AmountInFreeDefinedCurrency6 ) as esl,
      sum( _item.AmountInFreeDefinedCurrency7 ) as fsl,
      sum( _item.AmountInFreeDefinedCurrency8 ) as gsl
}
where
  (
        _item.GLBusinessTransactionType  = 'KOAE' // for non-event-based migrated orders

    and _item.OriginObjectType = '23'
  )
group by
  _item.OrderID,
  _item.OrderItem,
  _item.CompanyCode,
  _item.SourceLedger,
  _item.SubLedgerAcctLineItemType,
  _item.FiscalYearPeriod