P_RTPCOrderSettCostForRev

@AbapCatalog.sqlViewName: 'PFIRTPCORDSCFR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label      : 'RTPC Order Settled Cost For Reversal'

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #BASIC
@VDM.private:true
define view P_RTPCOrderSettCostForRev
  as select from    acdoca         as a
    inner join      I_Ledger       as l         on  a.rldnr           = l.Ledger
                                                and l.IsLeadingLedger = 'X' //only support version 000 which corresponding to leading ledger

    left outer join fins_acdoc_ref as _prec_ref on  a.awtyp          =  _prec_ref.prec_awtyp
                                                and a.aworg          =  _prec_ref.prec_aworg
                                                and a.awref          =  _prec_ref.prec_awref
                                                and a.awitem         =  _prec_ref.prec_awitem
                                                and a.subta          =  _prec_ref.prec_subta
                                                and (
                                                   _prec_ref.objnr   =  ''
                                                   or(
                                                     _prec_ref.objnr <> ''
                                                     and a.objnr     =  _prec_ref.objnr
                                                   )
                                                 )

{

  '00'                                             as lednr,
  aufnr,
  a.objnr,
  ryear                                            as gjahr,
  rbukrs,
  fiscyearper,
  belnr,
  docln,
  '000'                                            as versn,
  '04'                                             as wrttp,
  racct                                            as kstar,
  hrkft,
  vrgng,
  case when parobsrc = '1' then parob1     else case
       when parobsrc = '2' then paccasty
       else ''                             end end as parob,
  uspob,
  rassc                                            as vbund,
  sbusa                                            as pargb,
  co_beknz                                         as beknz,
  rwcur                                            as twaer,
  rvunit                                           as meinh,
  bemot,
  beltp,

  bttype,

  awtyp,
  awref,
  awitem,
  aworg,
  awsys,
  subta,

  _prec_ref.prec_awmult                            as prec_awmult,

  wsl                                              as wtgbtr,

  hsl                                              as wogbtr,

  ksl                                              as wkgbtr,

  kfsl                                             as wkfbtr,

  psl                                              as pagbtr,

  pfsl                                             as pafbtr,

  vmsl                                             as megbtr,

  vmfsl                                            as mefbtr,

  osl                                              as wagbtr,

  vsl                                              as wvgbtr,

  bsl                                              as wbgbtr,

  csl                                              as wcgbtr,

  dsl                                              as wdgbtr,

  esl                                              as wegbtr,

  fsl                                              as wfgbtr,

  gsl                                              as wggbtr,

  hsl                                              as whgbtr,

  co_osl                                           as wsgbtr

}

where
  (
       accasty  =  'OR'
    or accasty  =  'OP'
  )
  and(
       autyp    =  '10'
    or autyp    =  '40'
  )
  and  xsettled =  'X'
  and  bttype   <> 'TBCS' --ignore Transaction-Based Split
  and  bttype   <> 'EBWP' --ignore Event-Based WIP posting
  and  co_beknz <> 'A'    //exclude settlement line items

  and  aufnr    <> paufnr //exclude pre-settlement

  //and  co_belnr <> ''

  and  a.objnr  <> ''