P_PubSecOpenInvoiceItems

@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@VDM.viewType: #COMPOSITE
@VDM.private:true
@ObjectModel: {
     usageType: {
         dataClass: #MIXED,
         serviceQuality: #P,
         sizeCategory: #XL
     }
}
@EndUserText.label: 'Open Invoice Items - Vendor/Customer'

define view entity P_PubSecOpenInvoiceItems
  as select from I_GLAccountLineItem as Inv
    cross join   I_PubSecPlanningCategory
{
  key Inv.SourceLedger,
  key Inv.CompanyCode,
  key Inv.FiscalYear,
  key Inv.AccountingDocument,
  key Inv.LedgerGLLineItem,
  key Inv.Ledger,
  key cast( '00000000000000000000000'  as fis_fp_request_tsn preserving type ) as FinancialPlanningReqTransSqnc,
  key cast( '000000' as fis_fp_data_packet preserving type )                   as FinancialPlanningDataPacket,
  key cast( 0 as fis_fp_entry_item )                                           as FinancialPlanningEntryItem,
  key I_PubSecPlanningCategory.PlanningCategory                                as PlanningCategory,
      // field ActualPlanJournalEntryItem required for representative key definition

      cast( Inv.LedgerGLLineItem as fis_act_pln_docln)                         as ActualPlanJournalEntryItem,

      Inv.ChartOfAccounts,
      Inv.ControllingArea,
      Inv.BusinessTransactionType,
      cast(cast( 'A' as abap.char (1)) as fis_actual_plan_code)                as ActualPlanCode,
      cast('  ' as psm_bdgt_cnsmpn_type_grp preserving type)                   as PubSecBudgetCnsmpnTypeGroup,

      Inv.ReferenceDocumentType,
      Inv.ReferenceDocument,
      Inv.ReferenceDocumentItem,
      Inv.SourceReferenceDocumentType,
      Inv.SourceReferenceDocument,
      Inv.SourceReferenceDocumentItem,
      Inv.IsCommitment,
      Inv.GLAccount,
      Inv.CostCenter,
      Inv.ProfitCenter,
      Inv.FunctionalArea,
      Inv.Segment,
      Inv.PartnerCostCenter,
      Inv.PartnerFunctionalArea,
      Inv.TransactionCurrency,
      Inv.AmountInTransactionCurrency,
      Inv.CompanyCodeCurrency,
      Inv.AmountInCompanyCodeCurrency,
      Inv.GlobalCurrency,
      Inv.AmountInGlobalCurrency,
      Inv.FiscalPeriod,
      Inv.FiscalYearVariant,
      Inv.PostingDate,
      Inv.IsOpenItemManaged,
      Inv.ClearingDate,
      Inv.OriginCostCenter,
      Inv.PartnerWBSElement,
      Inv.CashLedgerCompanyCode,
      Inv.CashLedgerAccount,
      Inv.FinancialManagementArea,
      Inv.Fund,
      Inv.GrantID,
      Inv.BudgetPeriod,
      Inv.PartnerFund,
      Inv.PartnerGrant,
      Inv.PartnerBudgetPeriod,
      Inv.PubSecBudgetAccount,
      Inv.PubSecBudgetAccountCoCode,
      Inv.PubSecBudgetCnsmpnDate,
      Inv.PubSecBudgetCnsmpnFsclPeriod,
      Inv.PubSecBudgetCnsmpnFsclYear,
      Inv.PubSecBudgetIsRelevant,
      Inv.PubSecBudgetCnsmpnType,
      Inv.PubSecBudgetCnsmpnAmtType,
      Inv.SponsoredProgram,
      Inv.SponsoredClass,
      Inv.GteeMBudgetValidityNumber,
      Inv.EarmarkedFundsDocument,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      case
      when
      Inv.PubSecBudgetCnsmpnType = '54' then
      (cast (Inv.AmountInGlobalCurrency as psm_amt_expn_inv_grp_curr) * -1 )
      else cast ('0' as psm_amt_expn_inv_grp_curr )
      end                                                                      as PubSecExpnInvcAmtInGlobCrcy,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      case when
      Inv.PubSecBudgetCnsmpnType = '55' then cast (Inv.AmountInGlobalCurrency as psm_amt_revn_inv_grp_curr)
      else
      cast ('0' as psm_amt_revn_inv_grp_curr )
      end                                                                      as PubSecRevnInvcAmtInGlobCrcy,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      cast ('0' as psm_amt_expn_transf_grp_curr )                              as PubSecExpnTransfAmtInGlobCrcy,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      cast ('0' as psm_amt_revn_transf_grp_curr )                              as PubSecRevnTransfAmtInGlobCrcy,

      //  /* Associations */


      Inv._BudgetPeriod,
      Inv._BusinessTransactionType,
      Inv._CashLedgerAccount,
      Inv._CashLedgerCompanyCode,
      Inv._ChartOfAccounts,
      Inv._CompanyCode,
      Inv._CompanyCodeCurrency,
      Inv._ControllingArea,
      Inv._CostCenter,
      Inv._FinancialManagementArea,
      Inv._FiscalYear,
      Inv._FiscalYearVariant,
      Inv._FunctionalArea,
      Inv._Fund,
      Inv._GLAccountInChartOfAccounts,
      Inv._GlobalCurrency,
      Inv._Grant,
      Inv._Ledger,
      Inv._PartnerCostCenter,
      Inv._PartnerFunctionalArea,
      Inv._ProfitCenter,
      Inv._PubSecBudgetAccount,
      Inv._PubSecBudgetAccountCoCode,
      Inv._PubSecBudgetCnsmpnAmtType,
      Inv._PubSecBudgetCnsmpnDate,
      Inv._PubSecBudgetCnsmpnFsclPeriod,
      Inv._PubSecBudgetCnsmpnFsclYear,
      Inv._PubSecBudgetCnsmpnType,
      Inv._ReferenceDocumentType,
      Inv._Segment,
      Inv._SourceLedger,
      Inv._SponsoredClass,
      Inv._SponsoredProgram,
      Inv._TransactionCurrency

}
where
       Inv.Ledger                 = '0L'
  and(
       Inv.PubSecBudgetCnsmpnType = '54'
    or Inv.PubSecBudgetCnsmpnType = '55'
  )