P_ProductionRoutingHeaderDEX

@VDM.private:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.representativeKey: 'ProductionRoutingInternalVers'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@VDM.viewType: #BASIC

define view entity P_ProductionRoutingHeaderDEX 
  as select from plko

  association [1..1] to I_BillOfOperationsType        as _BillOfOperationsType       on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [1..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup      on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                     and $projection.ProductionRoutingGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  -- to root, to parent
  association [1..1] to I_BillOfOperations            as _BillOfOperations           on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                     and $projection.ProductionRoutingGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                     and $projection.ProductionRouting = _BillOfOperations.BillOfOperationsVariant

{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plko.plnty                                                  as BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plko.plnnr                                                  as ProductionRoutingGroup,
  
      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key plko.plnal                                                  as ProductionRouting,
      
  key plko.zaehl                                                  as ProductionRoutingInternalVers,

      
      plko.versn                                                  as BillOfOperationsVersion,

      // ***************** Technical fields not on the CEWB-UI *****************


      plko.loekz                                                  as IsDeleted,
      plko.loekz_inherited                                        as IsImplicitlyDeleted,
   
      case when plko.arbty = '  ' and plko.arbid <> '00000000' then 'A '
      else plko.arbty end                                         as WorkCenterTypeCode,
      
      plko.arbid                                                  as WorkCenterInternalID,

      // *************************** Header general ****************************


      -- General data
      @Semantics.text: true
      plko.ktext                                                  as BillOfOperationsDesc,

      
      plko.txtsp                                                  as LongTextLanguageCode,

      
      plko.werks                                                  as Plant,

      
      plko.verwe                                                  as BillOfOperationsUsage,

      
      plko.statu                                                  as BillOfOperationsStatus,

      plko.profidnetz                                             as BillOfOperationsProfile,

      
      plko.vagrp                                                  as ResponsiblePlannerGroup,

      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      plko.losvn                                                  as MinimumLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      plko.losbs                                                  as MaximumLotSizeQuantity,
      
      plko.plnme                                                  as BillOfOperationsUnit,

      plko.plnnr_alt                                              as ReplacedBillOfOperations,

      plko.delkz                                                  as IsMarkedForDeletion,

      -- Production line
     
      plko.st_arbid                                               as LineHierarchyInternalID,

      // ************************* Quality Management **************************


      -- Parameter for dynamic modification/inspection points
      
      cast (plko.slwbez as vdm_qslwbez preserving type )          as InspSubsetFieldCombination,
      
      cast (plko.ppkztlzu as vdm_qppkztlzu preserving type )      as InspectionPartialLot,
      
      cast (plko.qprziehver as vdm_qprziehver preserving type )   as SmplDrawingProcedure,
      
      plko.qversnprzv                                             as SmplDrawingProcedureVersion,
      
      cast (plko.qdynhead as vdm_qdynhead preserving type )       as InspectionLotDynamicLevel,
      
      plko.qdynregel                                              as InspLotDynamicRule,
      plko.qdynstring                                             as InspLotDynamicCriteria,
      
      plko.strat                                                  as MaintenanceStrategy,

      -- Further QM data
      
      plko.extnum                                                 as InspExternalNumberingOfValues,
      
      plko.iwerk                                                  as MaintenancePlanningPlant,
      
      plko.istru                                                  as Assembly,
      
      plko.anlzu                                                  as OperationSystemCondition,
      
      
      plko.adpsp                                                  as ReferenceElement,

      
      plko.kokrs                                                  as ControllingArea,
      --    @ObjectModel.foreignKey.association: '_WBSElementBasicData'
      cast(plko.pspnr as ps_s4_pspnr preserving type)             as WBSElementInternalID,
      
      plko.kzkfg                                                  as BillOfOperationIsConfigurable,

      // The conversion from DEC16 to DEC15 is intended (needed for BW extraction). Entries of plko.tstmp_bw are always DEC15 anyways.

      cast(plko.tstmp_bw as tzntstmps)                            as BillOfOperationsDateTime,

      // *************************** Administration ****************************


      -- Administrative Data
      @Semantics.systemDate.createdAt: true
      plko.andat                                                  as CreationDate,
      @Semantics.user.createdBy: true
      cast(plko.annam as vdm_createdbyuserid preserving type)     as CreatedByUser,

      @Semantics.systemDate.lastChangedAt: true
      plko.aedat                                                  as LastChangeDate,
      @Semantics.user.lastChangedBy: true
      cast(plko.aenam as vdm_lastchangedbyuserid preserving type) as LastChangedByUser,
      plko.changeddatetime                                        as ChangedDateTime,

      -- Validity
      plko.aennr                                                  as ChangeNumber,
      @Semantics.businessDate.from: true
      cast(plko.datuv as pph_begda preserving type)               as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast(plko.valid_to as pph_endda preserving type)            as ValidityEndDate,

      -- Additional Data
      plko.reodat                                                 as LastReorganizationDate,
      plko.abdat                                                  as LastUsageDate,
      plko.abanz                                                  as NumberOfUsages,

      --Effectivity Type in Planning Routing
      plko.efftyp                                                 as EffectivityType,

      -- Industry fields
      // A&D: Task list has an operation which is referenced in another task list, which maybe again has referenced operations.

      //      It has no other "own" operation, only referenced.

      xhiertl                                                     as TaskListIsHierarchical,
      plko.ms_flag                                                as InspPlanHasMultipleSpec,

      // Default values of Activity

      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      plko.bmsch                                                  as OperationReferenceQuantity,
      
      plko.meinh                                                  as OperationUnit,
      plko.umrez                                                  as OpQtyToBaseQtyNmrtr,
      plko.umren                                                  as OpQtyToBaseQtyDnmntr,

      // **************************** Associations *****************************


      _BillOfOperations,
      _BillOfOperationsGroup,
      _BillOfOperationsType
} where plko.plnty = 'N'