P_ProccatalogcallstructWD

@AbapCatalog.sqlViewName: 'PPROCCATCAL001WD'
@VDM.private: true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #CUSTOMIZING

define view P_ProccatalogcallstructWD
  as select from    I_Proccatalogcallstruct as ActiveDocument
    left outer join proccatcallstr_d        as DraftDocument on  DraftDocument.activeopnctlgwebserviceid = ActiveDocument.OpnCtlgWebServiceID
                                                             and DraftDocument.activeopnctlgsqnccntr     = ActiveDocument.OpnCtlgSqncCntr
{
  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x preserving type ) as OpnCtlgSqncCntrDraftUUID,
  key ActiveDocument.OpnCtlgSqncCntr                                                     as ActiveOpnCtlgSqncCntr,
  key ActiveDocument.OpnCtlgWebServiceID                                                 as ActiveOpnCtlgWebServiceID,
      cast ( hextobin('00000000000000000000000000000000') as sysuuid_x preserving type ) as OpnCtlgWebServiceDraftUUID,
      ActiveDocument.OpnCtlgSqncCntr,
      ActiveDocument.OpnCtlgParamName,
      ActiveDocument.OpnCtlgParamVal,
      ActiveDocument.OpnCtlgValType,
      DraftDocument.opnctlgwebservicedraftuuid                                           as DraftAdministrativeDataUUID,
      cast( 'X' as sdraft_is_active preserving type )                                    as IsActiveEntity,
      cast( ' ' as sdraft_has_active preserving type )                                   as HasActiveEntity,
      cast(
      case
      when DraftDocument.opnctlgsqnccntrdraftuuid is null then ' '
      else 'X'
      end  as sdraft_has_draft preserving type )                                         as HasDraftEntity
}
union all select from proccatcallstr_d          as DraftDocument
  inner join          I_DraftAdministrativeData as I_DraftAdministrativeData on I_DraftAdministrativeData.DraftUUID = DraftDocument.opnctlgwebservicedraftuuid
{
  key DraftDocument.opnctlgsqnccntrdraftuuid,
  key DraftDocument.activeopnctlgsqnccntr,
  key DraftDocument.activeopnctlgwebserviceid,
      DraftDocument.opnctlgwebservicedraftuuid,
      DraftDocument.opnctlgsqnccntr,
      DraftDocument.opnctlgparamname,
      DraftDocument.opnctlgparamval,
      DraftDocument.opnctlgvaltype,
      DraftDocument.opnctlgwebservicedraftuuid         as DraftAdministrativeDataUUID,
      cast( ' '  as sdraft_is_active preserving type ) as IsActiveEntity,
      DraftDocument.hasactiveentity,
      cast( ' '  as sdraft_has_draft preserving type ) as HasDraftEntity
}
where
     I_DraftAdministrativeData.CreatedByUser   = $session.user
  or I_DraftAdministrativeData.InProcessByUser = $session.user