P_ProcOrdOpsMgmtGoodsMovement

@AbapCatalog.sqlViewName: 'PPOROPGDMVMT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'Process Order Operation Goods Movement'

@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view P_ProcOrdOpsMgmtGoodsMovement
  as select from I_MaterialDocumentRecord as _Document
  association [1..1] to I_ManufacturingOrder        as _Order                 on  $projection.ProcessOrder          = _Order.ManufacturingOrder
                                                                              and _Order.ManufacturingOrderCategory = '40'
  association [0..1] to I_MaterialText              as _MaterialText          on  $projection.Material   = _MaterialText.Material
                                                                              and _MaterialText.Language = $session.system_language

  association [0..1] to I_GoodsMovementTypeT        as _GoodsMovementTypeText on  $projection.GoodsMovementType   = _GoodsMovementTypeText.GoodsMovementType
                                                                              and _GoodsMovementTypeText.Language = $session.system_language

  association [0..1] to P_ProcOrdMgmtFirstOperation as _FirstOperation        on  $projection.ProcessOrder = _FirstOperation.ProcessOrder
  //and $projection.OrderInternalBillOfOperations = _FirstOperation.MfgOrderInternalID

  association [0..1] to P_ProcOrdMgmtLastOperation  as _LastOperation         on  $projection.ProcessOrder = _LastOperation.ProcessOrder
  // and $projection.OrderInternalBillOfOperations = _LastOperation.MfgOrderInternalID

{
  key   MaterialDocument,
  key   MaterialDocumentYear,
  key   MaterialDocumentItem,


        case when MaintOrderRoutingNumber is not initial then
                MaintOrderRoutingNumber
                else _Order.MfgOrderInternalID end                    as OrderInternalBillOfOperations,

        case when MaintOrderOperationCounter is not initial then
         MaintOrderOperationCounter
         when GoodsMovementType = '261' or GoodsMovementType = '262' or GoodsMovementType = '531' or GoodsMovementType = '532'
         then        _FirstOperation.OrderOperationInternalID
         when    GoodsMovementType = '101' or GoodsMovementType = '102'
         then             _LastOperation.OrderOperationInternalID end as OrderIntBillOfOperationsItem,

        _Document.ManufacturingOrder                                  as ProcessOrder,
        ManufacturingOrderItem,

        _Order.ManufacturingOrderCategory                             as ManufacturingOrderCategory,

        _Order.ManufacturingOrderType                                 as ManufacturingOrderType,

        _Order.ProductionPlant,

        _Order.ProductionSupervisor,

        _Document.Plant,
        _Document._Plant.PlantName,

        GoodsMovementType,
        _GoodsMovementTypeText.GoodsMovementTypeName,

        _Document.Material,
        _MaterialText.MaterialName,

        PostingDate,

        QuantityInBaseUnit,
        MaterialBaseUnit                                              as BaseUnit,
        
        QuantityInEntryUnit,
        EntryUnit,

        _Document.Plant                                               as PlantForEdit,
        _Document.Material                                            as MaterialForEdit,

        Batch                                                         as BatchForEdit,
        Batch,
        StorageLocation,
        _StorageLocation.StorageLocationName,
        GoodsMovementIsCancelled
}
where
  _Order.ManufacturingOrderCategory = '40';