P_ProcOrdMgmtOpCompWithSts

@AbapCatalog.sqlViewName: 'PPOROPCOMPSTS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
//@EndUserText.label: 'Process Order Op Components with status'

@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.private: true
@VDM.viewType:  #COMPOSITE
@AccessControl.privilegedAssociations: ['_MRPController', '_ProductionSupervisor']
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.ignorePropagatedAnnotations: true
define view P_ProcOrdMgmtOpCompWithSts
  //  as select from I_MfgOrderOperationComponent as comp

  as select from I_ProcOrdMgmtOpCompBasic as comp
    inner join   I_MfgOrderStatus         as status on  comp.ManufacturingOrder           = status.ManufacturingOrder
                                                    and status.ManufacturingOrderCategory = '40'

  association [1..1] to I_CalendarDate  as _RequirementDate on  $projection.MatlCompRequirementDate = _RequirementDate.CalendarDate
  association [0..1] to I_MRPController as _MRPController   on  $projection.Plant         = _MRPController.Plant
                                                            and $projection.MRPController = _MRPController.MRPController
  association [0..1] to I_MaterialPlant as _MaterialPlant   on  $projection.Plant    = _MaterialPlant.Plant
                                                            and $projection.Material = _MaterialPlant.Material
{
      // Key

      @ObjectModel.foreignKey.association: '_Reservation'
  key comp.Reservation,
      @ObjectModel.text.element: 'BOMItemDescription'
  key comp.ReservationItem,
      @ObjectModel.foreignKey.association: '_ReservationDocRecordType'
  key comp.RecordType,

      // Order and operation data

      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      comp.ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      comp.ManufacturingOrderType,
      @ObjectModel.foreignKey.association: '_ManufacturingOrder'
      comp.ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      comp.ManufacturingOrderSequence,
      //      @ObjectModel.foreignKey.association: '_MfgOrderOpBySemanticKey'

      comp.ManufacturingOrderOperation,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      comp.ProductionPlant,
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      comp.ProductionSupervisor,

      //Order Status

      @Semantics.booleanIndicator
      status.OrderIsReleased                                                      as OrderIsReleased,
      @Semantics.booleanIndicator
      status.OrderIsConfirmed                                                     as OrderIsConfirmed,
      @Semantics.booleanIndicator
      status.OrderIsDeleted                                                       as OrderIsDeleted,
      @Semantics.booleanIndicator
      status.OrderIsTechnicallyCompleted                                          as OrderIsTechnicallyCompleted,
      @Semantics.booleanIndicator
      status.OrderIsClosed                                                        as OrderIsClosed,
      @Semantics.booleanIndicator
      status.OrderIsMarkedForDeletion                                             as OrderIsMarkedForDeletion,
      @Semantics.booleanIndicator
      status.MaterialAvailyIsNotChecked                                           as MaterialAvailyIsNotChecked,

      // Date and Time

      @Semantics.businessDate.at: true
      comp.MatlCompRequirementDate,
      comp.MatlCompRequirementTime,

      // Attributes

      comp.ReservationItemCreationCode,
      comp.ReservationIsFinallyIssued,
      comp.MatlCompIsMarkedForDeletion,
      comp.MaterialComponentIsMissing,
      comp.IsBulkMaterialComponent,
      comp.MatlCompIsMarkedForBackflush,
      comp.MaterialCompIsAlternativeItem,
      comp.MatlCompIsTextItem,
      comp.MatlCompDiscontinuationType,
      comp.MatlCompIsConfigurable,
      comp.MaterialCompIsCostRelevant,
      comp.MaterialComponentIsClassified,
      comp.MaterialCompIsIntraMaterial,
      comp.UsageProbabilityPercent,

      // Long Text

      @ObjectModel.foreignKey.association: '_LongTextLanguage'
      comp.LongTextLanguageCode,
      comp.LongTextExists,

      // Assignments

      @ObjectModel.foreignKey.association: '_RequirementType'
      comp.RequirementType,
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      comp.MaterialGroup,
      @ObjectModel.foreignKey.association: '_Material'
      comp.Material,
      @ObjectModel.foreignKey.association: '_Plant'
      comp.Plant,
      @ObjectModel.foreignKey.association: '_MRPController'
      cast(_MaterialPlant.MRPController as pph_dispo preserving type)             as MRPController,
      @ObjectModel.foreignKey.association: '_SalesOrder'
      comp.SalesOrder,
      @ObjectModel.foreignKey.association: '_SalesOrderItem'
      comp.SalesOrderItem,
      @ObjectModel.foreignKey.association: '_WBSElement'
      comp.WBSElementInternalID,
      comp.ProductConfiguration,
      @ObjectModel.foreignKey.association: '_ChangeNumber'
      comp.ChangeNumber,
      comp.EffectivityParameterVariant,
      //      comp.SortField,


      // Assignments BOM

      comp.BillOfMaterialCategory,
      comp.BillOfMaterialInternalID,
      comp.BillOfMaterialVariant,
      @ObjectModel.text.element: 'BOMItemDescription'
      comp.BOMItem                                                                as BillOfMaterialItemNodeNumber,
      comp.BOMItemCategory                                                        as BillOfMaterialItemCategory,
      @ObjectModel.text.element: 'BOMItemDescription'
      comp.BillOfMaterialItemNumber,
      @Semantics.text: true
      comp.BOMItemDescription,
      @ObjectModel.foreignKey.association: '_BOMExplosion'
      comp.BOMExplosionDateID,

      // Assignments Purchasing

      comp.PurchasingInfoRecord,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      comp.PurchasingGroup,
      --    @ObjectModel.foreignKey.association: '_PurchaseRequisition'
      comp.PurchaseRequisition,
      --    @ObjectModel.foreignKey.association: '_PurchaseRequisitionItem'
      comp.PurchaseRequisitionItem,
      --    @ObjectModel.foreignKey.association: '_PurchaseOrder'
      comp.PurchaseOrder,
      --    @ObjectModel.foreignKey.association: '_PurchaseOrderItem'
      comp.PurchaseOrderItem,
      @Semantics.calendarItem.duration: true
      comp.DeliveryDurationInDays,

      // Goods Movement data

      comp.GoodsMovementIsAllowed,
      @ObjectModel.foreignKey.association: '_StorageLocation'
      comp.StorageLocation,
      _StorageLocation.StorageLocationName,
      comp.Batch,
      comp.BatchSplitType,
      @ObjectModel.foreignKey.association: '_DebitCreditCode'
      comp.DebitCreditCode,
      @ObjectModel.foreignKey.association: '_GoodsMovementType'
      comp.GoodsMovementType,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
      comp.InventorySpecialStockType,
      comp.InventorySpecialStockValnType,
      @ObjectModel.foreignKey.association: '_ConsumptionPosting'
      comp.ConsumptionPosting,
      @ObjectModel.foreignKey.association: '_SupplyArea'
      comp.SupplyArea,
      @Semantics.text: true
      comp.GoodsRecipientName,
      @Semantics.text: true
      comp.UnloadingPointName,
      comp.StockSegment,
      comp.RequirementSegment,

      // Assignments WM

      @ObjectModel.foreignKey.association: '_Warehouse'
      comp.Warehouse,
      comp.StorageType,
      comp.StorageBin,

      // Assignments FI/CO

      @ObjectModel.foreignKey.association: '_BusinessArea'
      comp.BusinessArea,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      comp.CompanyCode,
      @ObjectModel.foreignKey.association: '_GLAccount'
      comp.GLAccount,
      @ObjectModel.foreignKey.association: '_AccountAssignmentCategory'
      comp.AccountAssignmentCategory,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      comp.FunctionalArea,

      // Variable-size comp. data

      comp.MaterialCompIsVariableSized,
      //      cast(comp.NumberOfVariableSizeComponents as int2)                           as NumberOfVariableSizeComponents,

      @Semantics.unitOfMeasure: true
      comp.VariableSizeComponentUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeComponentUnit'
      @DefaultAggregation: #SUM
      comp.VariableSizeComponentQuantity,
      comp.FormulaKey,

      // Phantom assembly

      comp.MaterialComponentIsPhantomItem,
      comp.OrderPathValue,
      comp.OrderLevelValue,

      _BillOfMaterialItem.MaterialIsCoProduct,
      _Material.IsBatchManagementRequired,

      // Lead-Time offset

      comp.LeadTimeOffset,
      @Semantics.unitOfMeasure: true
      comp.OperationLeadTimeOffsetUnit,
      comp.OperationLeadTimeOffset,

      // Quantities and UoM

      comp.QuantityIsFixed,
      comp.IsNetScrap,
      @DefaultAggregation: #MAX
      comp.ComponentScrapInPercent,
      @DefaultAggregation: #MAX
      comp.OperationScrapInPercent,
      @Semantics.unitOfMeasure: true
      comp.BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @DefaultAggregation: #SUM
      cast(comp.RequiredQuantity as requirementquantity preserving type)          as RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @DefaultAggregation: #SUM
      comp.WithdrawnQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @DefaultAggregation: #SUM
      (comp.RequiredQuantity - comp.WithdrawnQuantity)                            as OpenQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @DefaultAggregation: #SUM
      cast((comp.WithdrawnQuantity - comp.RequiredQuantity) as deviationquantity) as DeviationQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @DefaultAggregation: #SUM
      comp.ConfirmedAvailableQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @DefaultAggregation: #SUM
      comp.MaterialCompOriginalQuantity,

      @Semantics.unitOfMeasure: true
      comp.EntryUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      @DefaultAggregation: #SUM
      comp.GoodsMovementEntryQty,

      comp.LeadingReservationItem,

      // Associations

      _Reservation,
      _ReservationItem,
      _ManufacturingOrder,
      _ReservationDocRecordType,
      _MfgOrderSequence,
      _MfgOrderOpBySemanticKey                                                    as _MfgOrderOperation,
      _MfgOrderCategory,
      _MfgOrderType,
      _ProductionPlant,
      _ProductionSupervisor,
      _RequirementType,
      _MaterialGroup,
      _Material,
      _MaterialPlant,
      _Plant,
      _MRPController,
      _StorageLocation,
      _Batch,
      _DebitCreditCode,
      _GoodsMovementType,
      _InventorySpecialStockType,
      _ConsumptionPosting,
      _SupplyArea,
      _Warehouse,
      _BOMExplosion,
      _BOMItemCategory,
      _SalesOrder,
      _SalesOrderItem,
      _WBSElement,
      _ChangeNumber,
      _PurchasingGroup,
      _PurchasingInfoRecord,
      _PurchaseOrder,
      _PurchaseOrderItem,
      _PurchaseRequisition,
      _CompanyCode,
      _BusinessArea,
      _FunctionalArea,
      _GLAccount,
      _AccountAssignmentCategory,
      _BaseUnit,
      _EntryUnit,
      _OpLeadTimeOffsetUnit,
      _VariableSizeCompUnit,
      _LongTextLanguage,
      _RequirementDate
}
where

//      comp.IsCoProduct                    is null //no co products

      comp.IsCoProduct  = '' //no co products

  and comp.MaterialComponentIsPhantomItem = ''
  and comp.ManufacturingOrderCategory     = '40';