P_PlanData_RT_01

@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'PPLANDATA_01'
@AbapCatalog.compiler.compareFilter: true

@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
//@AccessControl.authorizationCheck: #NOT_ALLOWED

@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true

define view P_PlanData_RT_01

  as select from    I_FinancialPlanningEntryItem as Source

  //  Find all relevant dimen, vers, rldnr.

  //  For one line in acdocp this may result in several lines.


    inner join      I_CompanyCode                              on Source.CompanyCode = I_CompanyCode.CompanyCode

    left outer join tfin010                                    on tfin010.rcomp = I_CompanyCode.Company


    left outer join tf165                                      on  tfin010.dimen = tf165.dimen
                                                               and tfin010.bunit = tf165.bunit
                                                               and tf165.trans   = 'H'

    left outer join tf200                                      on  tf165.rvers             = tf200.inpvs
                                                               and tf200.planvers          = 'X'
                                                               and Source.PlanningCategory = tf200.category_src
                                                               and tf200.rldnr_src         = Source.Ledger

    inner join      I_SAPClient                  as _SAPClient on _SAPClient.sapclient = $session.client

  //                                                                              begin of bbrCC1911

    left outer join t881                                       on  t881.appl    = 'EC'
                                                               and t881.subappl = 'CS'
  //                                                                                  end of bbrCC1911


{
  // GroupCurrency

  case
  // ledger currency is irrelevant

      when t881.curt2 = '30'
          then _SAPClient.GroupCurrency
  // ledger currency

      else t881.gcurr // use even if initial

  end                                               as GroupCurrency,

  tfin010.dimen                                     as ConsolidationDimension,
  tfin010.bunit                                     as ConsolidationUnit,

  tf200.rvers                                       as ConsolidationVersion,
  tf200.impvs                                       as FSItemMappingVersion,

  I_CompanyCode.ChartOfAccounts                     as ReferenceChartOfAccounts,

  t881.rldnr                                        as ConsolidationLedger,

  //I_CnsldtnUnitByTimeVersion.DocumentEntryIsInGroupCurrency,

  //tf168.curr_group_send               as CnsldtnUnitGroupCrcySource,

  //I_CnsldtnUnitByTimeVersion.CnsldtnUnitLocalCrcySource,


  Source.FiscalPeriod,
  Source.LedgerFiscalYear                           as FiscalYear,
  cast(Source.FiscalYearPeriod as fins_fyearperiod) as FiscalYearPeriod,

  // mandatory standard fields

  Source.PartnerCompany,
  Source.TransactionCurrency                        as BalanceTransactionCurrency,
  Source.CostSourceUnit                             as BaseUnit,
  Source.FinancialTransactionType,
  Source.FunctionalArea,
  Source.BusinessArea,
  Source.CostCenter,
  Source.GLAccount,
  Source.ProfitCenter,
  Source.AmountInTransactionCurrency                as AmountInTransactionCurrency,
  Source.AmountInCompanyCodeCurrency                as AmountInLocalCurrency,
  Source.AmountInGlobalCurrency                     as AmountInGroupCurrency,
  Source.ValuationQuantity                          as QuantityInBaseUnit,
  Source.AmountInFreeDefinedCurrency1               as osl,
  Source.AmountInFreeDefinedCurrency2               as vsl,
  Source.AmountInFreeDefinedCurrency3               as bsl,
  Source.AmountInFreeDefinedCurrency4               as csl,
  Source.AmountInFreeDefinedCurrency5               as dsl,
  Source.AmountInFreeDefinedCurrency6               as esl,
  Source.AmountInFreeDefinedCurrency7               as fsl,
  Source.AmountInFreeDefinedCurrency8               as gsl,
  Source.Segment,

  // public sector (industry specific)

  Source.FinancialManagementArea,
  Source.GrantID,
  Source.Fund,

  // specific fileds for this cds view

  Source.FinPlngEntryItemCrtnDateTime,
  Source.AmountInCompanyCodeCurrency,
  Source.CompanyCodeCurrency,
  Source.AmountInGlobalCurrency,
  Source.GlobalCurrency,
  Source.FinancialPlanningReqTransSqnc,
  Source.FinancialPlanningDataPacket,
  Source.FinancialPlanningEntryItem,
  cast('000000000000000' as timestamp)              as const_zero

}