P_PlanBalFlowDateFunc2

 @AbapCatalog.entityBuffer.definitionAllowed: false
 @AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST, #UNION]
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@VDM.private:true
@Metadata.ignorePropagatedAnnotations: true
define view entity P_PlanBalFlowDateFunc2 as select from I_FinancialPlanningEntryItem as I_FinancialPlanningEntryItem                                                              
              inner join   I_FiscalDateFunctionValue     on       I_FiscalDateFunctionValue.FiscalYearVariant        = I_FinancialPlanningEntryItem.FiscalYearVariant
                                                              and I_FiscalDateFunctionValue.DateFunctionValidityDate = $session.system_date
                                                              and I_FiscalDateFunctionValue.DateFunctionStartDate   <= I_FinancialPlanningEntryItem.PostingDate
                                                              and I_FiscalDateFunctionValue.DateFunctionEndDate     >= I_FinancialPlanningEntryItem.PostingDate                                                                
                                                         
{
key cast( 'P' as fis_actual_plan_code preserving type )   as ActualPlanCode,
key I_FinancialPlanningEntryItem.PlanningCategory,
key I_FinancialPlanningEntryItem.Ledger,
key I_FinancialPlanningEntryItem.CompanyCode,
key I_FiscalDateFunctionValue.DateFunction,
key I_FinancialPlanningEntryItem.FiscalYearPeriod,  
key cast(cast( '2         ' as abap.char(10) ) as fis_glaccount_flow_type preserving type )   as GLAccountFlowType,      

// *************    


   I_FinancialPlanningEntryItem.FiscalYearVariant,
   I_FinancialPlanningEntryItem.LedgerFiscalYear,
   I_FinancialPlanningEntryItem.FiscalYear,

   I_FinancialPlanningEntryItem.FiscalPeriod,                                                               
   I_FinancialPlanningEntryItem.PostingDate,
   
   I_FinancialPlanningEntryItem.ChartOfAccounts,
   I_FinancialPlanningEntryItem.GLAccount,
   
   I_FinancialPlanningEntryItem.ControllingArea,
   I_FinancialPlanningEntryItem.CostCenter,
   I_FinancialPlanningEntryItem.ProfitCenter,
   I_FinancialPlanningEntryItem.FunctionalArea,
   I_FinancialPlanningEntryItem.BusinessArea,
   I_FinancialPlanningEntryItem.Segment,
   
// use Sold...   

   I_FinancialPlanningEntryItem.Product,           // MATNR

   I_FinancialPlanningEntryItem.ProductGroup,      // MATKL_MM 

   
   I_FinancialPlanningEntryItem.SoldProduct,       // MATNR_COPA

   I_FinancialPlanningEntryItem.SoldProductGroup,  // MATKL

   
   I_FinancialPlanningEntryItem.Customer,
   I_FinancialPlanningEntryItem.CustomerGroup,   

   cast( '          ' as md_supplier preserving type ) as Supplier,         
   
   @ObjectModel.foreignKey.association: '_GlobalCurrency'
   I_FinancialPlanningEntryItem.GlobalCurrency,
   @Aggregation.default: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
   I_FinancialPlanningEntryItem.AmountInGlobalCurrency,
   @Aggregation.default: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
   I_FinancialPlanningEntryItem.FixedAmountInGlobalCrcy,   
   
   @Aggregation.default: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }         
   I_FinancialPlanningEntryItem.AmountInGlobalCurrency as KslwoBCF,
      
   @Aggregation.default: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }        
   cast (0 as fis_ksl) as KslonlyBCF,    
   
   I_FinancialPlanningEntryItem._GlobalCurrency,
   I_FinancialPlanningEntryItem._FiscalCalendarDate,
   I_FinancialPlanningEntryItem._GLAccountInChartOfAccounts,
   I_FinancialPlanningEntryItem._FiscalYearVariant     
                                     
}