P_PlanBalFlowDateFunc

 @AbapCatalog.entityBuffer.definitionAllowed: false
 @AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST, #UNION]
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@VDM.private:true
@Metadata.ignorePropagatedAnnotations: true
define view entity P_PlanBalFlowDateFunc as select from I_FinancialPlanningEntryItem as I_FinancialPlanningEntryItem
              inner join   P_FiscalDateFunctionValueFY   on (     P_FiscalDateFunctionValueFY.FiscalYearVariant        = I_FinancialPlanningEntryItem.FiscalYearVariant
                                                              and P_FiscalDateFunctionValueFY.DateFunctionValidityDate = $session.system_date
                                                              and P_FiscalDateFunctionValueFY.FiscalYearStartDate     <= I_FinancialPlanningEntryItem.PostingDate
                                                              and P_FiscalDateFunctionValueFY.DateFunctionEndDate     >= I_FinancialPlanningEntryItem.PostingDate )
                                                         or (     P_FiscalDateFunctionValueFY.FiscalYearVariant        = I_FinancialPlanningEntryItem.FiscalYearVariant 
                                                              and P_FiscalDateFunctionValueFY.DateFunctionValidityDate = $session.system_date
                                                              and P_FiscalDateFunctionValueFY.StartFiscalYear         <= I_FinancialPlanningEntryItem.LedgerFiscalYear
                                                              and P_FiscalDateFunctionValueFY.EndFiscalYear           >= I_FinancialPlanningEntryItem.LedgerFiscalYear 
                                                              and                                                        I_FinancialPlanningEntryItem.FiscalPeriod = '000' )
{
key cast( 'P' as fis_actual_plan_code preserving type )   as ActualPlanCode,
key I_FinancialPlanningEntryItem.PlanningCategory,
key I_FinancialPlanningEntryItem.Ledger,
key I_FinancialPlanningEntryItem.CompanyCode,
key P_FiscalDateFunctionValueFY.DateFunction,
key I_FinancialPlanningEntryItem.FiscalYearPeriod,  
key cast(cast( '2         ' as abap.char(10) ) as fis_glaccount_flow_type preserving type )   as GLAccountFlowType,       

// *************    


   I_FinancialPlanningEntryItem.FiscalYearVariant,
   I_FinancialPlanningEntryItem.LedgerFiscalYear,
   I_FinancialPlanningEntryItem.FiscalYear,

   I_FinancialPlanningEntryItem.FiscalPeriod,                                                               
   I_FinancialPlanningEntryItem.PostingDate,
   
   I_FinancialPlanningEntryItem.ChartOfAccounts,
   I_FinancialPlanningEntryItem.GLAccount,
   
   I_FinancialPlanningEntryItem.ControllingArea,
   I_FinancialPlanningEntryItem.CostCenter,
   I_FinancialPlanningEntryItem.ProfitCenter,
   I_FinancialPlanningEntryItem.FunctionalArea,
   I_FinancialPlanningEntryItem.BusinessArea,
   I_FinancialPlanningEntryItem.Segment,
   
// use Sold...   

   I_FinancialPlanningEntryItem.Product,           // MATNR

   I_FinancialPlanningEntryItem.ProductGroup,      // MATKL_MM 

   
   I_FinancialPlanningEntryItem.SoldProduct,       // MATNR_COPA

   I_FinancialPlanningEntryItem.SoldProductGroup,  // MATKL

   
   I_FinancialPlanningEntryItem.Customer,
   I_FinancialPlanningEntryItem.CustomerGroup,   
   
   I_FinancialPlanningEntryItem.OrderID,
   I_FinancialPlanningEntryItem.SalesDocument,

   cast( '          ' as md_supplier preserving type ) as Supplier,    
   
   @ObjectModel.foreignKey.association: '_GlobalCurrency'
   I_FinancialPlanningEntryItem.GlobalCurrency,
   @Aggregation.default: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
   I_FinancialPlanningEntryItem.AmountInGlobalCurrency,
   @Aggregation.default: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
   I_FinancialPlanningEntryItem.FixedAmountInGlobalCrcy,   
   
   @Aggregation.default: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }        
   case when I_FinancialPlanningEntryItem.PostingDate <> '00000000' then I_FinancialPlanningEntryItem.AmountInGlobalCurrency    
                                       else cast (0 as fis_ksl)
   end
   as KslwoBCF,
      
   @Aggregation.default: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }        
   case when I_FinancialPlanningEntryItem.PostingDate = '00000000' then I_FinancialPlanningEntryItem.AmountInGlobalCurrency    
                                      else cast (0 as fis_ksl)
   end
   as KslonlyBCF,     
   
   I_FinancialPlanningEntryItem._GlobalCurrency,
   I_FinancialPlanningEntryItem._FiscalCalendarDate,
   I_FinancialPlanningEntryItem._GLAccountInChartOfAccounts,
   I_FinancialPlanningEntryItem._FiscalYearVariant     
                                     
}