P_PctrChangeDocItem

@AbapCatalog.sqlViewName: 'PFIPCTRCHGDOCIT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Profit Center Change Document Item'
@VDM.private: true
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_PctrChangeDocItem
  as select from I_ChangeDocumentItem

  association [0..1] to P_PctrChangeDocument  as _ProfitCenterChangeDocument on  $projection.ChangeDocObjectClass = _ProfitCenterChangeDocument.ChangeDocObjectClass
                                                                             and $projection.ChangeDocObject      = _ProfitCenterChangeDocument.ChangeDocObject
                                                                             and $projection.ChangeDocument       = _ProfitCenterChangeDocument.ChangeDocument

  association [0..1] to I_ChangeDocChangeIndT as _ChgDocItemChangeTypeText   on  _ChgDocItemChangeTypeText.Value    = $projection.ChangeDocItemChangeType
                                                                             and _ChgDocItemChangeTypeText.Language = $session.system_language

{
  key I_ChangeDocumentItem.ChangeDocObject,
  key I_ChangeDocumentItem.ChangeDocObjectClass,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.DatabaseTable,
  key I_ChangeDocumentItem.ChangeDocTableKey,
  key I_ChangeDocumentItem.ChangeDocDatabaseTableField,
  key I_ChangeDocumentItem.ChangeDocItemChangeType,
      _ChgDocItemChangeTypeText.Text                                                                   as ChangeDocItemChangeTypeText,
      I_ChangeDocumentItem.ChangeDocPreviousUnit,
      I_ChangeDocumentItem.ChangeDocNewUnit,
      I_ChangeDocumentItem.ChangeDocPreviousCurrency,
      I_ChangeDocumentItem.ChangeDocNewCurrency,
      cast ( I_ChangeDocumentItem.ChangeDocPreviousFieldValue as fis_cc_old_fieldval preserving type ) as ChangeDocPreviousFieldValue,
      cast ( I_ChangeDocumentItem.ChangeDocNewFieldValue as fis_cc_new_fieldval preserving type )      as ChangeDocNewFieldValue,

      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 1, 3) as mandt )                        as ChangeDocumentSAPClient,
      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 4, 4) as kokrs )                        as ControllingArea, //ChangeDocumentControllingArea,

      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 8, 10) as prctr )                       as ProfitCenter, //ChangeDocumentProfitCenter,

      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 18, 8) as fis_cc_datbis )               as ValidityEndDate, //ChangeDocumentValidityEndDate,

      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 26, 8) as fis_cc_datab )                as ValidityStartDate, //ChangeDocValidityStartDate,


      I_ChangeDocumentItem.ChangeDocDatabaseTableField                                                 as DatabaseTableFieldName,
      I_ChangeDocumentItem.DatabaseTable                                                               as ObjectDatabaseTable,

      _ProfitCenterChangeDocument,
      _ChgDocItemChangeTypeText

}
where
      I_ChangeDocumentItem.ChangeDocObjectClass        =  'PRCTR'
  // We need the KEY items to identify which records are 'history' records.

  and I_ChangeDocumentItem.ChangeDocDatabaseTableField <> 'KEY'