P_PPH_MRP_MAT

@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC
@VDM.private: true
define view entity P_PPH_MRP_MAT
  as select from           pph_dbvm                      as d
    left outer join        pphdbvmset                    as s   on  s.matnr = d.matnr
                                                                and s.werks = d.werks
    left outer join        pph_mrp_issues                as i   on  i.matnr = d.matnr
                                                                and i.werks = d.werks
                                                                and i.berid = d.berid
    left outer to one join I_MRPMasterDataIssueCatAssgmt as cat on  cat.SystemMessageIdentification = i.msgid
                                                                and cat.SystemMessageNumber         = i.msgno
{
  key d.matnr,
  key d.werks,
  key d.berid,
  key coalesce( i.source_of_issue, 'H')            as source_of_issue, -- Hana MRP doees not write success message
  key coalesce( i.counter, 0 )                     as counter,
      coalesce(cat.MRPMasterDataIssueCategory,'I') as issue_category,
      i.log_uuid,
      coalesce(i.timestamp,d.dstmp)                as message_timestamp,
      d.dstmp                                      as MRP_timestamp,
      coalesce(i.msgid,'PPH_MRP')                  as msgid, -- nothing found --> last time planned successfully
      coalesce(i.msgty,'I')                        as msgty,
      case when d.dstmp > 0 then coalesce(i.msgno,'130')
                            else coalesce(i.msgno,'131')
      end                                          as msgno,
      i.msgv1,
      i.msgv2,
      i.msgv3,
      i.msgv4,
      s.plan_in_abap,
      s.planned_in_hana,
      s.planned_in_abap,
      s.planned_in_ppds
}
where
      d.plscn    = '000'
  and d.sc_empty = ''
  and d.nodisp   = ''