P_PL_SAFTInvcHeaderBscVersion2

@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking : #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #P
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED

define view entity P_PL_SAFTInvcHeaderBscVersion2
   with parameters
    P_StartDate : datum,
    P_EndDate   : datum
  as select from I_JournalEntry            as Entry
    inner join   I_OperationalAcctgDocItem as Item       on  Item.CompanyCode          = Entry.CompanyCode
                                                         and Item.AccountingDocument   = Entry.AccountingDocument
                                                         and Item.FiscalYear           = Entry.FiscalYear
                                                         and Item.FinancialAccountType = 'D'

//    inner join   P_PL_SAFTMapTaxCode       as MapTaxCode on  Entry.CompanyCode        = MapTaxCode.CompanyCode

//                                                         and Entry.FiscalYear         = MapTaxCode.FiscalYear

//                                                         and Entry.AccountingDocument = MapTaxCode.AccountingDocument

                                                         
   inner join   P_PL_SAFTINVOICETAXD       as Tax  on  Tax.CompanyCode        = Item.CompanyCode
                                                   and Tax.AccountingDocument = Item.AccountingDocument
                                                   and Tax.FiscalYear         = Item.FiscalYear
                                                   and Tax.TaxCode            = Item.TaxCode
    

  association [0..1] to I_JournalEntryItemOneTimeData as _OneTimeAccountBP on  $projection.CompanyCode            = _OneTimeAccountBP.CompanyCode
                                                                and $projection.FiscalYear             = _OneTimeAccountBP.FiscalYear
                                                                and $projection.AccountingDocument     = _OneTimeAccountBP.AccountingDocument
                                                                and $projection.AccountingDocumentItem = _OneTimeAccountBP.AccountingDocumentItem

{
  key Entry.CompanyCode,
  key Entry.AccountingDocument,
  key Entry.FiscalYear,
  key max(Item.AccountingDocumentItem)                 as AccountingDocumentItem,

      Entry.BusinessTransactionType,

      Entry.TaxReportingDate,
      Entry.PostingDate,
      Entry.DocumentDate,
      Entry.ReferenceDocumentType,

      Entry.TransactionCurrency,
      Entry.CompanyCodeCurrency,

      Entry.DocumentReferenceID,
      Entry.AlternativeReferenceDocument,

      Item.Customer,
      Item.Supplier,

      Item.DocumentItemText,

      Item.InvoiceReference,
      Item.InvoiceReferenceFiscalYear,
      
      Item.BillingDocument,

      Item.IsEUTriangularDeal,

      Item.VATRegistration,
      Item.TaxCountry,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      sum (Item.AmountInTransactionCurrency) * -1 as AmountInTransactionCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      sum(Item.AmountInCompanyCodeCurrency) * -1 as AmountInCompanyCodeCurrency,

      Entry._CompanyCode,
      Item._Customer,
      Item._Supplier,
      _OneTimeAccountBP
}
where
          Entry.TaxReportingDate        between $parameters.P_StartDate and $parameters.P_EndDate
  and(
          Entry.BusinessTransactionType = 'SD00'
    or    Entry.BusinessTransactionType = 'RFBU'
  )
  and(
    (
          Item.Supplier                is not null
      and Item.Supplier                is not initial
    )
    or(
          Item.Customer                is not null
      and Item.Customer                is not initial
    )
  )
group by
  Entry.CompanyCode,
  Entry.AccountingDocument,
  Entry.FiscalYear,
  Entry.BusinessTransactionType,
  Entry.TaxReportingDate,
  Entry.PostingDate,
  Entry.DocumentDate,
  Entry.TransactionCurrency,
  Entry.CompanyCodeCurrency,
  Entry.DocumentReferenceID,
  Entry.AlternativeReferenceDocument,
  Entry.ReferenceDocumentType,
  Item.Customer,
  Item.Supplier,
  Item.DocumentItemText,
  Item.InvoiceReference,
  Item.InvoiceReferenceFiscalYear,
  Item.BillingDocument,
  Item.IsEUTriangularDeal,
  Item.TaxCountry,
  Item.VATRegistration