P_PH_JournalEntrySum

DDL: P_PH_JOURNALENTRYSUM SQL: PPHCASJRNLENTRY Type: view CONSUMPTION Package: GLO_FIN_IS_PH

PH CAS Journal Entry Balance Sum

P_PH_JournalEntrySum is a Consumption CDS View that provides data about "PH CAS Journal Entry Balance Sum" in SAP S/4HANA. It reads from 1 data source (I_GLAccountLineItem) and exposes 17 fields with key fields CompanyCode, Ledger, FiscalYear, FiscalPeriod, AccountingDocument. It has 1 association to related views. Part of development package GLO_FIN_IS_PH.

1 data source(s) 17 fields

Data Sources (1)

SourceAliasJoin Type
I_GLAccountLineItem JournalEntryItem from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_AccountingDocumentTypeText _AccountingDocumentTypeText JournalEntryItem.AccountingDocumentType = _AccountingDocumentTypeText.AccountingDocumentType and _AccountingDocumentTypeText.Language = $session.system_language

Annotations (6)

NameValueLevelField
AbapCatalog.sqlViewName PPHCASJRNLENTRY view
VDM.viewType #CONSUMPTION view
VDM.private true view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #NOT_REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY CompanyCode CompanyCode
KEY Ledger Ledger
KEY FiscalYear FiscalYear
KEY FiscalPeriod FiscalPeriod
KEY AccountingDocument AccountingDocument
KEY GLAccount GLAccount
PostingDate PostingDate
ChartOfAccounts ChartOfAccounts
OriginalReferenceDocument
TaxCode TaxCode
AccountingDocumentType AccountingDocumentType
AccountingDocumentTypeName _AccountingDocumentTypeText AccountingDocumentTypeName
DocumentItemText DocumentItemText
CompanyCodeCurrency I_GLAccountLineItem CompanyCodeCurrency
DebitAmountInCoCodeCrcy
CreditAmountInCoCodeCrcy
AmountInCompanyCodeCurrency 
@AbapCatalog.sqlViewName: 'PPHCASJRNLENTRY'
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_PH_JournalEntrySum

  as select from I_GLAccountLineItem as JournalEntryItem

  association [0..1] to I_AccountingDocumentTypeText as _AccountingDocumentTypeText on  JournalEntryItem.AccountingDocumentType = _AccountingDocumentTypeText.AccountingDocumentType
                                                                                    and _AccountingDocumentTypeText.Language    = $session.system_language
{
  key CompanyCode,
  key Ledger,
  key FiscalYear,
  key FiscalPeriod,
  key AccountingDocument,
  key GLAccount,

      PostingDate,
      ChartOfAccounts,
      case when JournalEntryItem._JournalEntry.DocumentReferenceID  = '0000000000000000'
      then ''
      else JournalEntryItem._JournalEntry.DocumentReferenceID
      end                                                              as DocumentReferenceID,
      LEFT(JournalEntryItem._JournalEntry.OriginalReferenceDocument,10) as OriginalReferenceDocument,
      TaxCode,
      AccountingDocumentType,
      _AccountingDocumentTypeText.AccountingDocumentTypeName,
      DocumentItemText,

      @Semantics.currencyCode: true
      JournalEntryItem.CompanyCodeCurrency,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      sum(DebitAmountInCoCodeCrcy)                                      as DebitAmountInCoCodeCrcy,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      sum(CreditAmountInCoCodeCrcy)                                     as CreditAmountInCoCodeCrcy,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      sum(AmountInCompanyCodeCurrency)                                  as AmountInCompanyCodeCurrency

}

group by
  CompanyCode,
  Ledger,
  FiscalYear,
  FiscalPeriod,
  AccountingDocument,
  DocumentItemText,
  GLAccount,
  PostingDate,
  ChartOfAccounts,
  AccountingDocumentType,
  _AccountingDocumentTypeText.AccountingDocumentTypeName,
  JournalEntryItem.CompanyCodeCurrency,
  TaxCode,
  JournalEntryItem._JournalEntry.DocumentReferenceID,
  JournalEntryItem._JournalEntry.OriginalReferenceDocument

Learn More