P_PCPrptyApplicabiltyNone

@AbapCatalog:
{
  -- SQL view name (16 characters)
  sqlViewName: 'PPCPRAPPLNONE',

  --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true
}

-- Access Control: Authorizations Checks
@AccessControl:
{
  // authorization check not required as view only reads domain values

  authorizationCheck: #NOT_REQUIRED
}

-- Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

-- VDM view type
@VDM.viewType: #BASIC

@VDM.private: true

@ObjectModel:
{

  --Performance Annotations
  usageType:
  {
    dataClass: #META,
    sizeCategory: #S,
    serviceQuality: #B
  },
  representativeKey: 'ProdCmplncPhrs'
}

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] } */
define view P_PCPrptyApplicabiltyNone
  -- Select data from domain value table
  as select from dd07l as PCPrptyAppl

  -- Text association
  association [0..*] to P_PCPrptyApplicabiltyNoneText as _Text on $projection.ProdCmplncPhrs = _Text.ProdCmplncPhrs

{
  key cast(hextobin('00000000000000000000000000000000')
    as ehfnd_phrs_uuid preserving type)                                as ProdCmplncPhrsUUID,

      @ObjectModel.text.association: '_Text'
  key PCPrptyAppl.domvalue_l                                           as ProdCmplncPhrs,

      _Text[1: Language = $session.system_language].ProdCmplncPhrsText as ProdCmplncPhrsText,

      /*Association*/
      _Text
}

where PCPrptyAppl.domname  = 'EHFND_APPLICABILTY_NONE'
  and PCPrptyAppl.as4local = 'A'