P_PCCTargetCostByLdgr

DDL: P_PCCTARGETCOSTBYLDGR Type: view_entity COMPOSITE Package: FINS_PCC_RTPC_REM

Target Cost by Ledger for PCC

P_PCCTargetCostByLdgr is a Composite CDS View that provides data about "Target Cost by Ledger for PCC" in SAP S/4HANA. It reads from 2 data sources (I_MfgOrdPlngCat, I_FinancialPlanningEntryItem) and exposes 43 fields with key fields Ledger, CompanyCode, GLAccount, BusinessTransactionType, ControllingDebitCreditCode. Part of development package FINS_PCC_RTPC_REM.

2 data source(s) 43 fields

Data Sources (2)

SourceAliasJoin Type
I_MfgOrdPlngCat _MfgOrdPlngCat inner
I_FinancialPlanningEntryItem _PlanningEntryItem from

Parameters (1)

NameTypeDefault
P_Ledger fins_ledger

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #COMPOSITE view
VDM.private true view

Fields (43)

KeyFieldSource TableSource FieldDescription
KEY Ledger I_FinancialPlanningEntryItem Ledger
KEY CompanyCode I_FinancialPlanningEntryItem CompanyCode
KEY GLAccount I_FinancialPlanningEntryItem GLAccount
KEY BusinessTransactionType I_FinancialPlanningEntryItem BusinessTransactionType
KEY ControllingDebitCreditCode I_FinancialPlanningEntryItem ControllingDebitCreditCode
KEY PartnerAccountAssignmentType I_FinancialPlanningEntryItem PartnerAccountAssignmentType
KEY PartnerCostCenter I_FinancialPlanningEntryItem PartnerCostCenter
KEY PartnerCostCtrActivityType I_FinancialPlanningEntryItem PartnerCostCtrActivityType
KEY PartnerOrder I_FinancialPlanningEntryItem PartnerOrder
KEY CostSourceUnit I_FinancialPlanningEntryItem CostSourceUnit
KEY ProducedProduct I_FinancialPlanningEntryItem ProducedProduct
KEY Material I_FinancialPlanningEntryItem Material
KEY WorkCenterInternalID I_FinancialPlanningEntryItem WorkCenterInternalID
KEY OrderOperation I_FinancialPlanningEntryItem OrderOperation
KEY Plant I_FinancialPlanningEntryItem Plant
KEY CostingLotSize I_FinancialPlanningEntryItem CostingLotSize
KEY LotSizeUnit I_FinancialPlanningEntryItem LotSizeUnit
KEY ControllingArea I_FinancialPlanningEntryItem ControllingArea
KEY CostEstimateValidityStartDate I_FinancialPlanningEntryItem CostEstimateValidityStartDate
KEY CostEstimateValidityEndDate I_FinancialPlanningEntryItem CostEstimateValidityEndDate
KEY IsLotSizeIndependent I_FinancialPlanningEntryItem IsLotSizeIndependent
AmountInGlobalCurrency
FixedAmountInGlobalCurrency
AmountInCompanyCodeCurrency
AmountInFreeDefinedCurrency1
AmountInFreeDefinedCurrency2
AmountInFreeDefinedCurrency3
AmountInFreeDefinedCurrency4
AmountInFreeDefinedCurrency5
AmountInFreeDefinedCurrency6
AmountInFreeDefinedCurrency7
AmountInFreeDefinedCurrency8
TotalQuantity
CompanyCodeCurrency I_FinancialPlanningEntryItem CompanyCodeCurrency
GlobalCurrency I_FinancialPlanningEntryItem GlobalCurrency
FreeDefinedCurrency1 I_FinancialPlanningEntryItem FreeDefinedCurrency1
FreeDefinedCurrency2 I_FinancialPlanningEntryItem FreeDefinedCurrency2
FreeDefinedCurrency3 I_FinancialPlanningEntryItem FreeDefinedCurrency3
FreeDefinedCurrency4 I_FinancialPlanningEntryItem FreeDefinedCurrency4
FreeDefinedCurrency5 I_FinancialPlanningEntryItem FreeDefinedCurrency5
FreeDefinedCurrency6 I_FinancialPlanningEntryItem FreeDefinedCurrency6
FreeDefinedCurrency7 I_FinancialPlanningEntryItem FreeDefinedCurrency7
FreeDefinedCurrency8 I_FinancialPlanningEntryItem FreeDefinedCurrency8 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
@VDM.private: true

define view entity P_PCCTargetCostByLdgr
  with parameters
    P_Ledger : fins_ledger
  as select from I_FinancialPlanningEntryItem as _PlanningEntryItem
    inner join   I_MfgOrdPlngCat              as _MfgOrdPlngCat on _MfgOrdPlngCat.PlanningCategory = _PlanningEntryItem.PlanningCategory
{  
  key  _PlanningEntryItem.Ledger,
  key  _PlanningEntryItem.CompanyCode,
  key  _PlanningEntryItem.GLAccount,                         
  key  _PlanningEntryItem.BusinessTransactionType,
  key  _PlanningEntryItem.ControllingDebitCreditCode,  
  key  _PlanningEntryItem.PartnerAccountAssignmentType,
  key  _PlanningEntryItem.PartnerCostCenter,
  key  _PlanningEntryItem.PartnerCostCtrActivityType,
  key  _PlanningEntryItem.PartnerOrder,
  key  _PlanningEntryItem.CostSourceUnit,
  key  _PlanningEntryItem.ProducedProduct,
  key  _PlanningEntryItem.Material,
  key  _PlanningEntryItem.WorkCenterInternalID,
  key  _PlanningEntryItem.OrderOperation,
  key  _PlanningEntryItem.Plant,
        @Semantics: { quantity : {unitOfMeasure: 'LotSizeUnit'} } 
  key  _PlanningEntryItem.CostingLotSize,
  key  _PlanningEntryItem.LotSizeUnit,
  key  _PlanningEntryItem.ControllingArea,
  key  _PlanningEntryItem.CostEstimateValidityStartDate,
  key  _PlanningEntryItem.CostEstimateValidityEndDate,
  key  _PlanningEntryItem.IsLotSizeIndependent,
              
       @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }           
       sum(_PlanningEntryItem.AmountInGlobalCurrency)       as AmountInGlobalCurrency,      
       @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
       sum(_PlanningEntryItem.FixedAmountInGlobalCrcy)      as FixedAmountInGlobalCurrency,       
       @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }  
       sum(_PlanningEntryItem.AmountInCompanyCodeCurrency)  as AmountInCompanyCodeCurrency,       
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
       sum(_PlanningEntryItem.AmountInFreeDefinedCurrency1) as AmountInFreeDefinedCurrency1,       
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }       
       sum(_PlanningEntryItem.AmountInFreeDefinedCurrency2) as AmountInFreeDefinedCurrency2,       
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }          
       sum(_PlanningEntryItem.AmountInFreeDefinedCurrency3) as AmountInFreeDefinedCurrency3,       
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }          
       sum(_PlanningEntryItem.AmountInFreeDefinedCurrency4) as AmountInFreeDefinedCurrency4,       
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }          
       sum(_PlanningEntryItem.AmountInFreeDefinedCurrency5) as AmountInFreeDefinedCurrency5,       
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }          
       sum(_PlanningEntryItem.AmountInFreeDefinedCurrency6) as AmountInFreeDefinedCurrency6,       
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }          
       sum(_PlanningEntryItem.AmountInFreeDefinedCurrency7) as AmountInFreeDefinedCurrency7,       
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }          
       sum(_PlanningEntryItem.AmountInFreeDefinedCurrency8) as AmountInFreeDefinedCurrency8,

       //Quantity       

       @Semantics: { quantity : {unitOfMeasure: 'CostSourceUnit'} }         
       sum(_PlanningEntryItem.ValuationQuantity)            as TotalQuantity,                                             
       
       _PlanningEntryItem.CompanyCodeCurrency,
       _PlanningEntryItem.GlobalCurrency,
       _PlanningEntryItem.FreeDefinedCurrency1,
       _PlanningEntryItem.FreeDefinedCurrency2,
       _PlanningEntryItem.FreeDefinedCurrency3,
       _PlanningEntryItem.FreeDefinedCurrency4,
       _PlanningEntryItem.FreeDefinedCurrency5,
       _PlanningEntryItem.FreeDefinedCurrency6,
       _PlanningEntryItem.FreeDefinedCurrency7,
       _PlanningEntryItem.FreeDefinedCurrency8       
}
where
      _PlanningEntryItem.Ledger                     =  $parameters.P_Ledger
  and _MfgOrdPlngCat.PlngCatIsForMatlCostEstPlnCost =  'X'
  and _PlanningEntryItem.OrderID                    is initial  
  and _PlanningEntryItem.ProducedProduct            is not initial
group by
  _PlanningEntryItem.Ledger,
  _PlanningEntryItem.CompanyCode,
  _PlanningEntryItem.GLAccount,
  _PlanningEntryItem.BusinessTransactionType,
  _PlanningEntryItem.ControllingDebitCreditCode,
  _PlanningEntryItem.AccountAssignmentType,
  _PlanningEntryItem.PartnerAccountAssignmentType,
  _PlanningEntryItem.PartnerCostCenter,
  _PlanningEntryItem.PartnerCostCtrActivityType,
  _PlanningEntryItem.PartnerOrder,
  _PlanningEntryItem.CostSourceUnit,
  _PlanningEntryItem.ProducedProduct,
  _PlanningEntryItem.Material,
  _PlanningEntryItem.WorkCenterInternalID,
  _PlanningEntryItem.OrderOperation,
  _PlanningEntryItem.Plant,
  _PlanningEntryItem.ControllingArea,
  _PlanningEntryItem.CostingLotSize,
  _PlanningEntryItem.LotSizeUnit,
  _PlanningEntryItem.IsLotSizeIndependent, 
  _PlanningEntryItem.CostEstimateValidityStartDate, 
  _PlanningEntryItem.CostEstimateValidityEndDate,
  _PlanningEntryItem.GlobalCurrency,
  _PlanningEntryItem.CompanyCodeCurrency,  
  _PlanningEntryItem.FreeDefinedCurrency1,
  _PlanningEntryItem.FreeDefinedCurrency2,
  _PlanningEntryItem.FreeDefinedCurrency3,
  _PlanningEntryItem.FreeDefinedCurrency4,
  _PlanningEntryItem.FreeDefinedCurrency5,
  _PlanningEntryItem.FreeDefinedCurrency6,
  _PlanningEntryItem.FreeDefinedCurrency7,
  _PlanningEntryItem.FreeDefinedCurrency8

Learn More