P_OrderOpCompStatusBasic

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@VDM.private: true
// provides the non-aggregated component status

// to be used in aggregation views such as P_OrderOpCompStatusBasicAggrgn only


/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define view entity P_OrderOpCompStatusBasic
  as select from I_StatusObjectStatusBasic as jest
  
  association [0..1] to I_StatusCode as _ComponentIsCreatedCode        on  _ComponentIsCreatedCode.StatusCode    = 'I0001'
                                                                       and _ComponentIsCreatedCode.StatusProfile = ''
  association [0..1] to I_StatusCode as _ComponentIsReleasedCode       on  _ComponentIsReleasedCode.StatusCode    = 'I0002'
                                                                       and _ComponentIsReleasedCode.StatusProfile = ''
  association [0..1] to I_StatusCode as _ComponentIsPrintedCode        on  _ComponentIsPrintedCode.StatusCode    = 'I0007'
                                                                       and _ComponentIsPrintedCode.StatusProfile = ''           
  association [0..1] to I_StatusCode as _ComponentIsDeletedCode        on  _ComponentIsDeletedCode.StatusCode    = 'I0013'
                                                                       and _ComponentIsDeletedCode.StatusProfile = ''
  association [0..1] to I_StatusCode as _CompIsCreatedByOrderSplitCode on  _CompIsCreatedByOrderSplitCode.StatusCode    = 'I0487'
                                                                       and _CompIsCreatedByOrderSplitCode.StatusProfile = ''
{
    // Key

key jest.StatusObject as ObjectInternalID,

    @Semantics.booleanIndicator: true 
    case jest.StatusCode
      when 'I0001' then 'X'
      else ''
    end as MaterialComponentIsCreated,
    @Semantics.booleanIndicator: true 
    case jest.StatusCode
      when 'I0002' then 'X'
      else ''
    end as MaterialComponentIsReleased,
    @Semantics.booleanIndicator: true 
    case jest.StatusCode
      when 'I0007' then 'X'
      else ''
    end as MaterialComponentIsPrinted,
    @Semantics.booleanIndicator: true 
    case jest.StatusCode
      when 'I0013' then 'X'
      else ''
    end as MaterialComponentIsDeleted,
    @Semantics.booleanIndicator: true 
    case jest.StatusCode
      when 'I0487' then 'X'
      else ''
    end as MatlCompIsCreatedByOrderSplit,

    // Associations

    _StatusObject,
    _ComponentIsCreatedCode,
    _ComponentIsReleasedCode,
    _ComponentIsPrintedCode,
    _ComponentIsDeletedCode,
    _CompIsCreatedByOrderSplitCode
}
where
  (     jest.StatusCode       = 'I0001'
    or  jest.StatusCode       = 'I0002'
    or  jest.StatusCode       = 'I0007'
    or  jest.StatusCode       = 'I0013'
--  or  jest.StatusCode       = 'I0291' // no disp.

    or  jest.StatusCode       = 'I0487'
  ) and jest.StatusIsInactive = ' ' 
    and jest.StatusObject like 'OK%';