P_MaterialLedgerDocumentRecord

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #C,
    sizeCategory: #XXL,
    dataClass: #MIXED
}
@VDM: {
  viewType: #BASIC,
  private: true
}
--@EndUserText.label: 'Material Ledger Document Record'
define view entity P_MaterialLedgerDocumentRecord
  as select from           mldoc         as doc
    inner join             ckmlhd        as hd      on doc.kalnr = hd.kalnr
    left outer to one join mlrunlist     as _list   on doc.kalnr               =  _list.kalnr
                                                    and(
                                                      doc.jahrper              =  _list.jahrper
                                                      or(
                                                        _list.from_jahrper     <> '0000000'
                                                        and _list.from_jahrper <= doc.jahrper
                                                        and _list.jahrper      >= doc.jahrper
                                                      )
                                                    )
    left outer to one join ckmlrunperiod as _period on  _period.run_id = _list.run_id
                                                    and _period.rldnr  = doc.rldnr
{
  key doc.docref                               as MaterialLedgerDocRef,
  key doc.curtp                                as CurrencyRole,
      doc.rldnr                                as Ledger,
      cast ( doc.jahrper as fins_fyearperiod ) as FiscalYearPeriod,
      doc.xabr                                 as MatlLdgrDocIsCostingRelevant,
      doc.categ                                as MaterialLedgerCategory,
      doc.ptyp                                 as ProcessCategory, //doc.PTYP ,

      doc.kalnr                                as CostEstimate,
      hd.matnr                                 as Material,
      doc.posart                               as MaterialLedgerItemType,

      doc.bvalt                                as ProcurementAlternative, //bvalt

      doc.process                              as ProductionProcess, //doc.PROCESS,


      @Semantics.quantity.unitOfMeasure: 'ValuationQuantityUnit'
      doc.quant                                as ValuationQuantity,     //quant

      doc.meins                                as ValuationQuantityUnit, //meins

      @Semantics.amount.currencyCode: 'Currency'
      doc.stval                                as InventoryAmtInCCCrcy,  //stval

      @Semantics.amount.currencyCode: 'Currency'
      doc.prd                                  as PriceDifferenceAmtInCCCrcy,  //prd

      @Semantics.amount.currencyCode: 'Currency'
      doc.kdm                                  as ExchRateDiffAmtInCoCodeCrcy, //kdm

      doc.waers                                as Currency, //waers


      doc.aufnr                                as ProductionOrder,
      doc.eqnum                                as EquivalenceNumberOfJntProdn,

      doc.budat                                as PostingDate,
      doc.werks                                as Plant,
      doc.awtyp                                as ReferenceDocumentType,
      doc.awref                                as SourceReferenceDocument,
      doc.aworg                                as ReferenceDocumentContext,
      doc.awitem                               as ReferenceDocumentItem,
      doc.glvor                                as RefBusinessTransactionType,
      doc.vgart                                as MaterialLedgerTransactionType,
      doc.bwart                                as GoodsMovementType,
      doc.kstar                                as CostElement,
      _list.runref                             as CostingRunReference, //runref

      _period.run_id                           as CostingRun, //period.RUN_ID,

      _period.run_type                         as CostingRunType,     //preiod.RUN_TYPE,

      _period.last_day                         as LastDayOfMonthDate, //LAST_DAY,

      _period.first_day                        as FirstDayOfMonthDate //FIRST_DAY


}
where
  (
        _list.runref like 'ACT__'
    and doc.rldnr    =    substring(_list.runref,4,2)
  )