P_MY_JournalEntryItem

@AbapCatalog.sqlViewName: 'PMYJRNLENTRITM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType:#COMPOSITE
@VDM.private: true
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass:  #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
//@EndUserText.label: 'Journal Entry Item for MY GAF'

define view P_MY_JournalEntryItem as select from  I_OperationalAcctgDocItem

  {
  key CompanyCode,
  key AccountingDocument,
  key FiscalYear,
  key AccountingDocumentItem,
      concat(concat(CompanyCode, AccountingDocument),FiscalYear) as OriginRefDocBusObjTypeName,
      PostingDate,
      _JournalEntry.TaxReportingDate,
      DocumentDate,
      GLAccount,
      _GLAccountInChartOfAccounts._Text[1: Language = $session.system_language ].GLAccountName,
      _JournalEntry.AccountingDocumentHeaderText,
      _GLAccountInChartOfAccounts.ChartOfAccounts,
      _GLAccountInChartOfAccounts.GLAccountType,
      case FinancialAccountType
      when 'D' then _Customer.CustomerName
      when 'K' then _Supplier.SupplierName
      end as BusinessPartnerPhysicianName,
      case FinancialAccountType      
      when 'D' then _Customer.AuthorizationGroup
      when 'K' then _Supplier.AuthorizationGroup
      end  as AuthorizationGroup,
       case FinancialAccountType  
       when 'D' then _Customer._CustomerToBusinessPartner._BusinessPartner.IsBusinessPurposeCompleted
       when 'K' then _Supplier._SupplierToBusinessPartner._BusinessPartner.IsBusinessPurposeCompleted
      end as IsBusinessPurposeCompleted,
      OriginalReferenceDocument,
      FinancialAccountType,
      @Semantics.currencyCode: true
      TransactionCurrency,
      @Semantics.currencyCode:true
      CompanyCodeCurrency,
      @Semantics.currencyCode:true
      AdditionalCurrency1,
      @Semantics.currencyCode:true
      AdditionalCurrency2,
      DebitCreditCode,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case DebitCreditCode
      when 'S' then abs(AmountInTransactionCurrency)
      end as DebitAmountInTransCrcy,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case DebitCreditCode
      when 'H' then abs(AmountInTransactionCurrency)
      end as CreditAmountInTransCrcy,    
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      case DebitCreditCode
      when 'S' then abs(AmountInCompanyCodeCurrency)
      end as DebitAmountInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      case DebitCreditCode
      when 'H' then abs(AmountInCompanyCodeCurrency)
      end as CreditAmountInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      case DebitCreditCode
      when 'S' then abs(AmountInAdditionalCurrency1)
      end as DebitAmountInAddlCrcy1,
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      case DebitCreditCode
      when 'H' then abs(AmountInAdditionalCurrency1)
      end as CreditAmountInAddlCrcy1,
       @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      case DebitCreditCode
      when 'S' then abs(AmountInAdditionalCurrency2)
      end as DebitAmountInAddlCrcy2,
      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      case DebitCreditCode
      when 'H' then abs(AmountInAdditionalCurrency2)
      end as CreditAmountInAddlCrcy2,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(0 as figlcn_balance) as GLAcctBalanceAmt,
      $session.client                                                          as SystemClient,
      $session.system_date                                                     as SystemDate

  }