P_LogcDocDeliveryItem

@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM: {
  private: true,
  viewType: #CONSUMPTION
}

@Metadata.ignorePropagatedAnnotations: true
define view entity P_LogcDocDeliveryItem
  as select from I_DeliveryDocumentItem

  association [0..*] to I_ProductText       as _ProductText      on $projection.Product = _ProductText.Product
  // needed to redefine because of different cardinality between the union views

  association [0..*] to I_UnitOfMeasureText as _QuantityUnitText on $projection.OrderQuantityUnit = _QuantityUnitText.UnitOfMeasure

{
  key DeliveryDocument,
  key DeliveryDocumentItem,

      //SDDocumentCategory,

      // USE THE SAME LOGIC AS IN P_LogcDocDelivery

      cast ('LF' as ehfnd_log_doc_category)  as ProdCmplncLogsDocumentCategory,
      //      cast (

      //          case

      //            when PurchasingDocumentCategory = 'J'

      //              then 'LF' // Outbound Delivery (EHFND_LOG_DOC_CATEGORY)

      //          end as ehfnd_log_doc_category) as ProdCmplncLogsDocumentCategory


      @ObjectModel.text.association: '_ProductText'
      Product,

      // the actual quantity is the real quantity used for the delivery

      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ActualDeliveryQuantity                 as OrderQuantity,
      //      OriginalDeliveryQuantity,


      // @Semantics.unitOfMeasure: true

      @ObjectModel.text.association: '_QuantityUnitText'
      DeliveryQuantityUnit                   as OrderQuantityUnit,

      cast ('' as classifiedasdangerousgood) as ClassifiedAsDangerousGood,
      cast( '' as val_text)                  as ClassifiedAsDangerousGoodName,

      // needed to mark the blocked logistic document items

      cast (
          case
            when DangerousGoodsStatus = 'F' // DOM_DGSTA_LE - Blocked – Transport Forbidden

              then 'X'
            when DangerousGoodsStatus = 'G' // DOM_DGSTA_LE - Blocked – Decision Pending

              then 'X'
          end as boole_d)                    as IsBlocked,


      // Associations

      _ProductText,
      _QuantityUnitText,
      
      @ObjectModel.readOnly:true
      @Consumption.hidden: true
      _DeliveryDocument._ShippingPoint.ActiveDepartureCountry as DepartureCountry,
      
      @ObjectModel.readOnly:true
      @Consumption.hidden: true
      _DeliveryDocument._ShipToParty.Country as DestinationCountry,
      
      

      //Needed for Authorization check

      @ObjectModel.readOnly:true
      @Consumption.hidden: true
      _DeliveryDocument.ShippingPoint        as ShippingPoint

}
where
  // use only items where the Chemical Complinace Relevant Flag is true

    _Product.IsChemicalComplianceRelevant = 'Y'
  and(
    SDDocumentCategory                    = 'J'
  )