P_LglCntntMWorkflowTaskDetail

@AbapCatalog.sqlViewName: 'PLGLCNTNTMWFTD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType : #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.private: true
@ObjectModel: {
  usageType.serviceQuality: #C,
  usageType.sizeCategory: #L,
  usageType.dataClass:  #MIXED
}
@EndUserText.label: 'Legal Transaction Workflow Task Details'
define view P_LglCntntMWorkflowTaskDetail
  as select from I_LegalTransactionWorkflow

    join         I_WorkflowTaskApplObject as WorkflowTaskApplObject on  I_LegalTransactionWorkflow.LglTransWrkFlwModInstce   = WorkflowTaskApplObject.SAPBusinessObjectNodeKey1
                                                                    and WorkflowTaskApplObject.WorkflowObjectRole            = '99'
    //                                                                  SAP node type after 2008

                                                                    and (
                                                                       WorkflowTaskApplObject.SAPObjectNodeRepresentation    = 'LegalTransactionApproval'
                                                                       //                                                                  SAP node type before 2008

                                                                       or WorkflowTaskApplObject.SAPObjectNodeRepresentation = 'LegalTransaction'
                                                                     )
                                                                    and WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'
                                                                    and WorkflowTaskApplObject.WorkflowTaskInternalID        is not null
  association [0..1] to I_LglCntntMWorkflowTask     as _WorkflowTask              on  $projection.WorkflowTaskInternalID = _WorkflowTask.WorkflowTaskInternalID
                                                                                  and (
                                                                                     _WorkflowTask.WorkflowTaskType      = 'W'
                                                                                     or _WorkflowTask.WorkflowTaskType   = 'B'

                                                                                   )



  association [0..1] to I_WorkflowTaskResultComment as _WorkflowTaskResultComment on  _WorkflowTaskResultComment.WorkflowTaskInternalID = $projection.WorkflowTaskInternalID
  association [0..1] to I_User                      as _User                      on  _User.UserID = $projection.LegalTransactionTaskCurUsr
  association [0..*] to I_WorkflowStepResultText    as _WorkflowTaskStepResult    on  $projection.TopLevelWorkflowTaskDefinition = _WorkflowTaskStepResult.WorkflowScenarioDefinition
                                                                                  and $projection.WorkflowTaskDefinitionVersion  = _WorkflowTaskStepResult.WorkflowScenarioDefinitionVers
                                                                                  and $projection.WorkflowTaskStepType           = _WorkflowTaskStepResult.WorkflowStepType
                                                                                  and $projection.WorkflowTaskResult             = _WorkflowTaskStepResult.WorkflowStepResult
  association [1..1] to I_LegalTransactionBase      as _LegalTransaction          on  $projection.LegalTransactionUUID = _LegalTransaction.LegalTransactionUUID

{
  key  I_LegalTransactionWorkflow.LegalTransactionUUID,
  key  cast(WorkflowTaskApplObject.WorkflowTaskInternalID as lcm_sww_wiid)                         as LegalTransactionTask,
       WorkflowTaskApplObject.WorkflowTaskInternalID                                               as WorkflowTaskInternalID, //WorkflowTask,


       _WorkflowTask.WorkflowTaskStatus                                                            as LegalTransactionTaskStatus,

       _WorkflowTask.WorkflowTaskCreatedByUser                                                     as LegalTransactionTaskCrtedByUsr,

       _WorkflowTask.WorkflowTaskCurrentUser                                                       as LegalTransactionTaskCurUsr,

       _WorkflowTask.WrkflwTskCreationUTCDateTime                                                  as LglTransTskCrtnUTCDteTme,


       _WorkflowTask.WrkflwTskCompletionUTCDateTime                                                as LglCntntMTaskCompltnUTCDteTme,

       _WorkflowTask._TaskStatus._Text[1:Language=$session.system_language].WorkflowTaskStatusDesc as LegalTransactionTaskStatusName,


       _WorkflowTask.TopLevelWorkflowTaskDefinition                                                as TopLevelWorkflowTaskDefinition,

       _WorkflowTask.WorkflowTaskDefinitionVersion                                                 as WorkflowTaskDefinitionVersion,
       _WorkflowTask.WorkflowTaskStepType                                                          as WorkflowTaskStepType,
       _WorkflowTask.WorkflowTaskResult                                                            as WorkflowTaskResult,

       _LegalTransaction.LegalTransaction                                                          as LegalTransaction,
       _LegalTransaction.LegalTransactionTitle                                                     as LegalTransactionTitle,

       _WorkflowTaskResultComment.WorkflowTaskResultComment                                        as WorkflowTaskResultComment,

       // Associations

       _LegalTransaction,
       _User,
       _WorkflowTaskStepResult
}
where
       I_LegalTransactionWorkflow.LglTransWrkFlwModInstce <> ''
  and(
       _WorkflowTask.WorkflowTaskType                     =  'W'
    or _WorkflowTask.WorkflowTaskType                     =  'B'
  )