P_KZ_VATRetOutDoc

@AbapCatalog.sqlViewName: 'PKZVATRETOUTDOC'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@VDM.private: true
@AbapCatalog.compiler.compareFilter:true
@ClientHandling.algorithm: #SESSION_VARIABLE


define view P_KZ_VATRetOutDoc
  as select distinct from P_KZ_VATReturnSection3        as LogItems

    left outer join       P_KZ_JournalEntryItemLdngLdgr as DocumentItem    on  DocumentItem.CompanyCode        =  LogItems.CompanyCode
                                                                           and DocumentItem.AccountingDocument =  LogItems.AccountingDocument
                                                                           and DocumentItem.FiscalYear         =  LogItems.FiscalYear
                                                                           and DocumentItem.Material           <> ''
                                                                           and (
                                                                              DocumentItem.TaxCode             =  LogItems.TaxCode
                                                                              or DocumentItem.TaxCode          =  ''
                                                                            )

    left outer join       P_KZ_BillingMaterialDetails   as BillingMaterial on  BillingMaterial.BillingDocument  = LogItems.OriginalReferenceDocument
                                                                           and (
                                                                              LogItems.ReferenceDocumentType    = 'VBRK'
                                                                              or LogItems.ReferenceDocumentType = 'CF3PS'
                                                                            )
                                                                           and BillingMaterial.Material         = DocumentItem.Material



{
  //P_KZ_VATReturnSection3

  LogItems.CompanyCode,
  LogItems.AccountingDocument,
  LogItems.FiscalYear,
  LogItems.TaxCode,
  LogItems.TaxRate,
  LogItems.AmountSign,
  LogItems.NegativeSign,
  DocumentItem.AmountInCompanyCodeCurrency,
  //  case when DocumentItem.AmountInCompanyCodeCurrency is null

  //     then LogItems.TaxBaseAmountInCoCodeCrcy

  //     else DocumentItem.AmountInCompanyCodeCurrency

  //   end  as TaxBaseAmountInCoCodeCrcy,

  //

  //   case when DocumentItem.AmountInCompanyCodeCurrency is null

  //     then LogItems.TaxAmountInCoCodeCrcy

  //     else //cast( DocumentItem.AmountInCompanyCodeCurrency  as abap.fltp )  / cast( LogItems.TaxBaseAmountInCoCodeCrcy as abap.fltp )

  //            cast ( DIVISION( DocumentItem.AmountInCompanyCodeCurrency, LogItems.TaxBaseAmountInCoCodeCrcy, 2) as abap.dec( 3, 2 ) )

  //            //* cast( LogItems.TaxAmountInCoCodeCrcy as abap.fltp)

  //            * LogItems.TaxAmountInCoCodeCrcy

  //   end  as TaxAmountInCoCodeCrcy,



  LogItems.TaxBaseAmountInCoCodeCrcy,
  LogItems.TaxAmountInCoCodeCrcy,


  abs( LogItems.TaxBaseAmountInCoCodeCrcy )       as TaxBaseAmountInCoCodeCrcyABS,
  abs( DocumentItem.AmountInCompanyCodeCurrency ) as AmountInCompanyCodeCurrencyABS,



  LogItems.TaxBaseAmountInCoCodeCrcy              as TaxBaseAmountInCoCodeCrcyTot,

  LogItems.TaxAmountInCoCodeCrcy                  as TaxAmountInCoCodeCrcyTot,
  LogItems.TransactionTypeDetermination,
  LogItems.PostingDate,
  LogItems.TaxReportingDate,

  case LogItems.JrnlEntryCntrySpecificDate1
    when '' then LogItems.DocumentDate
    else LogItems.JrnlEntryCntrySpecificDate1
    end                                           as DocumentDate,

  LogItems.AccountingDocumentType,
  LogItems.IsReversal,
  LogItems.IsReversed,
  LogItems.OriginalReferenceDocument,
  LogItems.ReferenceDocumentType,
  LogItems.DocumentReferenceID,
  LogItems.BusinessTransactionType,
  LogItems.SenderLogicalSystem,
  LogItems.AccountingDocumentHeaderText,
  LogItems.AccountingDocCreatedByUser,
  LogItems.Reference1InDocumentHeader,
  LogItems.Reference2InDocumentHeader,
  LogItems.DocumentItemText,
  LogItems.CompanyCodeCurrency,
  LogItems.Currency,
  LogItems.StatryRptgEntity,
  LogItems.StatryRptCategory,
  LogItems.StatryRptRunID,
  LogItems.AccountingDocumentItem,
  LogItems.KZ_VATReturnSectionType,
  BillingMaterial.Material,
  DocumentItem.PurchasingDocument,
  DocumentItem.PurchasingDocumentItem,

  case LogItems.JrnlEntryCntrySpecificRef1
    when ''
        then case LogItems.DocumentReferenceID when ''
            then LogItems.AccountingDocument
        else LogItems.DocumentReferenceID
        end
    else LogItems.JrnlEntryCntrySpecificRef1
    end                                           as InvoiceNumber,


  case BillingMaterial.KZ_MaterialSubGroup
  when 'MIN'
   then BillingMaterial.BaseUnit
   else cast( '' as meins)
  end                                             as BaseUnit,
  @Semantics.quantity.unitOfMeasure: 'BaseUnit'

  case BillingMaterial.KZ_MaterialSubGroup
  when 'MIN'
  then  BillingMaterial.BillingQuantity
  else cast ( 0 as fkimg )
  end                                             as BillingQuantity,

  case BillingMaterial.KZ_MaterialSubGroup
  when 'MIN'
  then  BillingMaterial.MaterialName
  else ''
  end                                             as MaterialName,


  case BillingMaterial.Activity
    when '' then '1'
    else BillingMaterial.Activity
   end                                            as Activity,

  BillingMaterial.KZ_MaterialSubGroup,
  BillingMaterial.BaseUnit                        as AnalyticBaseUnit,
  @Semantics.quantity.unitOfMeasure: 'AnalyticBaseUnit'
  BillingMaterial.BillingQuantity                 as AnalyticBillingQuantity,
  BillingMaterial.MaterialName                    as AnalyticMaterialName


}

where
  LogItems.KZ_VATReturnSectionType = '07'