P_ID_AcctDocBusinessPartner

@VDM.viewType: #COMPOSITE
@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
define view entity P_ID_AcctDocBusinessPartner
  with parameters
    P_CompanyCode    : fis_bukrs,
    P_FromFiscalYear : gjahr,
    P_ToFiscalYear   : gjahr
  as select from I_OperationalAcctgDocItem
{
  key CompanyCode,
  key FiscalYear,
  key AccountingDocument,
      max(case when Customer is not null then Customer else '' end)                                                                                                                                                                                                           as Customer,
      max(case when Supplier is not null then Supplier else '' end)                                                                                                                                                                                                           as Supplier,
      max(case when BusinessPlace is not null then BusinessPlace else '' end)                                                                                                                                                                                                 as BusinessPlace,
      max(case when BillingDocument is not null then BillingDocument else '' end)                                                                                                                                                                                             as BillingDocument,
      max(case when SpecialGLCode is not null then SpecialGLCode  else '' end)                                                                                                                                                                                                as SpecialGLCode,
      max(case when IsNegativePosting is not null then IsNegativePosting else '' end)                                                                                                                                                                                         as IsNegativePosting,
      max(case when _OneTimeAccountBP.Country is not null then _OneTimeAccountBP.Country else case when _Customer.Country is not null then _Customer.Country else _Supplier.Country end end)                                                                                  as ActiveCountry,
      cast(max(case when _Customer._CustomerToBusinessPartner._BusinessPartner.PersonNumber is not null then _Customer._CustomerToBusinessPartner._BusinessPartner.PersonNumber else _Supplier._SupplierToBusinessPartner._BusinessPartner.PersonNumber  end ) as ad_persnum) as PersonNumber,
      max(case when _OneTimeAccountBP.TaxID1 is not null then _OneTimeAccountBP.TaxID1 else '' end)                                                                                                                                                                           as TaxID1,
      max(case when _OneTimeAccountBP.TaxID2 is not null then _OneTimeAccountBP.TaxID2 else '' end)                                                                                                                                                                           as TaxID2,
      max(case when _OneTimeAccountBP.TaxID3 is not null then _OneTimeAccountBP.TaxID3 else '' end)                                                                                                                                                                           as TaxID3,
      max(case when _OneTimeAccountBP.TaxID5 is not null then _OneTimeAccountBP.TaxID5 else '' end)                                                                                                                                                                           as TaxID5,
      max(case when _OneTimeAccountBP.BusinessPartnerName1 is not null then _OneTimeAccountBP.BusinessPartnerName1 else '' end)                                                                                                                                               as BusinessPartnerName1,
      max(case when _OneTimeAccountBP.BusinessPartnerName2 is not null then _OneTimeAccountBP.BusinessPartnerName2 else '' end)                                                                                                                                               as BusinessPartnerName2,
      max(case when _OneTimeAccountBP.BusinessPartnerName3 is not null then _OneTimeAccountBP.BusinessPartnerName3 else '' end)                                                                                                                                               as BusinessPartnerName3,
      max(case when _OneTimeAccountBP.BusinessPartnerName4 is not null then _OneTimeAccountBP.BusinessPartnerName4 else '' end)                                                                                                                                               as BusinessPartnerName4,
      max(case when _OneTimeAccountBP.StreetAddressName is not null then _OneTimeAccountBP.StreetAddressName else '' end)                                                                                                                                                     as StreetAddressName,
      max(case when _OneTimeAccountBP.CityName is not null then _OneTimeAccountBP.CityName else '' end)                                                                                                                                                                       as CityName,
      max(case when _OneTimeAccountBP.Country is not null then _OneTimeAccountBP.Country else '' end)                                                                                                                                                                         as Country,
      max(case when _OneTimeAccountBP.PostalCode is not null then _OneTimeAccountBP.PostalCode else '' end)                                                                                                                                                                   as PostalCode
}
where
       I_OperationalAcctgDocItem.CompanyCode           = $parameters.P_CompanyCode
  and  I_OperationalAcctgDocItem.FiscalYear            between $parameters.P_FromFiscalYear and $parameters.P_ToFiscalYear
  and(
       ( I_OperationalAcctgDocItem.ReferenceDocumentType = 'VBRK' and I_OperationalAcctgDocItem.BillingDocument is not initial )
    or I_OperationalAcctgDocItem.ReferenceDocumentType = 'BKPF'
  )
group by
  CompanyCode,
  FiscalYear,
  AccountingDocument