P_GoodsReceiptDataSIT

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass:#MIXED

@VDM.private: true
@VDM.viewType: #COMPOSITE
define view entity P_GoodsReceiptDataSIT
  as select from           I_PurchasingDocumentHistoryBsc as _purchDoc

    left outer to one join I_MaterialDocumentRecord  as _MaterialDocumentRecord on  _purchDoc.PurchasingHistoryDocument     =  _MaterialDocumentRecord.MaterialDocument
                                                                                and _purchDoc.PurchasingHistoryDocumentItem =  _MaterialDocumentRecord.MaterialDocumentItem
                                                                                and _purchDoc.PurchasingHistoryDocumentYear =  _MaterialDocumentRecord.MaterialDocumentYear
                                                                                and _purchDoc.PurchasingDocument            =  _MaterialDocumentRecord.PurchaseOrder
                                                                                and _purchDoc.PurchasingDocumentItem        =  _MaterialDocumentRecord.PurchaseOrderItem   
                                                                                and _purchDoc.Material                      =  _MaterialDocumentRecord.Material                                                                                                                                                                   
                                                                                and _MaterialDocumentRecord.StorageLocation <> ''

  association [1..1] to I_GoodsMovementDocument as _matDoc             on  _purchDoc.PurchasingHistoryDocument     = _matDoc.MaterialDocument
                                                                       and _purchDoc.PurchasingHistoryDocumentItem = _matDoc.MaterialDocumentItem
                                                                       and _purchDoc.PurchasingHistoryDocumentYear = _matDoc.MaterialDocumentYear
                                                                       and _purchDoc.PurchasingDocument            = _matDoc.PurchaseOrder
                                                                       and _purchDoc.PurchasingDocumentItem        = _matDoc.PurchaseOrderItem  
                                                                       and _purchDoc.Material                      = _matDoc.Material                                                                                                                                                      
                                                                       and _matDoc.MaterialDocumentRecordType      = 'MDOC'

  association [1..1] to P_GetLastPostingDate    as _GetLastPostingDate on  $projection.PurchaseOrder     = _GetLastPostingDate.PurchaseOrder
                                                                       and $projection.PurchaseOrderItem = _GetLastPostingDate.PurchaseOrderItem

{
  key _purchDoc.PurchasingHistoryDocument                                                                                       as MaterialDocument,
  key _purchDoc.PurchasingHistoryDocumentItem                                                                                   as MaterialDocumentItem,
  key _purchDoc.PurchasingHistoryDocumentYear                                                                                   as MaterialDocumentYear,
  key _purchDoc.PurchasingDocument                                                                                              as PurchaseOrder,
  key _purchDoc.PurchasingDocumentItem                                                                                          as PurchaseOrderItem,

      cast(_matDoc.Plant              as nsdm_gr_werks preserving type)                                                         as ReceivingPlant,
      _purchDoc.Material                                                                                                        as Material,
      cast(_MaterialDocumentRecord.StorageLocation as mmim_receiving_storagelocation preserving type )                          as StorageLocation,
      cast(_MaterialDocumentRecord.Batch           as mmim_receiving_batch preserving type )                                    as Batch,
      cast(_matDoc.CompanyCode        as nsdm_gr_bukrs preserving type)                                                         as ReceivingCompanyCode,
      cast(_matDoc._Plant.PlantName   as nsdm_gr_name preserving type)                                                          as ReceivingPlantName,
      cast(_matDoc.GoodsMovementType  as nsdm_gr_bwart preserving type)                                                         as GoodsReceiptMovementType,
      cast(_matDoc.PostingDate        as nsdm_gr_budat preserving type)                                                         as GoodsReceiptPostingDate,
      @Semantics.quantity.unitOfMeasure: 'GoodsReceiptBaseUnit' 
      cast(_matDoc.QuantityInBaseUnit as nsdm_gr_bstmg preserving type)                                                         as GoodsReceiptQuantity,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      cast(_matDoc.GoodsReceiptQtyInOrderUnit as nsdm_gr_bstmg preserving type)                                                 as GoodsReceiptQtyInOrderUnit, //2813353

      _purchDoc.OrderQuantityUnit,
      cast(_matDoc.MaterialBaseUnit   as nsdm_gr_meins preserving type)                                                         as GoodsReceiptBaseUnit,
      cast(_matDoc.CreatedByUser      as mmim_gr_created_by_user)                                                               as GRCreatedByUser,
      _matDoc.GoodsMovementIsCancelled                                                                                          as GoodsReceiptIsCanceled,
      _matDoc.ReversedMaterialDocument                                                                                          as GRReveralMaterialDocument,
      _matDoc.DebitCreditCode                                                                                                   as DebitCreditCode,         //3293401 

      
      _GetLastPostingDate,
      
      cast(_matDoc.DeliveryDocument as mmim_gr_delivery_document )                                                              as GoodsReceiptForDeliveryDoc,
      cast(_matDoc.DeliveryDocumentItem as mmim_gr_delivery_document_item)                                                      as GoodsReceiptForDeliveryDocItem,
      cast(_matDoc._DeliveryDocumentItem.CreationDate as mmim_gr_deliv_doc_itm_crtn_dte  preserving type)                       as GoodsReceiptDelivDocItmCrtnDte,
      cast(_matDoc._DeliveryDocumentItem.ActualDeliveredQtyInBaseUnit as mmim_gr_deliv_doc_itm_quantity )                       as GoodsReceiptDelivDocItmQty,
      cast(_matDoc._DeliveryDocumentItem.Batch as mmim_gr_deliv_doc_itm_batch preserving type)                                  as GoodsReceiptDelivDocItmBatch,
      cast(_matDoc._DeliveryDocument.DeliveryDocumentType as mmim_gr_deliv_doc_type preserving type)                            as GoodsReceiptDelivDocType,
      cast(_matDoc._DeliveryDocumentItem.GoodsMovementStatus as mmim_gr_deliv_doc_itm_status preserving type)                   as GoodsReceiptDelivDocItmStatus,

      cast( dats_tims_to_tstmp(_matDoc.CreationDate, _matDoc.CreationTime, 'UTC', $session.client, 'NULL' )
                                                                                                            as mmim_date_time ) as GoodsReceiptUTCDateTime,
      _purchDoc.Quantity                                                                                                        as QuantityInPurchaseOrderUnit                                                                                      

}
where
     _purchDoc.PurchasingHistoryCategory = 'E'
 and _matDoc.IsEffectiveGoodsMovement    = 'X'