P_GVoAAccountLineItemEnhcd

@AccessControl: { authorizationCheck: #MANDATORY,
                 personalData.blocking: #REQUIRED }
@ObjectModel: { usageType: { sizeCategory: #XXL,
                             dataClass:  #MIXED,
                             serviceQuality: #D },
                supportedCapabilities: [#SQL_DATA_SOURCE]}
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #COMPOSITE
@VDM.private:true

define view entity P_GVoAAccountLineItemEnhcd

  as select from           I_GLAccountLineItem        as _Source

    inner join             I_CnsldtnUnitByTimeVersion as _UnitByTimeVersion on  _UnitByTimeVersion.ConsolidationDimension    =  'Y1'
                                                                            and _UnitByTimeVersion.ConsolidationUnit         =  _Source.ConsolidationUnit

    // Cons unit time intervals can end at period 999 and start at 001 => When executing ruj in period 0 we have to check the cons unit interval in period 1

                                                                            and (
                                                                               _UnitByTimeVersion.FromFiscalYearPeriod       <= _Source.FiscalYearPeriod
                                                                               or(
                                                                                 _Source.FiscalPeriod                        =  '000'
                                                                                 and _UnitByTimeVersion.FromFiscalYearPeriod <= concat(
                                                                                   _Source.LedgerFiscalYear, '001'
                                                                                 )
                                                                               )
                                                                             )

                                                                            and _UnitByTimeVersion.ToFiscalYearPeriod        >= _Source.FiscalYearPeriod
                                                                            and _UnitByTimeVersion.CnsldtnDataTransferMethod =  'H'

    inner join             I_CnsldtnVersion           as _Version           on  _Version.CnsldtnUnitAttributeVersion   = _UnitByTimeVersion.CnsldtnUnitAttributeVersion
                                                                            and _Version.CnsldtnAccountingSourceLedger = _Source.Ledger
                                                                            and _Version.CnsldtnIsPlanVersion          = ''

    left outer to one join I_CnsldtnPullRequest       as _PullRequest       on  _PullRequest.FiscalYear           = _Source.FiscalYear
                                                                            and _PullRequest.FiscalPeriod         = _Source.FiscalPeriod
                                                                            and _PullRequest.ConsolidationVersion = _Version.ConsolidationVersion
                                                                            and _PullRequest.ConsolidationUnit    = _Source.ConsolidationUnit

  association [1..1] to E_JournalEntryItem as _Extension on  _Source.SourceLedger       = _Extension.SourceLedger
                                                         and _Source.CompanyCode        = _Extension.CompanyCode
                                                         and _Source.FiscalYear         = _Extension.FiscalYear
                                                         and _Source.AccountingDocument = _Extension.AccountingDocument
                                                         and _Source.LedgerGLLineItem   = _Extension.LedgerGLLineItem

{
  key _Source.SourceLedger,
  key _Source.CompanyCode,
  key _Source.FiscalYear,
  key _Source.AccountingDocument,
  key _Source.LedgerGLLineItem,
  key _Source.Ledger,

      // Hard coded fields

      cast( '' as fincs_group_jrnl_entry )                   as CnsldtnGroupJrnlEntry, // old name: ConsolidationDocumentNumber

      cast( '' as fincs_group_jrnl_entry_item )              as CnsldtnGroupJrnlEntryItem, // old name: ConsolidationPostingItem


      cast( 'M' as docct preserving type )                   as DocumentCategory,
      cast( '' as fc_ryacq )                                 as ConsolidationAcquisitionYear,
      cast( '' as rpacq )                                    as ConsolidationAcquisitionPeriod,
      cast( '' as fc_coicu )                                 as InvesteeConsolidationUnit,
      cast( '' as autom preserving type )                    as ConsolidationPostgItemAutoFlag,
      cast( '' as fincs_coiac )                              as InvestmentActivityType,
      cast( '' as fincs_coinr )                              as InvestmentActivity,
      cast( '' as fc_rtflg )                                 as CurrencyConversionsDiffType,
      cast( '' as docct preserving type )                    as RefConsolidationDocumentType,

      cast( 'Y1' as fc_dimen preserving type )               as ConsolidationDimension,
      cast( '' as fc_docty )                                 as ConsolidationDocumentType,
      cast( '' as fc_congr )                                 as ConsolidationGroup,
      cast( 'PER' as fincs_period_mode   )                   as PeriodMode,
      cast( 'C' as fincs_rrcty preserving type )             as GLRecordType,
      cast( '' as fc_plevl )                                 as PostingLevel,
      cast( '' as gu_recid )                                 as ConsolidationRecordNumber,

      _Version.ConsolidationVersion                          as ConsolidationVersion,

      cast( case
        when _PullRequest.CnsldtnPullRequestDateTime is not initial and _Source.CreationDateTime <= _PullRequest.CnsldtnPullRequestDateTime then 'R'
        else 'U'
      end as abap.char( 1 ) )                                as CnsldtnPullRequestState,

      _UnitByTimeVersion.DocumentEntryIsInGroupCurrency,

      // Fields from _Source

      _Source.LedgerFiscalYear,
      _Source.JrnlEntrAltvFYConsecutiveID,

      // Test workaround

      _Source.ChartOfAccounts,
      _Source.ControllingArea,

      ///////////////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_00  Unified Journal Entry: Transaction, Currencies, Units

      ///////////////////////////////////////////////////////////////////////////////

      _Source.FinancialTransactionType,
      _Source.GLBusinessTransactionType,
      _Source.BusinessTransactionCategory,
      _Source.BusinessTransactionType,
      _Source.FinancialClosingStep,
      _Source.ControllingBusTransacType,
      _Source.ReferenceDocumentType,
      _Source.LogicalSystem,
      _Source.ReferenceDocumentContext,
      _Source.ReferenceDocument,
      _Source.ReferenceDocumentItem,
      _Source.ReferenceDocumentItemGroup,
      _Source.TransactionSubitem,
      _Source.OffsettingLedgerGLLineItem,
      _Source.IsReversal,
      _Source.IsReversed,
      //XTRUEREV,

      //AWTYP_REV,

      _Source.ReversalReferenceDocumentCntxt,
      _Source.ReversalReferenceDocument,
      _Source.ReversalTransactionSubitem,
      _Source.IsSettlement,
      _Source.IsSettled,
      _Source.PredecessorReferenceDocType,
      _Source.PredecessorReferenceDocCntxt,
      _Source.PredecessorReferenceDocument,
      _Source.PredecessorReferenceDocItem,
      //PREC_SUBTA,

      _Source.PrdcssrJournalEntryCompanyCode,
      _Source.PrdcssrJournalEntryFiscalYear,
      _Source.PredecessorJournalEntry,
      _Source.PredecessorJournalEntryItem,

      _Source.SourceReferenceDocumentType,
      _Source.SourceLogicalSystem,
      _Source.SourceReferenceDocumentCntxt,
      _Source.SourceReferenceDocument,
      _Source.SourceReferenceDocumentItem,
      _Source.SourceReferenceDocSubitem,
      _Source.IsCommitment,
      _Source.JrnlEntryItemObsoleteReason,
      _Source.JrnlPeriodEndClosingRunLogUUID,
      _Source.OrganizationalChange,
      _Source.AccountingNotificationUUID,

      _Source.GLAccount,


      ////////////////////////////////////////////////////////////////////////////////////

      // .INCLUDE  ACDOC_SI_GL_ACCAS Unified Journal Entry: G/L additional account assignments

      ////////////////////////////////////////////////////////////////////////////////////

      _Source.CostCenter,
      _Source.ProfitCenter,
      _Source.FunctionalArea,
      _Source.BusinessArea,
      _Source.Segment,
      _Source.PartnerCostCenter,
      _Source.PartnerProfitCenter,
      _Source.PartnerFunctionalArea,
      _Source.PartnerBusinessArea,
      _Source.PartnerCompany,
      _Source.PartnerSegment,


      /////////////////////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_VALUE_DATA Unified Journal Entry: Value Fields

      /////////////////////////////////////////////////////////////////////////////////////


      _Source.BalanceTransactionCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      _Source.AmountInBalanceTransacCrcy,

      _Source.TransactionCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      _Source.AmountInTransactionCurrency,

      _Source.CompanyCodeCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      _Source.AmountInCompanyCodeCurrency,

      ////////////////////////////////////

      // NEW

      _Source.GlobalCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.AmountInGlobalCurrency,

      // Functional Currency

      _Source.FunctionalCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      _Source.AmountInFunctionalCurrency,

      _Source.FreeDefinedCurrency1,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      _Source.AmountInFreeDefinedCurrency1,

      _Source.FreeDefinedCurrency2,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      _Source.AmountInFreeDefinedCurrency2,

      _Source.FreeDefinedCurrency3,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      _Source.AmountInFreeDefinedCurrency3,

      _Source.FreeDefinedCurrency4,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      _Source.AmountInFreeDefinedCurrency4,

      _Source.FreeDefinedCurrency5,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      _Source.AmountInFreeDefinedCurrency5,

      _Source.FreeDefinedCurrency6,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      _Source.AmountInFreeDefinedCurrency6,

      _Source.FreeDefinedCurrency7,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      _Source.AmountInFreeDefinedCurrency7,

      _Source.FreeDefinedCurrency8,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      _Source.AmountInFreeDefinedCurrency8,
      ////////////////////////////////////


      ////////////////////////////////////

      // NEW

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.FixedAmountInGlobalCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.GrpValnFixedAmtInGlobCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.PrftCtrValnFxdAmtInGlobCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.TotalPriceVarcInGlobalCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.GrpValnTotPrcVarcInGlobCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.PrftCtrValnTotPrcVarcInGlbCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.FixedPriceVarcInGlobalCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.GrpValnFixedPrcVarcInGlobCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.PrftCtrValnFxdPrcVarcInGlbCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      _Source.FixedAmountInCoCodeCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      _Source.FixedAmountInTransCrcy,

      ////////////////////////////////////


      _Source.ControllingObjectCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
      _Source.AmountInObjectCurrency,

      _Source.GrantCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GrantCurrency'} }
      _Source.AmountInGrantCurrency,


      _Source.BaseUnit,
      @Aggregation.default: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      _Source.Quantity,

      @Aggregation.default: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      _Source.FixedQuantity,

      _Source.CostSourceUnit,
      @Aggregation.default: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'CostSourceUnit'} }
      _Source.ValuationQuantity,

      @Aggregation.default: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'CostSourceUnit'} }
      _Source.ValuationFixedQuantity,

      _Source.ReferenceQuantityUnit,
      @Aggregation.default: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'ReferenceQuantityUnit'} }
      _Source.ReferenceQuantity,

      _Source.AdditionalQuantity1Unit,
      @Aggregation.default: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'AdditionalQuantity1Unit'} }
      _Source.AdditionalQuantity1,

      _Source.AdditionalQuantity2Unit,
      @Aggregation.default: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'AdditionalQuantity2Unit'} }
      _Source.AdditionalQuantity2,

      _Source.AdditionalQuantity3Unit,
      @Aggregation.default: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'AdditionalQuantity3Unit'} }
      _Source.AdditionalQuantity3,


      /////////////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_FIX  Unified Journal Entry: Mandatory fields for G/L

      ////////////////////////////////////////////////////////////////////////////

      _Source.DebitCreditCode,
      @Semantics.fiscal.period: true
      _Source.FiscalPeriod,
      @Semantics.fiscal.yearVariant: true
      _Source.FiscalYearVariant,
      @Semantics.fiscal.yearPeriod: true
      _Source.FiscalYearPeriod,
      _Source.PostingDate,
      _Source.DocumentDate,
      _Source.AccountingDocumentType,
      _Source.AssignmentReference,
      _Source.AccountingDocumentCategory,
      _Source.JournalEntryItemCategory,
      _Source.PostingKey,
      _Source.TransactionTypeDetermination,
      _Source.SubLedgerAcctLineItemType,
      _Source.AccountingDocCreatedByUser,
      _Source.LastChangeDateTime,
      _Source.CreationDateTime,
      _Source.CreationDate,
      _Source.EliminationProfitCenter,
      _Source.OriginObjectType,
      _Source.GLAccountType,
      _Source.AlternativeGLAccount,
      _Source.CountryChartOfAccounts,

      _Source.ItemIsSplit,


      /////////////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_FINCS   Universal Journal Entry: Fields for Group Reporting

      ////////////////////////////////////////////////////////////////////////////

      @ObjectModel.foreignKey.association: '_ConsolidationUnit'
      _Source.ConsolidationUnit,
      @ObjectModel.foreignKey.association: '_PartnerConsolidationUnit'
      _Source.PartnerConsolidationUnit,
      @ObjectModel.foreignKey.association: '_Company'
      _Source.Company,
      @ObjectModel.foreignKey.association: '_ConsolidationChartOfAccounts'
      _Source.ConsolidationChartOfAccounts,
      @ObjectModel.foreignKey.association: '_CnsldtnFinancialStatementItem'
      _Source.CnsldtnFinancialStatementItem,
      @ObjectModel.foreignKey.association: '_CnsldtnSubitemCategory'
      _Source.CnsldtnSubitemCategory,
      @ObjectModel.foreignKey.association: '_CnsldtnSubitem'
      _Source.CnsldtnSubitem,


      ///////////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_GEN  Unified Journal Entry: Fields for several subledgers

      //////////////////////////////////////////////////////////////////////////

      _Source.InvoiceReference,
      _Source.InvoiceReferenceFiscalYear,
      _Source.FollowOnDocumentType,
      _Source.InvoiceItemReference,
      _Source.ReferencePurchaseOrderCategory,
      _Source.PurchasingDocument,
      _Source.PurchasingDocumentItem,
      _Source.AccountAssignmentNumber,
      _Source.DocumentItemText,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SalesDocumentStdVH',
                     element: 'SalesDocument' }
        }]
      _Source.SalesDocument,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SalesDocumentItemStdVH',
                     element: 'SalesDocumentItem' }
        }]
      _Source.SalesDocumentItem,
      _Source.Material,
      _Source.Product,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_PlantStdVH',
                     element: 'Plant' }
        }]
      _Source.Plant,
      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_Supplier_VH',
               element: 'Supplier' }
      }]
      _Source.Supplier,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_Customer_VH',
                     element: 'Customer' }
        }]
      _Source.Customer,
      _Source.ServicesRenderedDate,
      _Source.ConditionContract,

      /////////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_FI  Unified Journal Entry: Fields for FI subledgers

      /////////////////////////////////////////////////////////////////////////

      _Source.FinancialAccountType,
      _Source.SpecialGLCode,
      _Source.TaxCode,
      @Analytics.internalName: #LOCAL
      _Source.TaxCountry,
      _Source.HouseBank,
      _Source.HouseBankAccount,
      _Source.IsOpenItemManaged,
      _Source.ClearingDate,

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_AccountingDocumentStdVH',
                     element: 'AccountingDocument' },
          additionalBinding: [{ localElement: 'CompanyCode',
                                element: 'CompanyCode' },
                              { localElement: 'FiscalYear',
                                element: 'FiscalYear' }]
        }]

      @Analytics.internalName: #LOCAL
      _Source.ClearingJournalEntryFiscalYear,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_JournalEntryStdVH',
                     element: 'AccountingDocument' },
          additionalBinding: [{ localElement: 'CompanyCode',
                                element: 'CompanyCode' },
                              { localElement: 'ClearingJournalEntryFiscalYear',
                                element: 'FiscalYear' }]
        }]
      @Analytics.internalName: #LOCAL
      _Source.ClearingJournalEntry,

      _Source.ValueDate,
      _Source.GeneralLedgerAgingScope,
      _Source.GeneralLedgerAgingIncrement,

      /////////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_FAA  Unified Journal Entry: Fields for Asset Accounting

      /////////////////////////////////////////////////////////////////////////

      _Source.AssetDepreciationArea,
      _Source.MasterFixedAsset,
      _Source.FixedAsset,
      _Source.AssetValueDate,
      _Source.AssetTransactionType,
      _Source.AssetAcctTransClassfctn,
      _Source.DepreciationFiscalPeriod,
      _Source.GroupMasterFixedAsset,
      _Source.GroupFixedAsset,
      _Source.AssetClass,
      _Source.PartnerMasterFixedAsset,
      _Source.PartnerFixedAsset,


      //////////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_ML Unified Journal Entry: Fields for Material Ledger

      //////////////////////////////////////////////////////////////////////////

      _Source.CostEstimate,

      _Source.InvtrySpecialStockValnType_2,

      _Source.IsSupplierStockValuation,
      _Source.InventorySpecialStockType,
      _Source.InventorySpclStkSalesDocument,
      _Source.InventorySpclStkSalesDocItm,
      _Source.InvtrySpclStockWBSElmntIntID,
      _Source.InventorySpecialStockSupplier,
      _Source.InventoryValuationType,
      _Source.ValuationArea,

      _Source.MaterialLedgerProcessType,
      _Source.MaterialLedgerCategory,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      _Source.SlsPriceAmountInCoCodeCrcy,
      _Source.ProductPriceControl,

      ////////////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_CFIN   Unified Journal Entry: Fields for Central Finance

      //////////////////////////////////////////////////////////////////////////////

      _Source.SenderCompanyCode,
      _Source.SenderGLAccount,
      _Source.SenderAccountAssignment,
      _Source.SenderAccountAssignmentType,


      ////////////////////////////////////////////////////////////////////////////

      //  .INCLUDE  ACDOC_SI_CO  Unified Journal Entry: CO fields

      ///////////////////////////////////////////////////////////////////////////

      _Source.ControllingObject,
      _Source.CostOriginGroup,
      _Source.OriginSenderObject,
      _Source.ControllingDebitCreditCode,
      _Source.ControllingObjectDebitType,
      _Source.QuantityIsIncomplete,
      _Source.OffsettingAccount,
      _Source.OffsettingAccountType,
      _Source.OffsettingChartOfAccounts,
      _Source.LineItemIsCompleted,
      _Source.PersonnelNumber,
      _Source.ControllingObjectClass,
      _Source.PartnerCompanyCode,
      _Source.PartnerControllingObjectClass,
      _Source.OriginCostCenter,
      _Source.OriginProfitCenter,
      _Source.OriginCostCtrActivityType,
      @Analytics.internalName: #LOCAL
      _Source.OriginProduct,
      _Source.VarianceOriginGLAccount,

      _Source.AccountAssignment,
      @Analytics.internalName: #LOCAL
      _Source.AccountAssignmentType,
      _Source.CostCtrActivityType,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_Order',
                           element: 'OrderID' }
              }]
      _Source.OrderID,
      _Source.OrderCategory,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_WBSElementBasicDataStdVH',
                           element: 'WBSElementInternalID' }
              }]
      _Source.WBSElementInternalID,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_WBSElementBasicDataStdVH',
                           element: 'WBSElementInternalID' }
              }]
      _Source.PartnerWBSElementInternalID,
      _Source.ProjectInternalID,
      _Source.PartnerProjectInternalID,
      cast(_Source.Project as ps_pspid_edit preserving type) as Project,
      _Source.OperatingConcern,
      _Source.ProjectNetwork,
      _Source.RelatedNetworkActivity,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_BusinessProcessStdVH',
                           element: 'BusinessProcess' }
              }]
      _Source.BusinessProcess,
      _Source.CostObject,
      _Source.BillableControl,
      _Source.CostAnalysisResource,
      _Source.CustomerServiceNotification,

      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_AcctgServiceDocumentTypeVH',
                           element: 'ServiceDocumentType' }
              }]
      @Analytics.internalName: #LOCAL
      _Source.ServiceDocumentType,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_AcctgServiceDocumentVH',
                           element: 'ServiceDocument' }
              }]
      @Analytics.internalName: #LOCAL
      _Source.ServiceDocument,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_AcctgServiceDocumentItemVH',
                           element: 'ServiceDocumentItem' }
              }]
      @Analytics.internalName: #LOCAL
      _Source.ServiceDocumentItem,

      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_AcctgServiceDocumentTypeVH',
                           element: 'ServiceDocumentType' }
              }]
      @Analytics.internalName: #LOCAL
      _Source.PartnerServiceDocumentType,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_AcctgServiceDocumentVH',
                           element: 'ServiceDocument' }
              }]
      @Analytics.internalName: #LOCAL
      _Source.PartnerServiceDocument,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_AcctgServiceDocumentItemVH',
                           element: 'ServiceDocumentItem' }
              }]
      @Analytics.internalName: #LOCAL
      _Source.PartnerServiceDocumentItem,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_ServiceContractTypeStdVH',
                           element: 'ServiceDocumentType' }
              }]
      @Analytics.internalName: #LOCAL
      _Source.ServiceContractType,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_AcctgServiceContractVH',
                           element: 'ServiceContract' }
              }]
      @Analytics.internalName: #LOCAL
      _Source.ServiceContract,
      @Analytics.internalName: #LOCAL
      _Source.ServiceContractItem,

      _Source.BusinessSolutionOrder,
      _Source.BusinessSolutionOrderItem,

      _Source.ProviderContract,
      _Source.ProviderContractItem,

      _Source.RevenueAccountingContract,
      _Source.PerformanceObligation,

      @Analytics.internalName: #LOCAL
      _Source.TimeSheetOvertimeCategory,
      _Source.PartnerAccountAssignment,
      _Source.PartnerAccountAssignmentType,
      _Source.WorkPackage,
      _Source.WorkItem,
      _Source.PartnerCostCtrActivityType,

      _Source.PartnerOrder,
      _Source.PartnerOrder_2,

      _Source.PartnerOrderCategory,
      _Source.PartnerSalesDocument,
      _Source.PartnerSalesDocumentItem,
      _Source.PartnerProjectNetwork,
      _Source.PartnerProjectNetworkActivity,
      _Source.PartnerBusinessProcess,
      _Source.PartnerCostObject,
      _Source.ControllingDocumentItem,


      //////////////////////////////////////////////////////////////////////

      //  .INCLUDE  ACDOC_SI_COPA  Unified Journal Entry: CO-PA fields

      //////////////////////////////////////////////////////////////////////

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'C_BillingDocumentTypeVH',
                     element: 'BillingDocumentType' }
        }]
      _Source.BillingDocumentType,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SalesOrganization',
                     element: 'SalesOrganization' }
        }]
      _Source.SalesOrganization,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_DistributionChannel',
                     element: 'DistributionChannel' }
        }]
      _Source.DistributionChannel,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_Division',
                     element: 'Division' }
        }]
      @Analytics.internalName:#LOCAL
      _Source.OrganizationDivision,
      _Source.SoldMaterial,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ProductVH',
                     element: 'Product' }
        }]
      _Source.SoldProduct,
      _Source.MaterialGroup,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ProductGroupVH',
                     element: 'ProductGroup' }
        }]
      _Source.SoldProductGroup,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CustomerGroup',
                     element: 'CustomerGroup' }
        }]
      _Source.CustomerGroup,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CountryVH',
                     element: 'Country' }
        }]
      @Analytics.internalName:#LOCAL
      _Source.CustomerSupplierCountry,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CustomerSupplierIndustry',
                     element: 'Industry' }
        }]
      @Analytics.internalName:#LOCAL
      _Source.CustomerSupplierIndustry,
      @Consumption.valueHelpDefinition: [
       { entity:  { name:    'I_SalesDistrict',
                    element: 'SalesDistrict' }
       }]
      @Analytics.internalName:#LOCAL
      _Source.SalesDistrict,
      @Consumption.valueHelpDefinition: [
       { entity:  { name:    'I_Customer_VH',
                    element: 'Customer' }
       }]
      @Analytics.internalName: #LOCAL
      _Source.BillToParty,
      @Consumption.valueHelpDefinition: [
       { entity:  { name:    'I_Customer_VH',
                    element: 'Customer' }
       }]
      @Analytics.internalName: #LOCAL
      _Source.ShipToParty,

      _Source.CustomerSupplierCorporateGroup,


      //////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_PS  Unified Journal Entry: Fields for Public Sector

      /////////////////////////////////////////////////////////////////////

      @Analytics.internalName: #LOCAL
      _Source.CashLedgerCompanyCode,

      @Analytics.internalName: #LOCAL
      _Source.CashLedgerAccount,

      _Source.FinancialManagementArea,

      _Source.CommitmentItem,

      _Source.FundsCenter,

      @Analytics.internalName: #LOCAL
      _Source.FundedProgram,

      _Source.Fund,

      @Analytics.internalName: #LOCAL
      _Source.GrantID,

      _Source.BudgetPeriod,

      _Source.PartnerFund,

      @Analytics.internalName: #LOCAL
      _Source.PartnerGrant,

      @Analytics.internalName: #LOCAL
      _Source.PartnerBudgetPeriod,

      @Analytics.internalName: #LOCAL
      _Source.PubSecBudgetAccount,

      @Analytics.internalName: #LOCAL
      _Source.PubSecBudgetAccountCoCode,

      @Analytics.internalName: #LOCAL
      _Source.PubSecBudgetCnsmpnDate,

      @Analytics.internalName: #LOCAL
      _Source.PubSecBudgetCnsmpnFsclPeriod,

      @Analytics.internalName: #LOCAL
      _Source.PubSecBudgetCnsmpnFsclYear,

      @Analytics.internalName: #LOCAL
      _Source.PubSecBudgetIsRelevant,

      @Analytics.internalName: #LOCAL
      _Source.PubSecBudgetCnsmpnType,

      @Analytics.internalName: #LOCAL
      _Source.PubSecBudgetCnsmpnAmtType,

      @Analytics.internalName: #LOCAL
      _Source.SponsoredProgram,

      @Analytics.internalName: #LOCAL
      _Source.SponsoredClass,

      @Analytics.internalName: #LOCAL
      _Source.GteeMBudgetValidityNumber,

      _Source.EarmarkedFundsDocument,
      _Source.EarmarkedFundsDocumentItem,


      ///////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_JVA  Universal Journal Entry: Fields for Financial Services

      ///////////////////////////////////////////////////////////////////////

      _Source.FinancialServicesProductGroup,
      _Source.FinancialServicesBranch,
      _Source.FinancialDataSource,


      ///////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_JVA  Unified Journal Entry: Fields for Joint Venture Accounting

      ///////////////////////////////////////////////////////////////////////

      _Source.JointVenture,
      _Source.JointVentureEquityGroup,
      _Source.JointVentureCostRecoveryCode,
      _Source.JointVenturePartner,
      _Source.JointVentureBillingType,
      _Source.JointVentureEquityType,
      _Source.JointVentureProductionDate,
      _Source.JointVentureBillingDate,
      _Source.JointVentureOperationalDate,
      _Source.CutbackRun,
      _Source.JointVentureAccountingActivity,
      _Source.PartnerVenture,
      _Source.PartnerEquityGroup,
      _Source.SenderCostRecoveryCode,
      _Source.CutbackAccount,
      _Source.CutbackCostObject,

      ///////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_RE STRU  0 0 Unified Journal Entry: Fields for Real Estate

      ///////////////////////////////////////////////////////////////////////

      _Source.REBusinessEntity,
      _Source.RealEstateBuilding,
      _Source.RealEstateProperty,
      _Source.RERentalObject,
      _Source.RealEstateContract,
      _Source.REServiceChargeKey,
      _Source.RESettlementUnitID,
      _Source.SettlementReferenceDate,
      _Source.REPartnerBusinessEntity,
      _Source.RealEstatePartnerBuilding,
      _Source.RealEstatePartnerProperty,
      _Source.REPartnerRentalObject,
      _Source.RealEstatePartnerContract,
      _Source.REPartnerServiceChargeKey,
      _Source.REPartnerSettlementUnitID,
      _Source.PartnerSettlementReferenceDate,


      ///////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_ACR STRU  0 0 Universal Journal Entry: Fields for Accrual object

      ///////////////////////////////////////////////////////////////////////

      //   AccrualObject      --(1:N)-->  AccrualSubobject  --(1:N)-->  Accrual(Subobject)Item (this field is not stored in ACDOCA)

      //   AccrualObjectType                                            AccrualItemType  are the corresponding types

      _Source.AccrualObjectType,
      _Source.AccrualObjectLogicalSystem,
      _Source.AccrualObject,
      _Source.AccrualSubobject,
      _Source.AccrualItemType,
      _Source.AccrualReferenceObject,
      _Source.AccrualValueDate,


      ///////////////////////////////////////////////////////////////////////

      // .INCLUDE ACDOC_SI_VAL STRU  0 0 Universal Journal Entry: Fields for Fin. Valuation Object

      ///////////////////////////////////////////////////////////////////////

      _Source.FinancialValuationObjectType,
      _Source.FinancialValuationObject,
      _Source.FinancialValuationSubobject,
      _Source.NetDueDate,
      _Source.CreditRiskClass,

      //////////////////////////////////////////////////////////////////////

      //  .INCLUDE  ACDOC_SI_LOG  Universal Journal Entry: Fields for Logistics

      //////////////////////////////////////////////////////////////////////


      _Source.WorkCenterInternalID,
      _Source.OrderOperation,
      _Source.OrderItem,
      _Source.PartnerOrderItem,

      //////////////////////////////////////////////////

      // .INCLUDE  ACDOC_SI_LOG_ACT:  New Fields  PM  //

      //////////////////////////////////////////////////

      //  @ObjectModel.foreignKey.association: '_MaintenanceOrderSubOperation'      // Triangle Condition

      _Source.OrderSuboperation,
      _Source.Equipment,
      _Source.FunctionalLocation,
      _Source.Assembly,
      _Source.MaintenanceActivityType,
      _Source.MaintenanceOrderPlanningCode,
      _Source.MaintPriorityType,
      _Source.MaintPriority,
      _Source.SuperiorOrder,
      _Source.ProductGroup,
      _Source.MaintenanceOrderIsPlanned,


      //////////////////////////////////////////////////////////////////////////

      // .INCLUDE  ACDOC_SI_TECH:  Universal Journal Entry: Technical Fields  //

      //////////////////////////////////////////////////////////////////////////

      _Source.JrnlEntryItemMigrationSource,


      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      _Source.DebitAmountInCoCodeCrcy,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      _Source.CreditAmountInCoCodeCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      _Source.DebitAmountInTransCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      _Source.CreditAmountInTransCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      _Source.DebitAmountInBalanceTransCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      _Source.CreditAmountInBalanceTransCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.DebitAmountInGlobalCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Source.CreditAmountInGlobalCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      _Source.DebitAmountInFunctionalCrcy,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      _Source.CreditAmountInFunctionalCrcy,

      _Source.IsStatisticalOrder,

      _Source.IsStatisticalCostCenter,

      _Source.IsStatisticalSalesDocument,

      _Source.WBSIsStatisticalWBSElement,


      ///////////////////////////////////////////////////////////////////////////////

      // Fields from associations

      ///////////////////////////////////////////////////////////////////////////////


      _Source.CalendarYear,
      _Source.CalendarQuarter,
      _Source.CalendarYearQuarter,
      _Source.CalendarMonth,
      _Source.CalendarYearMonth,
      _Source.CalendarWeek,
      _Source.CalendarYearWeek,


      _Source._CashLedgerCompanyCode,
      _Source._CashLedgerAccount,
      _Source._FinancialManagementArea,
      _Source._FundsCenter,
      _Source._FundedProgram,
      _Source._Fund,
      _Source._Grant,
      _Source._BudgetPeriod,
      _Source._PartnerFund,
      _Source._PartnerGrant,
      _Source._PartnerBudgetPeriod,
      _Source._PubSecBudgetAccountCoCode,
      _Source._PubSecBudgetAccount,
      _Source._PubSecBudgetCnsmpnDate,
      _Source._PubSecBudgetCnsmpnFsclPeriod,
      _Source._PubSecBudgetCnsmpnFsclYear,
      _Source._PubSecBudgetCnsmpnType,
      _Source._PubSecBudgetCnsmpnAmtType,
      _Source._SponsoredProgram,
      _Source._SponsoredClass,

      _Source._ConsolidationUnit,
      _Source._PartnerConsolidationUnit,
      _Source._Company,
      _Source._ConsolidationChartOfAccounts,
      _Source._CnsldtnFinancialStatementItem,
      _Source._CnsldtnSubitemCategory,
      _Source._CnsldtnSubitem,

      _Source._ProviderContract,
      _Source._ProviderContractItem
}
// The following WHERE condition are taken from view P_GVoAGrpJEItm (helper view for I_GVoAGrpJEItm)

where
  (
       _Source.AccountingDocumentCategory    =  ''  //normal documents

    or _Source.AccountingDocumentCategory    =  'U' //documents without lines in BSEG

    or _Source.AccountingDocumentCategory    =  'L' //postings not in leading ledger, relevant in case an orientation ledger is used

    or _Source.AccountingDocumentCategory    =  'P' //predicted documents, posted in a separate extension ledger

    or _Source.AccountingDocumentCategory    =  'C' //balance Carryforward and Balance Adjustments from Migration

  )

  and  _Source.CnsldtnFinancialStatementItem <> '&NORELEASE'

  // Year End Closing postings are not relevant for consolidation

  and  _Source.ReferenceDocumentType         <> 'GLYEC'