P_GB_PAYTPRACTICEPERF1

@AbapCatalog.sqlViewName: 'PGBPPPR1'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
//@EndUserText.label: 'GB PPPR Layer 1'

@ObjectModel.usageType.sizeCategory: #XXL    // XL

@ObjectModel.usageType.serviceQuality: #C    // D

@ObjectModel.usageType.dataClass: #MIXED

@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@VDM.private: true




define view P_GB_PAYTPRACTICEPERF1
  as select from I_OperationalAcctgDocItem
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,
  key Supplier,
  key SpecialGLTransactionType,
      @ObjectModel.foreignKey.association: '_SpecialGLCode'
  key SpecialGLCode,
  key ClearingDate,
      @ObjectModel.foreignKey.association: '_ClearingJournalEntry'
  key ClearingJournalEntry, // AUGBL!

  key AssignmentReference,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key FiscalYear,
  key AccountingDocument,
  key AccountingDocumentItem,

      // ENTRY DATE -> CPUDT -> get from journal_entry

      PostingDate,
      DocumentDate,
      DueCalculationBaseDate,
      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
      AccountingDocumentType,
      @ObjectModel.foreignKey.association: '_FiscalPeriod'
      FiscalPeriod,



      @ObjectModel.foreignKey.association: '_PostingKey'
      PostingKey,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      BusinessArea,
      @ObjectModel.foreignKey.association: '_DebitCreditCode'
      DebitCreditCode,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode:true
      TransactionCurrency,         // waers

      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      AmountInTransactionCurrency, // wrbtr

      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      @Semantics.currencyCode:true
      CompanyCodeCurrency,         // hwaer

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      AmountInCompanyCodeCurrency, // dmbtr

      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} }
      AmountInAdditionalCurrency1, // dmbe2

      @ObjectModel.foreignKey.association: '_AdditionalCurrency1'
      @Semantics.currencyCode:true
      AdditionalCurrency1, // hwae2

      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      AmountInAdditionalCurrency2, // dmbe3

      @ObjectModel.foreignKey.association: '_AdditionalCurrency2'
      @Semantics.currencyCode:true
      AdditionalCurrency2, // hwae3

      @ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
      GLAccount,

      PaymentMethod,
      @ObjectModel.foreignKey.association: '_ClearingJrnlEntryFiscalYear'
      ClearingJournalEntryFiscalYear,

      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      NetPaymentDays,
      CashDiscount1Percent,
      CashDiscount2Percent,
      WithholdingTaxCode,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      WithholdingTaxBaseAmount,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      WithholdingTaxAmount,
      JointVentureCostRecoveryCode,
      DocumentItemText,
      TaxCode,
      //    landl not needed

      //    TargetSpecialGLCode, zumsk, not needed?

      //    ClearingDocFiscalYear,   // auggj

      //      DocumentReferenceID,   xblnr



      case
       when ClearingJournalEntry <> '' then ''    // BSAK

       when ClearingJournalEntry = '' then 'O'    // BSIK

       else 'N' // figure out else branch

      end  as StatusFlagValue,
      case
       when ClearingJournalEntry <> '' then '1'     // BSAK   cleared

       when ClearingJournalEntry = '' then '0'      // BSIK  open

       else '2'   // figure out else branch

       end as IsCleared,
      InvoiceReference,
      InvoiceReferenceFiscalYear,
      InvoiceItemReference,

      _FinancialAccountType,
      _SpecialGLCode,
      _Supplier,
      _CompanyCode,
      _JournalEntry,
      _FiscalPeriod,
      _AccountingDocumentType,
      I_OperationalAcctgDocItem.FinancialAccountType,
      _ClearingJournalEntry,
      _FiscalYear,
      _ClearingJrnlEntryFiscalYear,
      I_OperationalAcctgDocItem.ChartOfAccounts,
      _ChartOfAccounts,
      _GLAccountInChartOfAccounts,
      _AdditionalCurrency1,
      _AdditionalCurrency2,
      _PostingKey,
      _BusinessArea,
      _DebitCreditCode,
      _CompanyCodeCurrency,
      _TransactionCurrency
}
where
      AccountingDocumentCategory <> 'M'
  and AccountingDocumentCategory <> 'D'
  and AccountingDocumentCategory <> 'S'
  and AccountingDocumentCategory <> 'V'
  and AccountingDocumentCategory <> 'W'
  and AccountingDocumentCategory <> 'Z'
  and FinancialAccountType       =  'K'