P_FundFixedAsset

@AbapCatalog: {
  sqlViewName: 'PWUFUNDFA',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'WUFUND Fixed Assets'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType:{
  sizeCategory: #L,
  serviceQuality: #B,
  dataClass: #MIXED
}
@VDM: {
  private: true,
  viewType: #COMPOSITE
}
define view P_FundFixedAsset
  as select from I_FixedAssetAssgmt
  association [1..1] to I_Fund as _Fund on  $projection.ControllingArea = _Fund.FinancialManagementArea
                                        and $projection.Fund            = _Fund.Fund
{
  key cast( '1FXA' as psm_s4c_fm_fund_wu_obj_type_vh )                                           as FundWhereUsedObjType,
  key _Fund.FinancialManagementArea,
  key Fund,  
  key CompanyCode,
  key MasterFixedAsset,
  key FixedAsset,
  key ValidityEndDate,
      ValidityStartDate,
      _FixedAsset.FixedAssetDescription                                                          as FixedAssetDescription,
      _FixedAsset._AssetClass.AssetClass,
      _FixedAsset._AssetClass._Text[ Language = $session.system_language ].AssetClassName        as AssetClassName,
      ControllingArea,
      CostCenter,                
      BusinessArea,              
      Plant,                     
      AssetAuthorizationContext, 
      _CompanyCode.CompanyCodeName,
      _FixedAsset,
      _CompanyCode,      
      _MasterFixedAsset,
      _ControllingArea,
      _CostCenter,
      _BusinessArea,
      _Plant                          
}