P_FixedAssetPlanValue

@AbapCatalog: { sqlViewName: 'PFASSETPLAN',
                preserveKey:true,
                compiler.compareFilter: true}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private: true
@VDM.viewType: #BASIC
@ObjectModel: { usageType.serviceQuality: #C,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #MIXED }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

define view P_FixedAssetPlanValue
  as select  from faat_plan_values as Plan
{
  key Plan.bukrs                                              as CompanyCode,
  key Plan.anln1                                              as MasterFixedAsset,
  key Plan.anln2                                              as FixedAsset,
  key Plan.gjahr                                              as FiscalYear,
  key Plan.afabe                                              as AssetDepreciationArea,
  key Plan.poper                                              as FiscalPeriod,
  key cast(Plan.slalittype as fis_slalittype preserving type) as SubLedgerAcctLineItemType,

      @Semantics.fiscal.year: true
      Plan.gjahr                                              as LedgerFiscalYear,
      cast('2' as faa_use_val_ty)                             as PlannedValueIsInclusive,
      Plan.rldnr                                              as Ledger,
      Plan.movcat                                             as AssetAcctTransClassfctn,
      Plan.anlgr                                              as GroupMasterFixedAsset,
      Plan.anlgr2                                             as GroupFixedAsset,
      cast('A' as fis_koart)                                  as FinancialAccountType,
      Plan.recid                                              as JointVentureCostRecoveryCode,
      Plan.xpost                                              as DepreciationIsDue,

      Plan.rhcur                                              as CompanyCodeCurrency,
      Plan.hsl                                                as AmountInCompanyCodeCurrency,

      Plan.rkcur                                              as GlobalCurrency,
      Plan.ksl                                                as AmountInGlobalCurrency,

      Plan.rocur                                              as FreeDefinedCurrency1,
      Plan.osl                                                as AmountInFreeDefinedCurrency1,

      Plan.rvcur                                              as FreeDefinedCurrency2,
      Plan.vsl                                                as AmountInFreeDefinedCurrency2,

      Plan.rbcur                                              as FreeDefinedCurrency3,
      Plan.bsl                                                as AmountInFreeDefinedCurrency3,

      Plan.rccur                                              as FreeDefinedCurrency4,
      Plan.csl                                                as AmountInFreeDefinedCurrency4,

      Plan.rdcur                                              as FreeDefinedCurrency5,
      Plan.dsl                                                as AmountInFreeDefinedCurrency5,

      Plan.recur                                              as FreeDefinedCurrency6,
      Plan.esl                                                as AmountInFreeDefinedCurrency6,

      Plan.rfcur                                              as FreeDefinedCurrency7,
      Plan.fsl                                                as AmountInFreeDefinedCurrency7,

      Plan.rgcur                                              as FreeDefinedCurrency8,
      Plan.gsl                                                as AmountInFreeDefinedCurrency8

}
where
  Plan.movcat <> '00'

union all select from P_ACDOCP_COM as Plan
{
  key Plan.rbukrs                                             as CompanyCode,
  key Plan.anln1                                              as MasterFixedAsset,
  key Plan.anln2                                              as FixedAsset,
  key Plan.gjahr                                              as FiscalYear,
  key Plan.afabe                                              as AssetDepreciationArea,
  key Plan.poper                                              as FiscalPeriod,
  key cast(Plan.slalittype as fis_slalittype preserving type) as SubLedgerAcctLineItemType,

      @Semantics.fiscal.year: true
      Plan.ryear                                              as LedgerFiscalYear,
      cast('2' as faa_use_val_ty)                             as PlannedValueIsInclusive,
      Plan.rldnr                                              as Ledger,
      Plan.movcat                                             as AssetAcctTransClassfctn,
      cast('' as anlgr)                                       as GroupMasterFixedAsset,
      cast('' as anlgr2)                                      as GroupFixedAsset,
      cast('A' as fis_koart)                                  as FinancialAccountType,
      cast('' as jv_recind)                                   as JointVentureCostRecoveryCode,
      cast('' as faa_xpost)                                   as DepreciationIsDue,

      Plan.rhcur                                              as CompanyCodeCurrency,
      Plan.hsl                                                as AmountInCompanyCodeCurrency,

      Plan.rkcur                                              as GlobalCurrency,
      Plan.ksl                                                as AmountInGlobalCurrency,

      Plan.rocur                                              as FreeDefinedCurrency1,
      Plan.osl                                                as AmountInFreeDefinedCurrency1,

      Plan.rvcur                                              as FreeDefinedCurrency2,
      Plan.vsl                                                as AmountInFreeDefinedCurrency2,

      Plan.rbcur                                              as FreeDefinedCurrency3,
      Plan.bsl                                                as AmountInFreeDefinedCurrency3,

      Plan.rccur                                              as FreeDefinedCurrency4,
      Plan.csl                                                as AmountInFreeDefinedCurrency4,

      Plan.rdcur                                              as FreeDefinedCurrency5,
      Plan.dsl                                                as AmountInFreeDefinedCurrency5,

      Plan.recur                                              as FreeDefinedCurrency6,
      Plan.esl                                                as AmountInFreeDefinedCurrency6,

      Plan.rfcur                                              as FreeDefinedCurrency7,
      Plan.fsl                                                as AmountInFreeDefinedCurrency7,

      Plan.rgcur                                              as FreeDefinedCurrency8,
      Plan.gsl                                                as AmountInFreeDefinedCurrency8
}
where
  Plan.category = 'PFXDASSET'