P_EventBasedOrderPostingRule

@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

define view entity P_EventBasedOrderPostingRule
  // Material

  as select from           R_EventBasedDistrPostingRule as _Rule
    left outer to one join I_ProductText                as ProductText on  ProductText.Product  = _Rule.ProducedProduct
                                                                       and ProductText.Language = $session.system_language
{
  key _Rule.EventBasedDistrPostingRuleUUID,
      _Rule.SAPObjectNodeType,
      _Rule.ControllingObject,
      _Rule.ControllingObjectType,
      _Rule.EventBasedDistributionRuleSqnc,
      _Rule.EventBasedDistributionType,
      _Rule.EvtBsdDistrSourceStructure,
      _Rule.EvtBsdDistrSourceAssignment,
      _Rule.EventBasedDistrRateInPercent,
      _Rule.EvtBsdDistrEquivalenceFactor,
      _Rule.EventBasedDistributionDfltRule,
      _Rule.OrderID,
      _Rule.OrderItem,
      _Rule.OrderCategory,
      _Rule.IsSettled,
      _Rule.SalesOrder,
      _Rule.SalesOrderItem,
      _Rule.WBSElementInternalID,
      _Rule.ReceiverOrder,
      _Rule.PartnerOrderItem,
      _Rule.ProducedProduct, 
      _Rule.ReceiverCostCenter,

      _Rule.PartnerControllingObjectType,
      _Rule.ReceiverWBSElementInternalID,
      cast(_Rule.ProducedProduct as fco_ebpr_receiver)       as EvtBsdPostingRuleReceiver,
      cast(ProductText.ProductName as fco_ebpr_receiver_txt) as EvtBsdPostingRuleReceiverText,
      _Rule.EvtBsdDistrTracingFctrDetnMeth,
      _Rule.MfgOrdNonMatlRcvrAcctDetnMeth,
      _Rule.EnteredByUser,
      _Rule.CreationDate,
      _Rule.CreationTime,
      _Rule.LastChangedByUser,
      _Rule.LastChangeDate,
      _Rule.RecentlyChangedDateTime
}
where
  _Rule.PartnerControllingObjectType = 'MA'

// Order

union all select from    R_EventBasedDistrPostingRule as _Rule
  left outer to one join I_OrderBasic                 as OrderHeader on OrderHeader.OrderID = _Rule.ReceiverOrder
{
  key _Rule.EventBasedDistrPostingRuleUUID,
      _Rule.SAPObjectNodeType,
      _Rule.ControllingObject,
      _Rule.ControllingObjectType,
      _Rule.EventBasedDistributionRuleSqnc,
      _Rule.EventBasedDistributionType,
      _Rule.EvtBsdDistrSourceStructure,
      _Rule.EvtBsdDistrSourceAssignment,
      _Rule.EventBasedDistrRateInPercent,
      _Rule.EvtBsdDistrEquivalenceFactor,
      _Rule.EventBasedDistributionDfltRule,
      _Rule.OrderID,
      _Rule.OrderItem,
      _Rule.OrderCategory,
      _Rule.IsSettled,
      _Rule.SalesOrder,
      _Rule.SalesOrderItem,
      _Rule.WBSElementInternalID,
      _Rule.ReceiverOrder,
      _Rule.PartnerOrderItem,
      _Rule.ProducedProduct, 
      _Rule.ReceiverCostCenter,
      _Rule.PartnerControllingObjectType,
      _Rule.ReceiverWBSElementInternalID,
      cast(_Rule.ReceiverOrder as fco_ebpr_receiver)              as EvtBsdPostingRuleReceiver,
      cast(OrderHeader.OrderDescription as fco_ebpr_receiver_txt) as EvtBsdPostingRuleReceiverText,
      _Rule.EvtBsdDistrTracingFctrDetnMeth,
      _Rule.MfgOrdNonMatlRcvrAcctDetnMeth,
      _Rule.EnteredByUser,
      _Rule.CreationDate,
      _Rule.CreationTime,
      _Rule.LastChangedByUser,
      _Rule.LastChangeDate,
      _Rule.RecentlyChangedDateTime
}
where
  _Rule.PartnerControllingObjectType = 'OR'

// Order Item

union all select from    R_EventBasedDistrPostingRule as _Rule
  left outer to one join I_OrderItem                  as OrderItem on  OrderItem.OrderID = _Rule.OrderID
                                                                   and OrderItem.OrderItem = _Rule.PartnerOrderItem
{
  key _Rule.EventBasedDistrPostingRuleUUID,
      _Rule.SAPObjectNodeType,
      _Rule.ControllingObject,
      _Rule.ControllingObjectType,
      _Rule.EventBasedDistributionRuleSqnc,
      _Rule.EventBasedDistributionType,
      _Rule.EvtBsdDistrSourceStructure,
      _Rule.EvtBsdDistrSourceAssignment,
      _Rule.EventBasedDistrRateInPercent,
      _Rule.EvtBsdDistrEquivalenceFactor,
      _Rule.EventBasedDistributionDfltRule,
      _Rule.OrderID,
      _Rule.OrderItem,
      _Rule.OrderCategory,
      _Rule.IsSettled,
      _Rule.SalesOrder,
      _Rule.SalesOrderItem,
      _Rule.WBSElementInternalID,
      _Rule.ReceiverOrder,
      _Rule.PartnerOrderItem,
      _Rule.ProducedProduct, 
      _Rule.ReceiverCostCenter,
      _Rule.PartnerControllingObjectType,
      _Rule.ReceiverWBSElementInternalID,
      cast(_Rule.PartnerOrderItem as fco_ebpr_receiver) as EvtBsdPostingRuleReceiver,
      cast(OrderItem.Material as fco_ebpr_receiver_txt) as EvtBsdPostingRuleReceiverText,
      _Rule.EvtBsdDistrTracingFctrDetnMeth,
      _Rule.MfgOrdNonMatlRcvrAcctDetnMeth,
      _Rule.EnteredByUser,
      _Rule.CreationDate,
      _Rule.CreationTime,
      _Rule.LastChangedByUser,
      _Rule.LastChangeDate,
      _Rule.RecentlyChangedDateTime

}
where
  _Rule.PartnerControllingObjectType = 'OP'
// Cost Center

union all select from    R_EventBasedDistrPostingRule as _Rule
  inner join             I_OrderBasic                 as OrderMasterContext on OrderMasterContext.OrderID = _Rule.OrderID
  left outer to one join I_CostCenterText             as CostCenterText     on  CostCenterText.CostCenter        = _Rule.ReceiverCostCenter
                                                                            and CostCenterText.ControllingArea   = OrderMasterContext.ControllingArea
                                                                            and CostCenterText.Language          = $session.system_language
                                                                            and CostCenterText.ValidityStartDate <= $session.system_date
                                                                            and CostCenterText.ValidityEndDate   >= $session.system_date
{
  key _Rule.EventBasedDistrPostingRuleUUID,
      _Rule.SAPObjectNodeType,
      _Rule.ControllingObject,
      _Rule.ControllingObjectType,
      _Rule.EventBasedDistributionRuleSqnc,
      _Rule.EventBasedDistributionType,
      _Rule.EvtBsdDistrSourceStructure,
      _Rule.EvtBsdDistrSourceAssignment,
      _Rule.EventBasedDistrRateInPercent,
      _Rule.EvtBsdDistrEquivalenceFactor,
      _Rule.EventBasedDistributionDfltRule,
      _Rule.OrderID,
      _Rule.OrderItem,
      _Rule.OrderCategory,
      _Rule.IsSettled,
      _Rule.SalesOrder,
      _Rule.SalesOrderItem,
      _Rule.WBSElementInternalID,
      _Rule.ReceiverOrder,
      _Rule.PartnerOrderItem,
      _Rule.ProducedProduct, 
      _Rule.ReceiverCostCenter,
      _Rule.PartnerControllingObjectType,
      _Rule.ReceiverWBSElementInternalID,
      cast(_Rule.ReceiverCostCenter as fco_ebpr_receiver)                 as EvtBsdPostingRuleReceiver,
      cast(CostCenterText.CostCenterDescription as fco_ebpr_receiver_txt) as EvtBsdPostingRuleReceiverText,
      _Rule.EvtBsdDistrTracingFctrDetnMeth,
      _Rule.MfgOrdNonMatlRcvrAcctDetnMeth,
      _Rule.EnteredByUser,
      _Rule.CreationDate,
      _Rule.CreationTime,
      _Rule.LastChangedByUser,
      _Rule.LastChangeDate,
      _Rule.RecentlyChangedDateTime
}
where
  _Rule.PartnerControllingObjectType = 'KS'

// WBS Element (WBS Element Internal ID is provided)

union all select from    R_EventBasedDistrPostingRule as _Rule
  left outer to one join I_WBSElementBasicData        as WBSElement on WBSElement.WBSElementInternalID = _Rule.ReceiverWBSElementInternalID
{
  key _Rule.EventBasedDistrPostingRuleUUID,
      _Rule.SAPObjectNodeType,
      _Rule.ControllingObject,
      _Rule.ControllingObjectType,
      _Rule.EventBasedDistributionRuleSqnc,
      _Rule.EventBasedDistributionType,
      _Rule.EvtBsdDistrSourceStructure,
      _Rule.EvtBsdDistrSourceAssignment,
      _Rule.EventBasedDistrRateInPercent,
      _Rule.EvtBsdDistrEquivalenceFactor,
      _Rule.EventBasedDistributionDfltRule,
      _Rule.OrderID,
      _Rule.OrderItem,
      _Rule.OrderCategory,
      _Rule.IsSettled,
      _Rule.SalesOrder,
      _Rule.SalesOrderItem,
      _Rule.WBSElementInternalID,   
      _Rule.ReceiverOrder,
      _Rule.PartnerOrderItem,
      _Rule.ProducedProduct,                
      _Rule.ReceiverCostCenter,            
      _Rule.PartnerControllingObjectType,
      _Rule.ReceiverWBSElementInternalID,
      cast(_Rule.ReceiverWBSElementInternalID as fco_ebpr_receiver) as EvtBsdPostingRuleReceiver,
      cast(WBSElement.WBSDescription as fco_ebpr_receiver_txt)   as EvtBsdPostingRuleReceiverText,
      _Rule.EvtBsdDistrTracingFctrDetnMeth,
      _Rule.MfgOrdNonMatlRcvrAcctDetnMeth,
      _Rule.EnteredByUser,
      _Rule.CreationDate,
      _Rule.CreationTime,
      _Rule.LastChangedByUser,
      _Rule.LastChangeDate,
      _Rule.RecentlyChangedDateTime
}
where
      _Rule.PartnerControllingObjectType = 'PR'
  and _Rule.ReceiverWBSElementInternalID is not initial