P_EquiTimeSegFuncLocationUnion

@VDM.private: true
@VDM.viewType:#COMPOSITE
@AbapCatalog.sqlViewName: 'PEQTSEGFLOCU'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType:{
    serviceQuality: #C,
    sizeCategory: #XL,
    dataClass: #MIXED
}
define view P_EquiTimeSegFuncLocationUnion as select from           I_EquipmentTimeSeg          as _EquipmentTimeSeg
   
    left outer to one join I_Equipment                                               on I_Equipment.Equipment = _EquipmentTimeSeg.Equipment
    left outer to one join I_LocationAccountAssignment as _LocationAccountAssignment on _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr = _EquipmentTimeSeg.MaintObjectLocAcctAssgmtNmbr


{
  key cast ( _EquipmentTimeSeg.Equipment as eams_tec_obj )                                                           as TechnicalObject,
      @Environment.sql.passValue: true
  key cast ( 'EAMS_EQUI' as eams_tec_obj_type_value)                                                                 as TechObjIsEquipOrFuncnlLoc,
  key    _EquipmentTimeSeg.ValidityEndDate,
  key _EquipmentTimeSeg.EquipUsagePeriodSequenceNumber,
   _EquipmentTimeSeg.ValidityEndTime,
      _EquipmentTimeSeg.ValidityStartDate,

      _EquipmentTimeSeg.Equipment,
      cast( '' as tplnr )                                                                                            as FunctionalLocation,

      cast( I_Equipment.EquipmentCategory as eams_tec_obj_cat )                                                      as TechnicalObjectCategory,
      I_Equipment.TechnicalObjectType,
      I_Equipment.CreatedByUser,
      I_Equipment.CreationDate,
      I_Equipment.LastChangedByUser,
      I_Equipment.LastChangeDate,
      I_Equipment.AssetManufacturerName,
      I_Equipment.ManufacturerPartTypeName,
      _EquipmentTimeSeg.MaintenancePlanningPlant,
      _EquipmentTimeSeg.MaintenancePlannerGroup,
      _EquipmentTimeSeg.CatalogProfile,
      I_Equipment.AuthorizationGroup,
      _EquipmentTimeSeg.WorkCenterInternalID,
      _EquipmentTimeSeg.WorkCenterTypeCode,
      _EquipmentTimeSeg.MaintObjectLocAcctAssgmtNmbr,
      I_Equipment.ManufacturerCountry,
      I_Equipment.ConstructionYear,
      I_Equipment.ConstructionMonth,
      _EquipmentTimeSeg.ConstructionMaterial,
      I_Equipment.AcquisitionDate,
      I_Equipment.Currency,
      I_Equipment.AcquisitionValue,
      I_Equipment.MaintObjectInternalID,
      _EquipmentTimeSeg.TechnicalObjectSortCode,
      _EquipmentTimeSeg.ManufacturerPartNmbr,
      I_Equipment.SizeOrDimensionText,
      I_Equipment.ManufacturerSerialNumber,
      I_Equipment.InventoryNumber,
      I_Equipment.GrossWeight,
      I_Equipment.GrossWeightUnit,
      I_Equipment.OperationStartDate,
      cast ( '00' as ilom_level_kz )                                                                                 as FuncLocStrucIdentifyingLevel,
      cast ( '00' as ilom_level_kz2 )                                                                                as FuncLocStruc2ndIdentifyingLvl,
      cast ( '     ' as tplkz )                                                                                      as FuncLocationStructure,

      _LocationAccountAssignment.SalesOrganization,
      _LocationAccountAssignment.DistributionChannel,
      _LocationAccountAssignment.SalesOffice,
      _LocationAccountAssignment.OrganizationDivision,
      _LocationAccountAssignment.SalesGroup,
      _LocationAccountAssignment.AssetLocation,
      _LocationAccountAssignment._Location.LocationName,

      cast( _EquipmentText[1: Language = $session.system_language].EquipmentName
            as eams_tec_obj_des preserving type )                                                                    as TechnicalObjectDescription,
      _EquipmentText[1: Language = $session.system_language].EquipmentHasLongText                                    as TechnicalObjectHasLongText,
      cast( case when _EquipmentTimeSeg.SuperordinateEquipment <> ''
           then _EquipmentTimeSeg.SuperordinateEquipment
           else _LocationAccountAssignment.FunctionalLocation
           end as eams_tec_obj )                                                                                     as SuperiorTechnicalObject,
      cast( case when _EquipmentTimeSeg.SuperordinateEquipment <> ''
           then _EquipmentTimeSeg.SuperordinateEquipment
           else _LocationAccountAssignment._FunctionalLocation._FunctionalLocationLabel.FunctionalLocationLabelName
           end as eams_tech_obj_conv )                                                                               as SuperiorTechnicalObjectLabel,
      cast( case when _EquipmentTimeSeg.SuperordinateEquipment <> ''
                 then _EquipmentTimeSeg._SuperordinateEquipmentText[1: Language = $session.system_language].EquipmentName
                 else _LocationAccountAssignment._FunctionalLocation._FunctionalLocationText[1: Language = $session.system_language].FunctionalLocationName
                 end as eams_tec_obj_des )                                                                           as SuperiorTechnicalObjectName,
      cast( case when _EquipmentTimeSeg.SuperordinateEquipment <> '' then 'EAMS_EQUI'
           when _LocationAccountAssignment.FunctionalLocation <> '' then 'EAMS_FL' end  as eams_tec_obj_type_value ) as SuperiorObjIsEquipOrFuncnlLoc,
      _LocationAccountAssignment.FunctionalLocation                                                                  as SuperiorFunctionalLocation,
      _EquipmentTimeSeg.SuperordinateEquipment
}

union all select from I_FunctionalLocation
{
  key cast ( I_FunctionalLocation.FunctionalLocation as eams_tec_obj )                           as TechnicalObject,
  key cast ( 'EAMS_FL' as eams_tec_obj_type_value)                                               as TechObjIsEquipOrFuncnlLoc,
  key cast('99991231' as datbi ) as ValidityEndDate,
   key cast( '001' as eqlfn ) as EquipUsagePeriodSequenceNumber,
   cast('000000' as tims ) as ValidityEndTime,
      cast('19700101' as datbi ) as ValidityStartDate,

      cast ('' as equnr)                                                                         as Equipment,
      I_FunctionalLocation.FunctionalLocation,

      cast( I_FunctionalLocation.FunctionalLocationCategory as eams_tec_obj_cat )                as TechnicalObjectCategory,
      I_FunctionalLocation.TechnicalObjectType,
      I_FunctionalLocation.CreatedByUser,
      I_FunctionalLocation.CreationDate,
      I_FunctionalLocation.LastChangedByUser,
      I_FunctionalLocation.LastChangeDate,
      I_FunctionalLocation.AssetManufacturerName,
      I_FunctionalLocation.ManufacturerPartTypeName,
      I_FunctionalLocation.MaintenancePlanningPlant,
      I_FunctionalLocation.MaintenancePlannerGroup,
      I_FunctionalLocation.CatalogProfile,
      I_FunctionalLocation.AuthorizationGroup,
      I_FunctionalLocation.WorkCenterInternalID,
      I_FunctionalLocation.WorkCenterTypeCode,
      I_FunctionalLocation.MaintObjectLocAcctAssgmtNmbr,
      I_FunctionalLocation.ManufacturerCountry,
      I_FunctionalLocation.ConstructionYear,
      I_FunctionalLocation.ConstructionMonth,
      I_FunctionalLocation.ConstructionMaterial,
      I_FunctionalLocation.AcquisitionDate,
      I_FunctionalLocation.Currency,
      I_FunctionalLocation.AcquisitionValue,
      I_FunctionalLocation.MaintObjectInternalID,
      // dummy usage -- can't have empty field due to free-text search:

      _LocationAccountAssignment.MaintObjectFreeDefinedAttrib                                    as TechnicalObjectSortCode,
      I_FunctionalLocation.ManufacturerPartNmbr,
      I_FunctionalLocation.SizeOrDimensionText,
      I_FunctionalLocation.ManufacturerSerialNumber,
      I_FunctionalLocation.InventoryNumber,
      I_FunctionalLocation.GrossWeight,
      I_FunctionalLocation.GrossWeightUnit,
      I_FunctionalLocation.OperationStartDate,
      I_FunctionalLocation._FuncLocationStructure.FuncLocStrucIdentifyingLevel,
      I_FunctionalLocation._FuncLocationStructure.FuncLocStruc2ndIdentifyingLvl,
      I_FunctionalLocation._FuncLocationStructure.FuncLocationStructure,

      I_FunctionalLocation._LocationAccountAssignment.SalesOrganization,
      I_FunctionalLocation._LocationAccountAssignment.DistributionChannel,
      I_FunctionalLocation._LocationAccountAssignment.SalesOffice,
      I_FunctionalLocation._LocationAccountAssignment.OrganizationDivision,
      I_FunctionalLocation._LocationAccountAssignment.SalesGroup,
      I_FunctionalLocation._LocationAccountAssignment.AssetLocation,
      I_FunctionalLocation._LocationAccountAssignment._Location.LocationName,

      cast( _FunctionalLocationText[1: Language = $session.system_language].FunctionalLocationName
            as eams_tec_obj_des preserving type )                                                as TechnicalObjectDescription,
      _FunctionalLocationText[1: Language = $session.system_language].FuncnlLocHasLongText       as TechnicalObjectHasLongText,
      SuperiorFunctionalLocation                                                                 as SuperiorTechnicalObject,
      _SuperiorFunctionalLocation._FunctionalLocationLabel.FunctionalLocationLabelName           as SuperiorTechnicalObjectLabel,
      _SupFunctionalLocationText[1: Language = $session.system_language ].FunctionalLocationName as SuperiorTechnicalObjectName,
      case when SuperiorFunctionalLocation <> '' then 'EAMS_FL' end                              as SuperiorObjIsEquipOrFuncnlLoc,
      SuperiorFunctionalLocation,
      ''                                                                                         as SuperordinateEquipment
}