P_EntProjCostLineItems

@AbapCatalog.sqlViewName: 'PEPSRPRLS'
@VDM.viewType: #COMPOSITE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
define view P_EntProjCostLineItems
//Change For EPPM Release 25O2

// Prediction value inconsistency

  with parameters
  @Consumption.valueHelpDefinition : { entity : {name: 'C_CostCategoryVH', element: 'PlanningCategory'} }
  @Consumption.defaultValue: 'PLN'
    P_PlanningCategory : fcom_category
//// End of Change For EPPM Release 25O2   

 as select from   
//  Begin Change For EPPM Release 25O2 

// I_ProjectCostLineItems       as ProjCost


    P_PROJCSTLINEITEMS(P_PlanningCategory: :P_PlanningCategory)  as ProjCost
// End of Change For EPPM Release 25O2  

    left outer join I_EnterpriseProject          as EntProj       on ProjCost.ProjectInternalID = EntProj.ProjectInternalID
    left outer join I_PPM_ProjTeamMembersCntNoSt as TeamMemberCnt on TeamMemberCnt.ProjectSummaryTaskUUID = EntProj.ProjectSummaryTaskUUID

  association [0..1] to I_SingleResponsibleForProj as _Responsible on _Responsible.ReferencedObjectUUID = EntProj.ProjectSummaryTaskUUID
{

  key  EntProj.ProjectSummaryTaskUUID,
  key  ProjCost.ProjectInternalID,
  key  EntProj.ProjectUUID,
  key  ProjCost.Ledger,  // Change For EPPM Release 25O2 

       EntProj.Project,
       EntProj.ProjectDescription,
       EntProj.ProfitCenter,
       EntProj.FunctionalArea,
       EntProj.ResponsibleCostCenter,
       EntProj.ProjectStartDate,
       EntProj.ProjectEndDate,
       EntProj.CompanyCode,
       EntProj.ControllingArea,
       //CE2402 /S4PPM/PR1 changes - Begin 

       ProjCost.Plant,
       ProjCost.ProjectProfileCode,
       ProjCost.ProjectType,
       //CE2402 /S4PPM/PR1 changes - End

       case
          when EntProj.ProjectStartDate > '19000101'
            and EntProj.ProjectEndDate > '19000101'
          then cast ((dats_days_between(EntProj.ProjectStartDate, EntProj.ProjectEndDate) + 1) as numberofdays )
          else 0
       end                                           as PlannedDuration,
       // Actual Costs Excluding Settlements

       sum(case
       when ProjCost.IsSettled = 'X'
       then  ProjCost.ActualAmountInGlobalCurrency
       else 0  end)                                  as ActualAmountInGlobalCurrency,
       sum(ProjCost.PlanAmountInGlobalCurrency)      as PlanAmountInGlobalCurrency,
       ProjCost.GlobalCurrency,
       _Responsible.BusinessPartnerUUID,
       _Responsible.BusinessPartnerFullName,
       cast( TeamMemberCnt.TeamMemberCount as int4 ) as TeamMemberCount
}

group by
  EntProj.ProjectSummaryTaskUUID,
  ProjCost.ProjectInternalID,
  ProjCost.Ledger,
  EntProj.Project,
  EntProj.ProjectUUID,
  EntProj.ProjectDescription,
  EntProj.ProfitCenter,
  EntProj.FunctionalArea,
  EntProj.ResponsibleCostCenter,
  EntProj.ProjectStartDate,
  EntProj.ProjectEndDate,
  EntProj.CompanyCode,
  EntProj.ControllingArea,
  ProjCost.GlobalCurrency,
  _Responsible.BusinessPartnerUUID,
  _Responsible.BusinessPartnerFullName,
  TeamMemberCnt.TeamMemberCount,
  //CE2402 /S4PPM/PR1 changes - Begin 

  ProjCost.Plant,
  ProjCost.ProjectProfileCode,
  ProjCost.ProjectType
  //CE2402 /S4PPM/PR1 changes - End