P_EBWIP_WIP1

@AbapCatalog.sqlViewName: 'PEBWIPWIP1'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE
@VDM.private: true

define view P_EBWIP_WIP1
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : datum,
    P_Ledger  : fins_ledger
  as select from I_GLAccountLineItemRawData // I_JournalEntryItem

{
  key CompanyCode,
  key OrderID,
  key SubLedgerAcctLineItemType,

      sum(AmountInCompanyCodeCurrency)  as AmountInCompanyCodeCurrency,
      sum(AmountInGlobalCurrency)       as AmountInGlobalCurrency,

      sum(AmountInFreeDefinedCurrency1) as AmountInFreeDefinedCurrency1,
      sum(AmountInFreeDefinedCurrency2) as AmountInFreeDefinedCurrency2,
      sum(AmountInFreeDefinedCurrency3) as AmountInFreeDefinedCurrency3,
      sum(AmountInFreeDefinedCurrency4) as AmountInFreeDefinedCurrency4,
      sum(AmountInFreeDefinedCurrency5) as AmountInFreeDefinedCurrency5,
      sum(AmountInFreeDefinedCurrency6) as AmountInFreeDefinedCurrency6,
      sum(AmountInFreeDefinedCurrency7) as AmountInFreeDefinedCurrency7,
      sum(AmountInFreeDefinedCurrency8) as AmountInFreeDefinedCurrency8
}
where
      SourceLedger      = :P_Ledger
  and PostingDate <= $parameters.P_KeyDate
  and   (
       SubLedgerAcctLineItemType   = '09100'
    or SubLedgerAcctLineItemType   = '09110'
  )
  and  BusinessTransactionCategory = 'EBWP'
group by
  CompanyCode,
  OrderID,
  SubLedgerAcctLineItemType