P_EBPAO_WIPOverview2

DDL: P_EBPAO_WIPOVERVIEW2 Type: view COMPOSITE Package: ODATA_CO_EB_PRODN_ACCTG_OVW

Event-Based Production Accounting Overview WIP 2

P_EBPAO_WIPOverview2 is a Composite CDS View that provides data about "Event-Based Production Accounting Overview WIP 2" in SAP S/4HANA. It reads from 2 data sources (I_LedgerCompanyCodeCrcyRoles, P_EBPAO_WIPOverview1) and exposes 4 fields with key fields Ledger, CompanyCode, OrderID, OrderItem. Part of development package ODATA_CO_EB_PRODN_ACCTG_OVW.

2 data source(s) 4 fields

Data Sources (2)

SourceAliasJoin Type
I_LedgerCompanyCodeCrcyRoles _LedgerCompanyCodeCrcyRole inner
P_EBPAO_WIPOverview1 P_EBPAO_WIPOverview1 from

Parameters (3)

NameTypeDefault
P_Ledger fins_ledger
P_ToFiscalYearPeriod fins_fyearperiod
P_CurrencyRole fis_curtp

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName PEBPAOWIPOVW2 view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #NOT_REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view
VDM.private true view
VDM.viewType #COMPOSITE view

Fields (4)

KeyFieldSource TableSource FieldDescription
KEY Ledger WIPCost Ledger
KEY CompanyCode WIPCost CompanyCode
KEY OrderID WIPCost OrderID
KEY OrderItem WIPCost OrderItem 
@AbapCatalog: {
  sqlViewName: 'PEBPAOWIPOVW2',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@VDM: {
  private: true,
  viewType: #COMPOSITE
}
define view P_EBPAO_WIPOverview2 
  with parameters
    P_Ledger               : fins_ledger,
    P_ToFiscalYearPeriod   : fins_fyearperiod,
    P_CurrencyRole         : fis_curtp
  as select from P_EBPAO_WIPOverview1( P_Ledger              : :P_Ledger,
                                       P_ToFiscalYearPeriod  : :P_ToFiscalYearPeriod ) as WIPCost
    inner join   I_LedgerCompanyCodeCrcyRoles                                          as _LedgerCompanyCodeCrcyRole on  _LedgerCompanyCodeCrcyRole.CompanyCode = WIPCost.CompanyCode
                                                                                                                     and _LedgerCompanyCodeCrcyRole.Ledger      = :P_Ledger
{
  key WIPCost.Ledger,
  key WIPCost.CompanyCode,
  key WIPCost.OrderID,
  key WIPCost.OrderItem,

      cast(
        case :P_CurrencyRole
           when _LedgerCompanyCodeCrcyRole.CompanyCodeCurrencyRole  then WIPCost.AmountInCompanyCodeCurrency
           when _LedgerCompanyCodeCrcyRole.GlobalCurrencyRole       then WIPCost.AmountInGlobalCurrency
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency1Role then WIPCost.AmountInFreeDefinedCurrency1
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency2Role then WIPCost.AmountInFreeDefinedCurrency2
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency3Role then WIPCost.AmountInFreeDefinedCurrency3
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency4Role then WIPCost.AmountInFreeDefinedCurrency4
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency5Role then WIPCost.AmountInFreeDefinedCurrency5
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency6Role then WIPCost.AmountInFreeDefinedCurrency6
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency7Role then WIPCost.AmountInFreeDefinedCurrency7
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency8Role then WIPCost.AmountInFreeDefinedCurrency8
         else 0
      end as farp_amount_display_crcy) as AmountInDisplayCurrency
}

Learn More