P_EBOrderSplitVarianceCost1

@AbapCatalog.sqlViewName: 'PEBORDSVRCCS1'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.private: true
@VDM.viewType: #COMPOSITE

define view P_EBOrderSplitVarianceCost1
  with parameters
    P_Ledger               : fins_ledger,
    P_FromFiscalYearPeriod : fins_fyearperiod,
    P_ToFiscalYearPeriod   : fins_fyearperiod

  as select from I_JournalEntryItem
{
  key CompanyCode,
  key case
        when OrderID = '' then OriginOrder // V-Price Variance (BSX transaction)

        else OrderID
      end                               as OrderID,
  key OrderItem,
  key SubLedgerAcctLineItemType,

      sum(AmountInCompanyCodeCurrency)  as AmountInCompanyCodeCurrency,
      sum(AmountInGlobalCurrency)       as AmountInGlobalCurrency,
      sum(FixedAmountInGlobalCrcy)      as FixedAmountInGlobalCrcy,

      sum(AmountInFreeDefinedCurrency1) as AmountInFreeDefinedCurrency1,
      sum(AmountInFreeDefinedCurrency2) as AmountInFreeDefinedCurrency2,
      sum(AmountInFreeDefinedCurrency3) as AmountInFreeDefinedCurrency3,
      sum(AmountInFreeDefinedCurrency4) as AmountInFreeDefinedCurrency4,
      sum(AmountInFreeDefinedCurrency5) as AmountInFreeDefinedCurrency5,
      sum(AmountInFreeDefinedCurrency6) as AmountInFreeDefinedCurrency6,
      sum(AmountInFreeDefinedCurrency7) as AmountInFreeDefinedCurrency7,
      sum(AmountInFreeDefinedCurrency8) as AmountInFreeDefinedCurrency8
}
where
  (
       SubLedgerAcctLineItemType    =  '09130' //Input Price Variance

    or SubLedgerAcctLineItemType    =  '09131' //Input Quantity variance

    or SubLedgerAcctLineItemType    =  '09132' //Resource Usage variance

    or SubLedgerAcctLineItemType    =  '09138' //Output Price Variance

    or SubLedgerAcctLineItemType    =  '09139' //Lot Size variance

    or SubLedgerAcctLineItemType    =  '09140' //Remaining variance

  )
  and  BusinessTransactionCategory  =  'EBVP'
  and  TransactionTypeDetermination <> 'GBB'
  and  FiscalYearPeriod             >= $parameters.P_FromFiscalYearPeriod
  and  FiscalYearPeriod             <= $parameters.P_ToFiscalYearPeriod
  and  Ledger                       =  :P_Ledger
group by
  CompanyCode,
  OrderID,
  OriginOrder,
  OrderItem,
  SubLedgerAcctLineItemType