P_EBORDERACTUALOUTPUTQTYCRCY

DDL: P_EBORDERACTUALOUTPUTQTYCRCY Type: view_entity CONSUMPTION Package: ODATA_CO_RT_PRODUCTION_COSTS

Event Based Production Order Actual Out Qty Display Currency

P_EBORDERACTUALOUTPUTQTYCRCY is a Consumption CDS View that provides data about "Event Based Production Order Actual Out Qty Display Currency" in SAP S/4HANA. It reads from 1 data source (I_GLAccountLineItemRawData) and exposes 17 fields with key fields ControllingObject, OrderID, OrderItem. Part of development package ODATA_CO_RT_PRODUCTION_COSTS.

1 data source(s) 17 fields

Data Sources (1)

SourceAliasJoin Type
I_GLAccountLineItemRawData I_GLAccountLineItemRawData from

Parameters (3)

NameTypeDefault
P_Ledger fins_ledger
P_FromFiscalYearPeriod fis_jahrper
P_ToFiscalYearPeriod fis_jahrper

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view
VDM.private true view
VDM.viewType #CONSUMPTION view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY ControllingObject ControllingObject
KEY OrderID OrderID
KEY OrderItem OrderItem
CompanyCode CompanyCode
ProducedProduct Product
CompanyCodeCurrency CompanyCodeCurrency
GlobalCurrency GlobalCurrency
FreeDefinedCurrency1 FreeDefinedCurrency1
FreeDefinedCurrency2 FreeDefinedCurrency2
FreeDefinedCurrency3 FreeDefinedCurrency3
FreeDefinedCurrency4 FreeDefinedCurrency4
FreeDefinedCurrency5 FreeDefinedCurrency5
FreeDefinedCurrency6 FreeDefinedCurrency6
FreeDefinedCurrency7 FreeDefinedCurrency7
FreeDefinedCurrency8 FreeDefinedCurrency8
BaseUnit BaseUnit
PostingDate 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.private: true
@VDM.viewType: #CONSUMPTION
define view entity P_EBORDERACTUALOUTPUTQTYCRCY
  with parameters
    P_Ledger               : fins_ledger,
    P_FromFiscalYearPeriod : fis_jahrper,
    P_ToFiscalYearPeriod   : fis_jahrper
  as select from I_GLAccountLineItemRawData
{

  key ControllingObject,
  key OrderID,
  key OrderItem,
      
      CompanyCode,
      Product as ProducedProduct,
      CompanyCodeCurrency  as CompanyCodeCurrency,
      GlobalCurrency       as GlobalCurrency,
      FreeDefinedCurrency1 as FreeDefinedCurrency1,
      FreeDefinedCurrency2 as FreeDefinedCurrency2,
      FreeDefinedCurrency3 as FreeDefinedCurrency3,
      FreeDefinedCurrency4 as FreeDefinedCurrency4,
      FreeDefinedCurrency5 as FreeDefinedCurrency5,
      FreeDefinedCurrency6 as FreeDefinedCurrency6,
      FreeDefinedCurrency7 as FreeDefinedCurrency7,
      FreeDefinedCurrency8 as FreeDefinedCurrency8,

      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      sum(
        case 
          when ValuationQuantity is not initial then - ValuationQuantity
          else - Quantity 
        end
      )    as ActualOutputQuantity,
//      @Semantics.unitOfMeasure:true

      BaseUnit,
      max(PostingDate) as PostingDate
}
where
        SourceLedger                 =  $parameters.P_Ledger
  and(
        AccountAssignmentType        =  'OR'
    or  AccountAssignmentType        =  'OP'
  )
  and   OriginCtrlgDebitCreditCode   =  'L'
  and   TransactionTypeDetermination =  'GBB'
  and   BusinessTransactionCategory  <> 'TBCS'
  and   Product                     is not null
  and(
        FiscalYearPeriod             >= $parameters.P_FromFiscalYearPeriod
    and FiscalYearPeriod             <= $parameters.P_ToFiscalYearPeriod
  )
group by
  ControllingObject,
  OrderID,
  OrderItem,
  CompanyCode,
  Product,
  BaseUnit,
  CompanyCodeCurrency,
  GlobalCurrency,
  FreeDefinedCurrency1,
  FreeDefinedCurrency2,
  FreeDefinedCurrency3,
  FreeDefinedCurrency4,
  FreeDefinedCurrency5,
  FreeDefinedCurrency6,
  FreeDefinedCurrency7,
  FreeDefinedCurrency8

Learn More