P_EBASO_WIP1

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true

@VDM.private: true
@VDM.viewType: #COMPOSITE

define view entity P_EBASO_WIP1
  with parameters
    P_FromFiscalYearPeriod : fis_jahrper,
    P_ToFiscalYearPeriod   : fis_jahrper,
    P_Ledger               : fins_ledger
  as select from I_JournalEntryItem
{
  key CompanyCode,
  key FiscalYear,
  key AccountingDocument,
  key LedgerGLLineItem,
  key Ledger,
  key cast('32' as co_wrttp)                                as ControllingValueType, // WIP


      ControllingArea,
      cast(GLAccount as fis_racct)                          as CostElement,
      BusinessTransactionCategory,
      OriginCtrlgDebitCreditCode                            as ControllingDebitCreditCode,
      OriginSenderObject,
      OrderID,
      OrderItem,
      AccountAssignmentType,
      PartnerAccountAssignment,
      PartnerAccountAssignmentType,
      PartnerCostCenter,
      PartnerCostCtrActivityType,
      PartnerBusinessProcess,
      PartnerOrder_2                                        as PartnerOrder,
      cast(BaseUnit as meins)                               as UnitOfMeasure,
      SubLedgerAcctLineItemType,
      OriginCostCenter,
      OriginCostCtrActivityType,
      'D'                                                   as CtrlgOriginClassification, //Origin Indicator


      CompanyCodeCurrency,
      GlobalCurrency,
      FreeDefinedCurrency1,
      FreeDefinedCurrency2,
      FreeDefinedCurrency3,
      FreeDefinedCurrency4,
      FreeDefinedCurrency5,
      FreeDefinedCurrency6,
      FreeDefinedCurrency7,
      FreeDefinedCurrency8,

      cast(AmountInCompanyCodeCurrency as abap.dec(23, 2))  as AmountInCompanyCodeCurrency,
      cast(AmountInGlobalCurrency as abap.dec(23, 2))       as AmountInGlobalCurrency,
      cast(AmountInFreeDefinedCurrency1 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency1,
      cast(AmountInFreeDefinedCurrency2 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency2,
      cast(AmountInFreeDefinedCurrency3 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency3,
      cast(AmountInFreeDefinedCurrency4 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency4,
      cast(AmountInFreeDefinedCurrency5 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency5,
      cast(AmountInFreeDefinedCurrency6 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency6,
      cast(AmountInFreeDefinedCurrency7 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency7,
      cast(AmountInFreeDefinedCurrency8 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency8,
      cast(FixedAmountInGlobalCrcy as abap.dec(23, 2))      as FixedAmountInGlobalCrcy,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      Quantity                                              as TotalQuantity
}
where
  (
       SubLedgerAcctLineItemType   = '09100'
    or SubLedgerAcctLineItemType   = '09110'
  )
  and  BusinessTransactionCategory = 'EBWP'
  and  Ledger                      = $parameters.P_Ledger
  and  FiscalYearPeriod            >= $parameters.P_FromFiscalYearPeriod
  and  FiscalYearPeriod            <= $parameters.P_ToFiscalYearPeriod