P_EBASO_OrderPlanCost1

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true

@VDM.private: true
@VDM.viewType: #COMPOSITE

define view entity P_EBASO_OrderPlanCost1
  with parameters
    P_FromFiscalYearPeriod : fis_jahrper,
    P_ToFiscalYearPeriod   : fis_jahrper,
    P_Ledger               : fins_ledger
  as select from I_FinancialPlanningEntryItem
{
  key FinancialPlanningReqTransSqnc,
  key FinancialPlanningDataPacket,
  key FinancialPlanningEntryItem,
  key '01'                                                  as ControllingValueType, // Plan Cost


      CompanyCode,
      Plant,
      ControllingArea,
      PlanningCategory,
      cast(GLAccount as fis_saknr)                          as CostElement,
      BusinessTransactionCategory,
      ControllingDebitCreditCode,
      case
        when BusinessTransactionCategory = 'KPPP' then 'P'
        else 'S'
      end                                                   as CtrlgOriginClassification,
      OrderID,
      cast(
        case AccountAssignmentType
          when 'OR' then '0000'
          else OrderItem
        end
      as co_posnr)                                          as OrderItem,
      AccountAssignmentType,
      PartnerAccountAssignmentType,
      PartnerCostCenter,
      PartnerCostCtrActivityType,
      PartnerOrder_2                                        as PartnerOrder,
      CostSourceUnit                                        as UnitOfMeasure,
      Material,
      IsLotSizeIndependent,
      CostOriginGroup,
      OriginCostCenter,
      OriginCostCtrActivityType,

      CompanyCodeCurrency,
      GlobalCurrency,
      FreeDefinedCurrency1,
      FreeDefinedCurrency2,
      FreeDefinedCurrency3,
      FreeDefinedCurrency4,
      FreeDefinedCurrency5,
      FreeDefinedCurrency6,
      FreeDefinedCurrency7,
      FreeDefinedCurrency8,

      cast(AmountInCompanyCodeCurrency as abap.dec(23, 2))  as AmountInCompanyCodeCurrency,
      cast(AmountInGlobalCurrency as abap.dec(23, 2))       as AmountInGlobalCurrency,
      cast(AmountInFreeDefinedCurrency1 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency1,
      cast(AmountInFreeDefinedCurrency2 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency2,
      cast(AmountInFreeDefinedCurrency3 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency3,
      cast(AmountInFreeDefinedCurrency4 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency4,
      cast(AmountInFreeDefinedCurrency5 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency5,
      cast(AmountInFreeDefinedCurrency6 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency6,
      cast(AmountInFreeDefinedCurrency7 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency7,
      cast(AmountInFreeDefinedCurrency8 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency8,
      cast(FixedAmountInGlobalCrcy as abap.dec(23, 2))      as FixedAmountInGlobalCrcy,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      ValuationQuantity                                     as Quantity
}
where
  (
       AccountAssignmentType = 'OR'
    or AccountAssignmentType = 'OP'
  )
  and  Ledger                = $parameters.P_Ledger
  and  FiscalYearPeriod      >= $parameters.P_FromFiscalYearPeriod
  and  FiscalYearPeriod      <= $parameters.P_ToFiscalYearPeriod