P_EBASO_EvtBsdVariance1

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true

@VDM.private: true
@VDM.viewType: #COMPOSITE

define view entity P_EBASO_EvtBsdVariance1
  with parameters
    P_FromFiscalYearPeriod : fis_jahrper,
    P_ToFiscalYearPeriod   : fis_jahrper,
    P_Ledger               : fins_ledger
  as select from I_JournalEntryItem
{
  key SourceLedger,
  key CompanyCode,
  key Plant,
  key FiscalYear,
  key AccountingDocument,
  key LedgerGLLineItem,
  key Ledger,
  key cast('31' as co_wrttp)                                as ControllingValueType, // Variance


      ControllingArea,
      cast(
        case
          when VarianceOriginGLAccount is not initial then VarianceOriginGLAccount
          else OffsettingAccount
        end
      as fis_racct)                                         as CostElement,
      BusinessTransactionCategory,
      OriginCtrlgDebitCreditCode                            as ControllingDebitCreditCode,
      case SubLedgerAcctLineItemType
        when '09139'
          then 'C'  //Lot Size Variance is from Goods Receipt

        else 'B'
      end                                                   as CtrlgOriginClassification,
      case
        when OrderID <> '' then OrderID
        else OriginOrder // V-Price Variance (BSX transaction)

      end                                                   as OrderID,
      OrderItem,
      AccountAssignmentType,
      PartnerAccountAssignment,
      PartnerAccountAssignmentType,
      cast(OriginCostCenter as fis_skost)                   as PartnerCostCenter,
      cast(OriginCostCtrActivityType as fis_par_lstar)      as PartnerCostCtrActivityType,
      PartnerBusinessProcess,
      PartnerOrder_2                                        as PartnerOrder,
      cast(ReferenceQuantityUnit as meins)                  as UnitOfMeasure,
      OriginProduct                                         as Material,
      VarianceOriginGroup                                   as CostOriginGroup,

      SubLedgerAcctLineItemType,
      cast(
        case
          when SubLedgerAcctLineItemType = '09139' then 'X' // Lot-Size Variance

          else ''
        end
      as fco_psknz )                                        as IsLotSizeIndependent,

      // Origin Objects

      OriginCostCenter,
      OriginCostCtrActivityType,

      CompanyCodeCurrency,
      GlobalCurrency,
      FreeDefinedCurrency1,
      FreeDefinedCurrency2,
      FreeDefinedCurrency3,
      FreeDefinedCurrency4,
      FreeDefinedCurrency5,
      FreeDefinedCurrency6,
      FreeDefinedCurrency7,
      FreeDefinedCurrency8,

      cast(AmountInCompanyCodeCurrency as abap.dec(23, 2))  as AmountInCompanyCodeCurrency,
      cast(AmountInGlobalCurrency as abap.dec(23, 2))       as AmountInGlobalCurrency,
      cast(AmountInFreeDefinedCurrency1 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency1,
      cast(AmountInFreeDefinedCurrency2 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency2,
      cast(AmountInFreeDefinedCurrency3 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency3,
      cast(AmountInFreeDefinedCurrency4 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency4,
      cast(AmountInFreeDefinedCurrency5 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency5,
      cast(AmountInFreeDefinedCurrency6 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency6,
      cast(AmountInFreeDefinedCurrency7 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency7,
      cast(AmountInFreeDefinedCurrency8 as abap.dec(23, 2)) as AmountInFreeDefinedCurrency8
}
where
       BusinessTransactionCategory  = 'EBVP'
  and(
       TransactionTypeDetermination = 'PRD'
    or TransactionTypeDetermination = 'BSX'
    or TransactionTypeDetermination = ''
  )
  and  FiscalYearPeriod             >= $parameters.P_FromFiscalYearPeriod
  and  FiscalYearPeriod             <= $parameters.P_ToFiscalYearPeriod
  and  Ledger                       = $parameters.P_Ledger