P_DemandDrivenExtdProduct

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Demand Driven Product Details'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_DemandDrivenExtdProduct 
as select from I_DemandDrivenProduct as _ddProduct 

inner join  I_MaterialMRPArea as _MaterialMRPArea on _MaterialMRPArea.Material = _ddProduct.Material
                                                        and _MaterialMRPArea.Plant = _ddProduct.Plant
                                                        and _MaterialMRPArea.MRPArea = _ddProduct.MRPArea

inner join I_SDMAreaOfResponsibility as _SDMAreaOfResponsibility  on _SDMAreaOfResponsibility.Plant = _MaterialMRPArea.Plant 
                                                          and _SDMAreaOfResponsibility.MRPController = _MaterialMRPArea.MRPController
                                                          and _SDMAreaOfResponsibility.UserID = $session.user   

inner join I_BufferedMaterialPlant1 as _BufMatPlant on  _BufMatPlant.Material = _MaterialMRPArea.Material
                                                                and _BufMatPlant.Plant = _SDMAreaOfResponsibility.Plant
{

  key   _ddProduct.Material,
  key   _ddProduct.Plant,
  key   _ddProduct.MRPArea,
        _MaterialMRPArea.MRPController,
        _MaterialMRPArea.MRPType,
        _MaterialMRPArea.LotSizingProcedure,
        @Semantics.quantity.unitOfMeasure: 'BaseUnit'
        _MaterialMRPArea.MinimumLotSizeQuantity,
        _MaterialMRPArea.PlanningTimeFence,
        @Semantics.quantity.unitOfMeasure: 'BaseUnit'
        _MaterialMRPArea.ReorderThresholdQuantity,
        @Semantics.quantity.unitOfMeasure: 'BaseUnit'
        _MaterialMRPArea.MaterialMaxStockLevelQuantity,
        @Semantics.quantity.unitOfMeasure: 'BaseUnit'
        _MaterialMRPArea.SafetyStockQuantity,
        
        //DD Product Fields

        _ddProduct.ConsumptionCode,
        _ddProduct.ConsumptionMode,
             
        @Semantics.amount.currencyCode: 'Currency'
        _ddProduct.ProductConsumptionAmount,
        _ddProduct.Currency,
        _ddProduct.VariabilityCode,
        _ddProduct.VariabilityMode,
        @Semantics.quantity.unitOfMeasure: 'BaseUnit'
        _ddProduct.VariabilityQuantity,
        _ddProduct.VariabilityUnit,
        _ddProduct.ReplenishmentLeadTimeCode,
        _ddProduct.ReplenishmentLeadTimeMode,
        _ddProduct.ProcurementType,
        _ddProduct.ReplenishmentLeadTimeValue,
        _ddProduct.BOMUsageCode,
        _ddProduct.BOMUsageMode,
        _ddProduct.BOMUsageValue,
        _ddProduct.IndividualLeadTime,
        _ddProduct.SpikeHorizonConstant,
        _ddProduct.SpikeHorizonMultiplier,
        _ddProduct.SpikeThresholdFactor,
        cast(
          case
            when _ddProduct.LeadTimeCalculationMethod = ''
              then 'HCRE'
          else
            _ddProduct.LeadTimeCalculationMethod
          end as pph_leadtime_calc_method )                                          as LeadTimeCalculationMethod,
        _ddProduct.DecoupledLeadTime,
        _ddProduct.HorizonDaysInPast,
        _ddProduct.HorizonDaysInFuture,
        _ddProduct.PastHorizonDLTMultiplierValue,
        _ddProduct.FutureHrznDLTMultiplierValue,
        _ddProduct.DDScopeProduct,
        _ddProduct.CreatedByUser,
        _ddProduct.LastChangedByUser,
        _ddProduct.CreationDateTime,
        _ddProduct.LastChangeDateTime,
        _BufMatPlant.IsBulkMaterial,
        _BufMatPlant.IsPhantomItem,
        _BufMatPlant.BaseUnit,
        _BufMatPlant.ProductGroup,
        _BufMatPlant._MatStatus,
        
        _BufMatPlant.AuthorizationGroup,
        _BufMatPlant.ProductTypeAuthorizationGroup,
        _BufMatPlant.ProductGroupAuthorizationGroup      
}
where
   _MaterialMRPArea.DeletionIndicator <> 'X'
   and
   _ddProduct.Plant != _ddProduct.MRPArea
   and
   (_BufMatPlant.CrossPlantStatus is null or _BufMatPlant.CrossPlantStatus is initial)
   and
   (_BufMatPlant.MRPMaterialStatus is null or _BufMatPlant.MRPMaterialStatus is initial)
   and
   _BufMatPlant.IsBulkMaterial = ''
   and
   (_BufMatPlant.IsPhantomItem = '' or _BufMatPlant.IsPhantomItem is null)
   
union all 
  select from I_DemandDrivenProduct   as _ddProduct

inner join I_BufferedMaterialPlant1 as _BufMatPlant on  _BufMatPlant.Material = _ddProduct.Material  
                                                    and _BufMatPlant.Plant = _ddProduct.Plant       

inner join I_SDMAreaOfResponsibility as _SDMAreaOfResponsibility  on  _SDMAreaOfResponsibility.Plant = _BufMatPlant.Plant  
                                                  and _SDMAreaOfResponsibility.MRPController = _BufMatPlant.MRPController  
                                                  and _SDMAreaOfResponsibility.UserID = $session.user 
{

  key  _ddProduct.Material,
  key  _ddProduct.Plant,
  key  _ddProduct.Plant   as MRPArea,
       _BufMatPlant.MRPController,
       _BufMatPlant.MRPType,
       _BufMatPlant.LotSizingProcedure,
       _BufMatPlant.MinimumLotSizeQuantity,
       _BufMatPlant.PlanningTimeFence,
       _BufMatPlant.ReorderThresholdQuantity,
       _BufMatPlant.MaterialMaxStockLevelQuantity,
       _BufMatPlant.SafetyStockQuantity,
       
       //DD Product Fields

       _ddProduct.ConsumptionCode,
       _ddProduct.ConsumptionMode,
       
        _ddProduct.ProductConsumptionAmount,
        _ddProduct.Currency,
        _ddProduct.VariabilityCode,
        _ddProduct.VariabilityMode,
        _ddProduct.VariabilityQuantity,
        _ddProduct.VariabilityUnit,
        _ddProduct.ReplenishmentLeadTimeCode,
        _ddProduct.ReplenishmentLeadTimeMode,
        _ddProduct.ProcurementType,
        _ddProduct.ReplenishmentLeadTimeValue,
        _ddProduct.BOMUsageCode,
        _ddProduct.BOMUsageMode,
        _ddProduct.BOMUsageValue,
        _ddProduct.IndividualLeadTime,
        _ddProduct.SpikeHorizonConstant,
        _ddProduct.SpikeHorizonMultiplier,
        _ddProduct.SpikeThresholdFactor,
        cast(
          case
            when _ddProduct.LeadTimeCalculationMethod = ''
              then 'HCRE'
          else
            _ddProduct.LeadTimeCalculationMethod
          end as pph_leadtime_calc_method )                                          as LeadTimeCalculationMethod,
        _ddProduct.DecoupledLeadTime,
        _ddProduct.HorizonDaysInPast,
        _ddProduct.HorizonDaysInFuture,
        _ddProduct.PastHorizonDLTMultiplierValue,
        _ddProduct.FutureHrznDLTMultiplierValue,
        _ddProduct.DDScopeProduct,
        _ddProduct.CreatedByUser,
        _ddProduct.LastChangedByUser,
        _ddProduct.CreationDateTime,
        _ddProduct.LastChangeDateTime,
        _BufMatPlant.IsBulkMaterial,
        _BufMatPlant.IsPhantomItem,
        _BufMatPlant.BaseUnit,
        _BufMatPlant.ProductGroup,
        _BufMatPlant._MatStatus,      
        _BufMatPlant.AuthorizationGroup,
        _BufMatPlant.ProductTypeAuthorizationGroup,
        _BufMatPlant.ProductGroupAuthorizationGroup   
}where
_BufMatPlant.DeletionIndicator <> 'X'
and
_ddProduct.Plant = _ddProduct.MRPArea
and
(_BufMatPlant.CrossPlantStatus is null or _BufMatPlant.CrossPlantStatus is initial)
and
(_BufMatPlant.MRPMaterialStatus is null or _BufMatPlant.MRPMaterialStatus is initial)
and
_BufMatPlant.IsBulkMaterial = ''
and
(_BufMatPlant.IsPhantomItem = '' or _BufMatPlant.IsPhantomItem is null)