P_DRFEWMBATCH

@AbapCatalog.sqlViewName: 'PDRFEWMBATCHOUT'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass:#MASTER

@VDM.viewType: #BASIC
@VDM.private: true
define view P_DRFEWMBATCH
  as select from mch1
    inner join   tcuch              on kzdch_old <> '0'
    inner join   v_mard_md as md    on mch1.matnr = md.matnr
    inner join   t320 as lg         on  lg.lgort = md.lgort
                                    and lg.werks = md.werks
    inner join   t340d as ewm       on ewm.lgnum = lg.lgnum
{
  key mch1.matnr,
  key cast('    ' as werks_d preserving type) as werks,
  key mch1.charg,
  key lg.lgnum
}
where
  ewm.decsy = 'E'
group by
  mch1.matnr,
  mch1.charg,
  lg.lgnum

union all

select from  mcha
  inner join tcuch            on kzdch_old = '0'
  inner join v_mard_md as md  on  mcha.matnr = md.matnr
                              and mcha.werks = md.werks
  inner join t320 as lg       on  lg.lgort = md.lgort
                              and lg.werks = md.werks
  inner join t340d as ewm     on ewm.lgnum = lg.lgnum
{
  key mcha.matnr,
  key mcha.werks,
  key mcha.charg,
  key lg.lgnum
}
where
  ewm.decsy = 'E'
group by
  mcha.matnr,
  mcha.werks,
  mcha.charg,
  lg.lgnum