P_DMVCMaterialActivity

@AbapCatalog.sqlViewName: 'PDMVCMATLACTY'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #CHECK

@VDM.viewType: #COMPOSITE
@VDM.private:true
define view P_DMVCMaterialActivity
  with parameters
    P_DateFrom     : calendardate,
    P_DateTo       : calendardate,
    P_CurrencyType : curtp,
    P_Ledger       : fins_ledger
  as select distinct from P_MaterialLedgerDocument as _MaterialLedgerDocument
    inner join            P_MLActivityHeader       as _ActivityHeader      on _MaterialLedgerDocument.CostEstimate = _ActivityHeader.CostEstimate
    inner join            I_Plant                  as _Plant               on _ActivityHeader.Plant = _Plant.Plant
    inner join            I_Purreqvaluationarea    as _Purreqvaluationarea on _Plant.ValuationArea = _Purreqvaluationarea.ValuationArea

{
  key _MaterialLedgerDocument.CostEstimate,
  key _MaterialLedgerDocument.ProcessCategory,
      _ActivityHeader.objnr                  as ObjectInternalID,
      _ActivityHeader.Plant,
      _Plant.ValuationArea,
      _Purreqvaluationarea.CompanyCode,
      substring(_ActivityHeader.objnr, 3, 4) as ControllingArea,

      case substring(_ActivityHeader.objnr, 1, 2)
        when 'KL' then substring(_ActivityHeader.objnr, 7, 10)
        when 'BP' then substring(_ActivityHeader.objnr, 7, 8)
      end                                    as CostCenter,

      case substring(_ActivityHeader.objnr, 1, 2)
        when 'KL' then substring(_ActivityHeader.objnr, 17, 6)
        else ''
      end                                    as CostCtrActivityType,

      case substring(_ActivityHeader.objnr, 1, 2)
        when 'BP' then substring(_ActivityHeader.objnr, 7, 11)
        else ''
      end                                    as BusinessProcess,
      
      _MaterialLedgerDocument.awref          as ReferenceDocument,
      _MaterialLedgerDocument.awitem         as ReferenceDocumentItem,
      @Semantics.unitOfMeasure: true
      _MaterialLedgerDocument.ValuationQuantityUnit, //BaseUoM,

      @Semantics.currencyCode: true
      _MaterialLedgerDocument.Currency
}
where
      _MaterialLedgerDocument.CostEstimate != '000000000000'
  and LedgerValuationCurrencyRole = $parameters.P_CurrencyType
  and PostingDate                 >= $parameters.P_DateFrom
  and PostingDate                 <= $parameters.P_DateTo
  and (Ledger = :P_Ledger or Ledger = ' ')