P_DDPurchaseRequisition

DDL: P_DDPURCHASEREQUISITION SQL: PDDPURREQDET Type: view COMPOSITE Package: ODATA_PP_DD_ORD_DET

Purchase Requisition Basic Details

P_DDPurchaseRequisition is a Composite CDS View that provides data about "Purchase Requisition Basic Details" in SAP S/4HANA. It reads from 1 data source (I_Purchaserequisitionitem) and exposes 28 fields with key fields PurchaseRequisition, PurchaseRequisitionItem. Part of development package ODATA_PP_DD_ORD_DET.

1 data source(s) 28 fields

Data Sources (1)

SourceAliasJoin Type
I_Purchaserequisitionitem I_Purchaserequisitionitem from

Parameters (1)

NameTypeDefault
P_MRPElementCategory delkz

Annotations (9)

NameValueLevelField
AbapCatalog.sqlViewName PDDPURREQDET view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #NOT_REQUIRED view
VDM.viewType #COMPOSITE view
VDM.private true view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MASTER view

Fields (28)

KeyFieldSource TableSource FieldDescription
KEY PurchaseRequisition PurchaseRequisition
KEY PurchaseRequisitionItem PurchaseRequisitionItem
Material Material
MaterialName
Plant Plant
MaterialProcurementCategory PurchasingDocumentItemCategory
MRPController MRPController
PurchasingDocumentCategory PurchasingDocumentCategory
PurchaseRequisitionType PurchaseRequisitionType
PurchaseRequisitionIsFixed PurchaseRequisitionIsFixed
PurchasingInfoRecord PurchasingInfoRecord
PurchasingOrganization PurchasingOrganization
MaterialPlannedDeliveryDurn MaterialPlannedDeliveryDurn
MaterialGoodsReceiptDuration MaterialGoodsReceiptDuration
ReleaseDate PurchaseRequisitionReleaseDate
DeliveryDate DeliveryDate
PurchaseOutlineAgreement PurchaseContract
PurchaseOutlineAgreementItem PurchaseContractItem
TotalQuantity RequestedQuantity
OrderedQuantity OrderedQuantity
OpenQuantity
PurchaseRequisitionUnit BaseUnit
PurchasingGroup PurchasingGroup
PurchasingGroupName _PurchasingGroup PurchasingGroupName
PurchasingGroupPhoneNumber _PurchasingGroup PurchasingGroupPhoneNumber
PurchasingGroupEmailAddress _PurchasingGroup EmailAddress
FixedSupplier FixedSupplier
OrderUnit MaterialOrderUnit 
@AbapCatalog.sqlViewName: 'PDDPURREQDET'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'Purchase Requisition Basic Details'

@VDM.viewType: #COMPOSITE
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #X, sizeCategory: #XL, dataClass: #MASTER}
define view P_DDPurchaseRequisition
  with parameters
    P_MRPElementCategory : delkz
  as select from I_Purchaserequisitionitem
{

  key PurchaseRequisition,
  key PurchaseRequisitionItem,
      Material,
      _Material._Text[1:Language = $session.system_language].MaterialName,
      Plant,

      case $parameters.P_MRPElementCategory
      when 'BA'
      then Plant
      when 'U2'
      then SupplyingPlant
      end                                                                                                      as MRPPlant,

      case $parameters.P_MRPElementCategory
      when 'BA'
      then SupplyingPlant
      when 'U2'
      then Plant
      end                                                                                                      as SupplyingPlant,

      PurchasingDocumentItemCategory                                                                           as MaterialProcurementCategory,
      MRPController,

      PurchasingDocumentCategory,
      PurchaseRequisitionType,

      // Purchasing Related Data

      PurchaseRequisitionIsFixed,
      PurchasingInfoRecord,
      PurchasingOrganization,
      case SupplierMaterialNumber
        when '' then _PurchasingInfoRecord.SupplierMaterialNumber
        else SupplierMaterialNumber
      end                                                                                                      as SupplierMaterialNumber,
      MaterialPlannedDeliveryDurn,
      MaterialGoodsReceiptDuration,
      PurchaseRequisitionReleaseDate                                                                           as ReleaseDate,
      DeliveryDate,
      PurchaseContract                                                                                         as PurchaseOutlineAgreement,
      PurchaseContractItem                                                                                     as PurchaseOutlineAgreementItem,

      // Quantities and UoM

      @Semantics.quantity.unitOfMeasure: 'PurchaseRequisitionUnit'
      @DefaultAggregation: #NONE
      RequestedQuantity                                                                                        as TotalQuantity,
      @Semantics.quantity.unitOfMeasure: 'PurchaseRequisitionUnit'
      @DefaultAggregation: #NONE
      OrderedQuantity,
      @Semantics.quantity.unitOfMeasure: 'PurchaseRequisitionUnit'
      @DefaultAggregation: #NONE
      RequestedQuantity - OrderedQuantity                                                                      as OpenQuantity,
      @Semantics.unitOfMeasure: true
      BaseUnit                                                                                                 as PurchaseRequisitionUnit,

      PurchasingGroup,
      _PurchasingGroup.PurchasingGroupName,
      _PurchasingGroup.PurchasingGroupPhoneNumber,
      _PurchasingGroup.EmailAddress                                                                            as PurchasingGroupEmailAddress,

      case
      when FixedSupplier is not null and FixedSupplier <> ' ' and FixedSupplier <> ''
      then FixedSupplier
      else Supplier
      end                                                                                                      as Supplier,

      FixedSupplier,

      case
      when FixedSupplier = ''
      then ''
      else 'X'
      end                                                                                                      as SupplierIsFixed,
      MaterialOrderUnit                                                                                        as OrderUnit
}
where
  IsDeleted = ''

Learn More