P_DACRMLDOC

DDL: P_DACRMLDOC Type: view_entity COMPOSITE Package: ODATA_ML_ACR_DISP

MLDOC for DACR

P_DACRMLDOC is a Composite CDS View that provides data about "MLDOC for DACR" in SAP S/4HANA. It reads from 1 data source (P_MaterialLedgerDocument) and exposes 17 fields with key fields docref, CurrencyRole. Part of development package ODATA_ML_ACR_DISP.

1 data source(s) 17 fields

Data Sources (1)

SourceAliasJoin Type
P_MaterialLedgerDocument P_MaterialLedgerDocument from

Parameters (5)

NameTypeDefault
P_CostEstimate ck_kalnr
P_FiscalYearPeriod fins_fyearperiod
P_CurrencyRole fins_curtype
P_Ledger fins_ledger
P_BaseUnit valum

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label MLDOC for DACR view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view
VDM.private true view
VDM.viewType #COMPOSITE view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY docref docref
KEY CurrencyRole LedgerValuationCurrencyRole
CostEstimate CostEstimate
Ledger Ledger
FiscalYearPeriod FiscalYearPeriod
MaterialLedgerCategory categ
MaterialLedgerCategoryText
ProcessCategory ProcessCategory
ProcessCategoryName
ValuationQuantity ValuationQuantity
ValuationQuantityUnit ValuationQuantityUnit
InventoryAmtInCCCrcy InventoryAmtInCCCrcy
PriceDifferenceAmtInCCCrcy PriceDifferenceAmtInCCCrcy
ExchRateDiffAmtInCoCodeCrcy ExchRateDiffAmtInCoCodeCrcy
StandardPrice stprs
MaterialLedgerItemType posart
Currency Currency 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'MLDOC for DACR'

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}

@VDM.private: true
@VDM.viewType: #COMPOSITE
define root view entity P_DACRMLDOC
 with parameters
    P_CostEstimate :ck_kalnr,
    P_FiscalYearPeriod : fins_fyearperiod,
    P_CurrencyRole : fins_curtype,
    P_Ledger       : fins_ledger,
    P_BaseUnit : valum
  as select from P_MaterialLedgerDocument
  association of many to one I_MaterialLedgerCategory as _categname on  $projection.MaterialLedgerCategory = _categname.MaterialLedgerCategory 
  association of many to one P_MLProcessCategory as _procatname on $projection.ProcessCategory = _procatname.ProcessCategory 
{
  key docref,
  key LedgerValuationCurrencyRole as CurrencyRole,
      CostEstimate, 
      Ledger,
      FiscalYearPeriod,
      categ as MaterialLedgerCategory,
      _categname._Text[1: Language = $session.system_language ].MaterialLedgerCategoryText as MaterialLedgerCategoryText,      
      ProcessCategory,
      _procatname._Text[1: Language = $session.system_language ].ProcessCategoryName as ProcessCategoryName,
      @Semantics.quantity.unitOfMeasure: 'ValuationQuantityUnit'
      ValuationQuantity            as ValuationQuantity,       
      ValuationQuantityUnit,
      @Semantics.amount.currencyCode: 'Currency'
      InventoryAmtInCCCrcy         as InventoryAmtInCCCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      PriceDifferenceAmtInCCCrcy   as PriceDifferenceAmtInCCCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      ExchRateDiffAmtInCoCodeCrcy  as ExchRateDiffAmtInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'Currency' 
      stprs as StandardPrice,    
      posart as MaterialLedgerItemType,      
      Currency
}
where
  CostEstimate = $parameters.P_CostEstimate and
  LedgerValuationCurrencyRole = $parameters.P_CurrencyRole and
  Ledger = $parameters.P_Ledger and
  FiscalYearPeriod = $parameters.P_FiscalYearPeriod and
  ValuationQuantityUnit = $parameters.P_BaseUnit

Learn More