P_CtrlgOvhdJournalEntryItem

@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'PCTRLGOVHDJEI'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M

@VDM.viewType: #BASIC
@VDM.private: true

define view P_CtrlgOvhdJournalEntryItem
  as select from fco_ovhd_refdr     as _CtrlgOvhdRefDoc
    inner join   fco_ovhd_stadr     as _CtrlgOvhdStat    on _CtrlgOvhdStat.draftuuid = _CtrlgOvhdRefDoc.parentdraftuuid
    inner join   I_JournalEntryItem as _JournalEntryItem on  _JournalEntryItem.ReferenceDocumentType = _CtrlgOvhdRefDoc.referencedocumenttype
                                                         and _JournalEntryItem.ReferenceDocument     = _CtrlgOvhdRefDoc.referencedocument
                                                         and _JournalEntryItem.ControllingArea       = _CtrlgOvhdStat.controllingarea

{
  key _CtrlgOvhdRefDoc.controllingobject             as ControllingObject,
  key _CtrlgOvhdRefDoc.controllingoverheaddraftuuid  as ControllingOverheadDraftUUID,
  key SourceLedger,
  key _JournalEntryItem.CompanyCode,
  key _JournalEntryItem.FiscalYear,
      @Consumption.semanticObject: 'AccountingDocument'
  key AccountingDocument,
  key LedgerGLLineItem,
  key _JournalEntryItem.Ledger,
      _JournalEntryItem._Ledger.IsLeadingLedger      as IsLeadingLedger,
      LedgerFiscalYear,

      FiscalPeriod,

      _CompanyCode.CompanyCodeName,

      _CtrlgOvhdRefDoc.referencedocumenttype,
      _CtrlgOvhdRefDoc.referencedocument,

      CostCenter,
      ProfitCenter,
      Segment,
      cast(FunctionalArea as fm_efarea)              as FunctionalArea,
      cast(Fund as fm_efonds)                        as Fund,
      cast(BudgetPeriod as fm_ebudget_period)        as BudgetPeriod,
      cast(GrantID as gm_grant_receiver)             as GrantID,
      cast(PartnerFunctionalArea as fm_sfarea)       as PartnerFunctionalArea,
      cast(PartnerFund as fm_sfonds)                 as PartnerFund,
      cast(PartnerBudgetPeriod as fm_sbudget_period) as PartnerBudgetPeriod,
      cast(PartnerGrant as gm_grant_sender)          as PartnerGrant,
      BusinessTransactionType,
      DebitCreditCode,
      FinancialTransactionType,
      GLAccount,
      GLRecordType,
      WBSElement,

      @Semantics.currencyCode       : true
      BalanceTransactionCurrency,
      @Semantics.currencyCode       : true
      TransactionCurrency,
      @Semantics.currencyCode       : true
      CompanyCodeCurrency,
      @Semantics.currencyCode       : true
      GlobalCurrency,
      @Semantics.currencyCode       : true
      FreeDefinedCurrency1,
      @Semantics.currencyCode       : true
      FreeDefinedCurrency2,
      @Semantics.currencyCode       : true
      FreeDefinedCurrency3,
      @Semantics.currencyCode       : true
      FreeDefinedCurrency4,
      @Semantics.currencyCode       : true
      FreeDefinedCurrency5,
      @Semantics.currencyCode       : true
      FreeDefinedCurrency6,
      @Semantics.currencyCode       : true
      FreeDefinedCurrency7,
      @Semantics.currencyCode       : true
      FreeDefinedCurrency8,
      @Semantics.currencyCode       : true
      ControllingObjectCurrency,
      @Semantics.unitOfMeasure: true
      BaseUnit,
      @Semantics.amount.currencyCode: 'BalanceTransactionCurrency'
      AmountInBalanceTransacCrcy,
      @UI.lineItem.position: 50
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      AmountInTransactionCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      AmountInCompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'GlobalCurrency'
      AmountInGlobalCurrency,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency1'
      AmountInFreeDefinedCurrency1,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency2'
      AmountInFreeDefinedCurrency2,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency3'
      AmountInFreeDefinedCurrency3,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency4'
      AmountInFreeDefinedCurrency4,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency5'
      AmountInFreeDefinedCurrency5,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency6'
      AmountInFreeDefinedCurrency6,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency7'
      AmountInFreeDefinedCurrency7,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency8'
      AmountInFreeDefinedCurrency8,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      Quantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      FixedQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      ValuationQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      ValuationFixedQuantity,
      
      _JournalEntryItem.ControllingArea as ControllingArea,
      _JournalEntryItem.AccountingDocumentCategory as AccountingDocumentCategory
      
}

  where SourceLedger = _JournalEntryItem.Ledger