P_CostAccountingDocument_2

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'Cost Accounting Document'

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@VDM: {
  viewType: #COMPOSITE,
  private: true
}
/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view entity P_CostAccountingDocument_2
  as select from I_GLAccountLineItemRawData as _Header
  
{
  key _Header.FiscalYear,
  key _Header.ReferenceDocument,
  key _Header.ControllingArea,
  key _Header.LedgerGLLineItem,
  key _Header.ReferenceDocumentType,
  key _Header.ReferenceDocumentContext,
      
      _Header._JournalEntry.AccountingDocumentHeaderText,
      _Header.DocumentDate,
      _Header.PostingDate,
      _Header.FiscalPeriod,      
      _Header.FiscalYearPeriod,
      cast(_Header._JournalEntry.AccountingDocumentCreationDate as farp_cpudt preserving type) as AccountingDocumentCreationDate,
      cast(_Header.AccountingDocCreatedByUser as fco_cc_createdby preserving type)    as AccountingDocCreatedByUser,
      _Header.IsReversal,
      _Header.IsReversed,   
      cast(_Header._JournalEntry.ExchangeRateDate as fin_currconvdat preserving type) as ExchangeRateDate,
      _Header.PredecessorReferenceDocument,
      _Header.PredecessorReferenceDocType,
      _Header.PredecessorReferenceDocCntxt,
      _Header.ReversalReferenceDocument,
      _Header.ReversalReferenceDocumentType,

      _Header.GlobalCurrency,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Header.AmountInGlobalCurrency,
      
      cast(_Header.ControllingBusTransacType as fins_co_bus_trans preserving type ) as ControllingBusTransacType,
      _Header.BusinessTransactionCategory,
      
      cast(
        case _Header.IsReversal
            when '' then ( case _Header.PredecessorReferenceDocument
                            when '' then '1'
                            else '3' end )
            else '2'
      end as fco_posting_type) as AllocationPostingType,
      
      cast(
        case _Header.IsReversal
            when '' then ''
            else _Header.ReversalReferenceDocument 
        end as reversedreferencedocument preserving type )  as ReversedReferenceDocument,
      _Header.IsSettled
}

where 
_Header.OriginCtrlgDebitCreditCode = 'S' 
and ( ReferenceDocumentType = 'COBK' 
      or ( ReferenceDocumentType = 'CATS' 
           and IsReversal = '' 
           and ControllingBusTransacType = 'RKL'
           and ( _Header._JournalEntry.JournalEntryReprocessingStatus = '' or _Header._JournalEntry.JournalEntryReprocessingStatus = '3' ) ) 
      or ( ReferenceDocumentType = 'AFRU' and ControllingBusTransacType = 'RKL' ) )
and _Header._Ledger.IsLeadingLedger   = 'X'
and _Header.IsSettlement = ''
and _Header.JournalEntryIsSecondaryEntry = ''
and _Header.LogicalSystem = ''
and _Header.AccountAssignmentType <> ''
and _Header.ReferenceDocument <> ''