P_ContrAcctgGLItem

@AbapCatalog.viewEnhancementCategory: [#NONE]
@VDM.private: true
@VDM.viewType: #COMPOSITE

@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@AccessControl.authorizationCheck: #NOT_REQUIRED

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #MIXED
}

define view entity P_ContrAcctgGLItem
  with parameters
    P_FromPostingDate : fis_budat_from,
    P_ToPostingDate   : fis_budat_to,
    P_CompanyCode     : bukrs
  as select from I_CADocument       as ficadoc
    inner join   I_CADocumentGLItem as fica_glitems on  ficadoc.CADocumentNumber = fica_glitems.CADocumentNumber
                                                    and ficadoc.CAPostingDate    >= $parameters.P_FromPostingDate
                                                    and ficadoc.CAPostingDate    <= $parameters.P_ToPostingDate
                                                    and fica_glitems.CompanyCode = $parameters.P_CompanyCode

  association to I_CADocumentType as _CADocumentType on  $projection.CADocumentType    = _CADocumentType.CADocumentType
                                                     and $projection.CAApplicationArea = _CADocumentType.CAApplicationArea
{

  key  fica_glitems.CADocumentNumber                     as CADocumentNumber,
  key  fica_glitems.CAGLItemNumber                       as CAGLItemNumber,
       cast( '' as  opupw_kk)                            as CARepetitionItemNumber,
       fica_glitems.CompanyCode                          as CompanyCode,
       fica_glitems._CompCode.FiscalYearVariant          as FiscalYearVariant,
       cast( '' as  opupz_kk)                            as CASubItemNumber,
       cast( '' as  opupk_kk)                            as CABPItemNumber,
       ficadoc.CreatedByUser                             as CreatedByUser,
       ficadoc.CreationDate                              as CreationDate,
       ficadoc.CreationTime                              as CreationTime,
       ficadoc.CAApplicationArea                         as CAApplicationArea,
       ficadoc.DocumentDate                              as DocumentDate,
       ficadoc.LastChangeDate                            as LastChangeDate,
       ficadoc.CAReferenceDocument                       as CAReferenceDocument,
       ficadoc.CAClassificationKey                       as CAClassificationKey,
       ficadoc.CAPostingDate                             as CAPostingDate,
       fica_glitems.ChartOfAccounts                      as ChartOfAccounts,
       fica_glitems.GLAccount                            as GLAccount,
       fica_glitems.TaxCode                              as TaxCode,
       fica_glitems.TaxCountry                           as TaxCountry,
       fica_glitems.CATaxRate                            as CATaxRate,
       fica_glitems.CATransactionKeyAccountDetn          as CATransactionKeyAccountDetn,
       fica_glitems.CostCenter                           as CostCenter,
       ficadoc.CADocumentType                            as CADocumentType,
       _CADocumentType._Text[1: Language = $session.system_language].
       CADocumentTypeName                                as CADocumentTypeName,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       fica_glitems.CAAmountInTransactionCurrency        as CAAmountInTransactionCurrency,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       fica_glitems.CATaxBaseAmount                      as CATaxBaseAmount,
       fica_glitems.TransactionCurrency                  as TransactionCurrency,
       fica_glitems.Currency                             as CompanyCodeCurrency,
       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       fica_glitems.CAAmountInLocalCurrency              as CAAmountInLocalCurrency,
       @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
       fica_glitems.CATaxBaseAmountInLocalCurrency       as CATaxBaseAmountInLocalCurrency,
       fica_glitems.CAExchangeRate                       as CAExchangeRate,
       fica_glitems._CADocument.CAReversedDocumentNumber as CAReversedDocumentNumber
}