P_CollectionsAccount

@AbapCatalog: { sqlViewName: 'PCOLLSACCT',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData:       { blocking: #BLOCKED_DATA_EXCLUDED } }
@VDM: { viewType: #COMPOSITE,
        private: true }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #C,
                             sizeCategory: #L,
                             dataClass: #TRANSACTIONAL },
                representativeKey: 'Customer' }
@Consumption: { dbHints: [ 'USE_HEX_PLAN' ] }

define view P_CollectionsAccount
  as select distinct from I_Customer
    inner join            I_CustomerCompany            on I_Customer.Customer = I_CustomerCompany.Customer
    inner join            I_BusinessPartnerCustomer    on I_Customer.Customer = I_BusinessPartnerCustomer.Customer
    left outer to many join(
                          I_CollsSgmtCompanyCodeAssgmt
        inner join        I_BPCollectionsSegmentAssgmt on  I_CollsSgmtCompanyCodeAssgmt.CollectionSegment           = I_BPCollectionsSegmentAssgmt.CollectionSegment
                                                       and I_BPCollectionsSegmentAssgmt.BPCollSgmtAssignmentValidTo = '99991231'
    )
    on  I_CustomerCompany.CompanyCode             = I_CollsSgmtCompanyCodeAssgmt.CompanyCode
    and I_BusinessPartnerCustomer.BusinessPartner = I_BPCollectionsSegmentAssgmt.BusinessPartner

  // VDM Associations

  // Customer

  association [0..1] to I_Customer          as _Customer          on $projection.Customer = _Customer.Customer

  // Business Partner

  association [0..1] to I_BusinessPartner   as _BusinessPartner   on $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  // Company Code

  association [0..1] to I_CompanyCode       as _CompanyCode       on $projection.CompanyCode = _CompanyCode.CompanyCode

  // Collection Segment

  association [0..1] to I_CollectionSegment as _CollectionSegment on $projection.CollectionSegment = _CollectionSegment.CollectionSegment

{

      // VDM Fields

      @ObjectModel: { foreignKey: { association: '_Customer' } }
  key I_BusinessPartnerCustomer.Customer                                                                as Customer,

      @ObjectModel: { foreignKey: { association: '_CollectionSegment' } }
  key cast( I_BPCollectionsSegmentAssgmt.CollectionSegment as farp_collection_segment preserving type ) as CollectionSegment,

      @ObjectModel: { foreignKey: { association: '_CompanyCode' } }
  key I_CustomerCompany.CompanyCode                                                                     as CompanyCode,

      @ObjectModel: { foreignKey: { association: '_BusinessPartner' } }
  key I_BusinessPartnerCustomer.BusinessPartner                                                         as BusinessPartner,

      // Text Elements

      _Customer.CustomerName                                                                            as CustomerName,
      _CollectionSegment._Text[1:Language = $session.system_language].CollectionSegmentName             as CollectionSegmentName,
      _CompanyCode.CompanyCodeName                                                                      as CompanyCodeName,
      _BusinessPartner.BusinessPartnerName                                                              as BusinessPartnerName,

      // Exposed Associations

      _Customer,
      _BusinessPartner,
      _CompanyCode,
      _CollectionSegment

}