P_ChgRecdRefMfgBOM

@AbapCatalog.sqlViewName: 'PCRREFMFGBOMUN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.private: true
@VDM.viewType: #TRANSACTIONAL

/*
 * Creates the union of virtual and non-virtual manufacturing BOM entries.
 * Existing records are calculated here directly; empty attributes will be added later in ABAP exits
 * P_ChgRecdRefMfgBOMVirtual     returns BOMs where ChangeRecordVirtualRefInd = true  for Mfg BOM
 */
define view P_ChgRecdRefMfgBOM
  as select from I_ChgRecdRefMBOM      as ReferenceBOM
  // and ReferenceBOM.ChgRecRefInternalKey4 < MAST doesn't store the version

    inner join   I_MfgBOMUsage                            on ReferenceBOM.BillOfMaterialVariantUsage = I_MfgBOMUsage.BillOfMaterialVariantUsage
{
  key ChangeRecordReferenceUUID,
      ReferenceBOM.Material,
      ReferenceBOM.Plant,
      ReferenceBOM.BillOfMaterialVariantUsage,
      ReferenceBOM.BillOfMaterialVariant,
      cast(ChgRecRefInternalKey4 as cs_versn)                                                                                        as BillOfMaterialVersion,
      ChangeRecordUUID,
      ChangeRecord,
      ChangeRecordReferenceType,
      ChangeRecordReferenceSubtype,
      ChangeRecordRefObjectUUID,
      ChangeRecordReference,
      ParentChangeRecordRefUUID,
      IsMainReference,
      ReferenceBOM.CreatedByUser,
      CreationDateTime,
      ReferenceBOM.LastChangedByUser,
      LastChangeDateTime,
      ChangeRecordItemRelevance,
      ChangeRecordVirtualRefInd,

      cast(hextobin('00000000000000000000000000000000') as cs_guidb)                                                                 as BillOfMaterialHeaderUUID,
      concat(concat(concat(ReferenceBOM.BillOfMaterial,ReferenceBOM.BillOfMaterialCategory),ReferenceBOM.BillOfMaterialVariantUsage),ReferenceBOM.BillOfMaterialVariant) as BillOfMaterialUUID,
      ReferenceBOM.BillOfMaterial,
      ReferenceBOM.BillOfMaterialCategory,
      cast('' as cs_versnind)                                                                                                        as IsVersionBillOfMaterial,
      cast('' as cs_versnst)                                                                                                         as BOMVersionStatus,
      cast('' as stlst)                                                                                                              as BillOfMaterialStatus
}
where
  ChangeRecordVirtualRefInd <> 'X'
  
union all select from P_ChgRecdRefMfgBOMVirtual

{
  key ChangeRecordReferenceUUID,
      Material,
      Plant,
      BillOfMaterialVariantUsage,
      BillOfMaterialVariant,
      BillOfMaterialVersion,
      ChangeRecordUUID,
      ChangeRecord,
      ChangeRecordReferenceType,
      ChangeRecordReferenceSubtype,
      ChangeRecordRefObjectUUID,
      ChangeRecordReference,
      ParentChangeRecordRefUUID,
      IsMainReference,
      CreatedByUser,
      CreationDateTime,
      LastChangedByUser,
      LastChangeDateTime,
      ChangeRecordItemRelevance,
      ChangeRecordVirtualRefInd,
      BillOfMaterialHeaderUUID,
      BillOfMaterialUUID,
      BillOfMaterial,
      BillOfMaterialCategory,
      IsVersionBillOfMaterial,
      BOMVersionStatus,
      BillOfMaterialStatus
}
where
  ChangeRecordReferenceType = 'MBM'