P_CO_DIANFrmt1007JrnlItmWthBP3

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel: {
  representativeKey: 'LedgerGLLineItem',
  usageType.dataClass: #MIXED,
  usageType.serviceQuality: #P,
  usageType.sizeCategory: #XXL
}
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType: #CONSUMPTION,
  private: true
}
define view entity P_CO_DIANFrmt1007JrnlItmWthBP3
  with parameters
    @EndUserText.label: 'Statutory Report Entity'
    P_StatryRptgEntity  : srf_reporting_entity,
    @EndUserText.label: 'Statutory Report Category'
    P_StatryRptCategory : srf_rep_cat_id,
    @EndUserText.label: 'Statutory Report Run ID'
    P_StatryRptRunID    : srf_report_run_id,
    @EndUserText.label: 'Company Code'
    P_CompanyCode       : fis_bukrs,
    @EndUserText.label: 'Fiscal Year'
    P_FiscalYear        : fis_gjahr,
    @EndUserText.label: 'General Ledger'
    P_Ledger            : fins_ledger,
    @EndUserText.label: 'From Posting Date'
    P_FromPostingDate   : fis_budat_from,
    @EndUserText.label: 'To Posting Date'
    P_ToPostingDate     : fis_budat_to

  as select from P_CO_DIANFrmt1007JrnlEntrItem3(
                   P_StatryRptgEntity  : $parameters.P_StatryRptgEntity,
                   P_StatryRptCategory : $parameters.P_StatryRptCategory,
                   P_StatryRptRunID    : $parameters.P_StatryRptRunID,
                   P_CompanyCode       : $parameters.P_CompanyCode,
                   P_FiscalYear        : $parameters.P_FiscalYear,
                   P_Ledger            : $parameters.P_Ledger,
                   P_FromPostingDate   : $parameters.P_FromPostingDate,
                   P_ToPostingDate     : $parameters.P_ToPostingDate ) as JournalEntryItem

    inner join   I_OperationalAcctgDocItem                             as AcctgDocItem on  AcctgDocItem.PostingDate                >= $parameters.P_FromPostingDate
                                                                                       and AcctgDocItem.PostingDate                <= $parameters.P_ToPostingDate
                                                                                       and JournalEntryItem.CompanyCode            = AcctgDocItem.CompanyCode
                                                                                       and JournalEntryItem.FiscalYear             = AcctgDocItem.FiscalYear
                                                                                       and JournalEntryItem.AccountingDocument     = AcctgDocItem.AccountingDocument
                                                                                       and JournalEntryItem.AccountingDocumentItem = AcctgDocItem.AccountingDocumentItem
{
  key JournalEntryItem.StatryRptgEntity,
  key JournalEntryItem.StatryRptCategory,
  key JournalEntryItem.StatryRptRunID,
  key JournalEntryItem.Ledger,
  key JournalEntryItem.CompanyCode,
  key JournalEntryItem.FiscalYear,
  key JournalEntryItem.AccountingDocument,
  key JournalEntryItem.LedgerGLLineItem,
  key JournalEntryItem.CO_DIANReportFormat,
  key JournalEntryItem.CO_DIANReportItemType,

      -- G/L Account information
      JournalEntryItem.CO_DIANAmountClassification,
      JournalEntryItem.GLAccount,
      JournalEntryItem.GLAccountType,
      JournalEntryItem.AlternativeGLAccount,
      JournalEntryItem.SpecialGLCode,
      JournalEntryItem.ChartOfAccounts,
      JournalEntryItem.CountryChartOfAccounts,
      JournalEntryItem.FinancialAccountType,
      JournalEntryItem.DebitCreditCode,
      JournalEntryItem.TaxCode,

      -- Third-party identification
      JournalEntryItem.Customer,
      JournalEntryItem.OffsettingAccount,
      JournalEntryItem.OffsettingAccountType,

      cast( left( AcctgDocItem.OplAcctgDocItmCntrySpcfcRef1, 20 ) as ficodian_bp_tax_long_number preserving type ) as CO_DIANBPTaxLongNumber,

      AcctgDocItem.Reference1IDByBusinessPartner,
      AcctgDocItem.Reference3IDByBusinessPartner,

      case when AcctgDocItem.OplAcctgDocItmCntrySpcfcRef1 is not null and AcctgDocItem.OplAcctgDocItmCntrySpcfcRef1 <> ''
           then AcctgDocItem.OplAcctgDocItmCntrySpcfcRef1
           when AcctgDocItem.Reference1IDByBusinessPartner is not null and AcctgDocItem.Reference1IDByBusinessPartner <> ''
           then AcctgDocItem.Reference1IDByBusinessPartner
           else null
       end                                                                                                         as ReportedTaxNumber,

      -- Document details
      JournalEntryItem.AccountingDocumentItem,
      JournalEntryItem.AccountingDocumentType,
      JournalEntryItem.IsReversal,
      JournalEntryItem.IsReversed,
      JournalEntryItem.CostCenter,
      JournalEntryItem.ProfitCenter,
      JournalEntryItem.TransactionTypeDetermination,
      JournalEntryItem.FiscalPeriod,
      JournalEntryItem.PostingDate,
      JournalEntryItem.DocumentDate,
      JournalEntryItem.ClearingDate,
      JournalEntryItem.AccountingDocCreatedByUser,

      -- Document reference
      JournalEntryItem.ReferenceDocumentType,
      JournalEntryItem.ReferenceDocument,
      JournalEntryItem.ReferenceDocumentItem,

      @ObjectModel.foreignKey.association: '_ReportingCurrency'
      JournalEntryItem.ReportingCurrency,
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      JournalEntryItem.AmountInReportingCurrency,

      -- Association
      JournalEntryItem._ReportingCurrency
}
where
      JournalEntryItem.OffsettingAccountType     <> 'D'
  and JournalEntryItem.AmountInReportingCurrency <> 0